trip_master.F90

Go to the documentation of this file.

!###################################################################
PROGRAM trip_master
!###################################################################
!
!
!!****  *TRIP_MASTER*  
!!
!!    PURPOSE
!!    -------
!!   
!!    Driver for TRIP from CNRM
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    06/08
!!      S.Sénési    08/11/16 : interface to XIOS 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_surfex_trip_n
USE modd_off_trip_n
!
USE modd_trip_listing
!
USE modn_trip_run, ONLY : lrestart, lprint, lwr_diag,  &
                          xtstep_run, xtstep_diag
!
USE modd_trip_par, ONLY : xundef, nundef, xday
!
USE mode_rw_trip
!
USE modi_read_nam_trip_run
USE modi_read_nam_trip
USE modi_read_nam_trip_grid
!
USE modi_abort_trip
USE modi_get_trip_grid_conf
!
USE modi_init_trip
USE modi_init_trip_par
USE modi_trip_run_conf
USE modi_trip_restart
USE modi_trip_diag_run
USE modi_trip_run
!
USE modi_trip_oasis_init
USE modi_trip_oasis_read_nam
USE modi_trip_oasis_define
USE modi_trip_oasis_end
!
USE modi_trip_xios_init
!
#ifdef SFX_MPI
#ifdef SFX_MPL
USE mpl_data_module, ONLY : lmplusercomm, mplusercomm
#endif
#endif
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#if defined CPLOASIS || defined WXIOS
include 'mpif.h'
#endif
!
INTEGER                           :: IYEAR               ! current year         (UTC)
INTEGER                           :: IMONTH              ! current month        (UTC)
INTEGER                           :: IDAY                ! current day          (UTC)
REAL                              :: ZTIME               ! current time           (s)
REAL                              :: ZRUNTIME            ! total simulated time   (s)
!
INTEGER                           :: INB_TSTEP_RUN       ! number of time step in the run
INTEGER                           :: ILON                ! Number of longitude
INTEGER                           :: ILAT                ! Number of latittude
!
INTEGER                           :: INB_OL              ! number of time step if forcing offline
INTEGER                           :: ILON_OL             ! Number of longitude if forcing offline
INTEGER                           :: ILAT_OL             ! Number of latittude if forcing offline
!
INTEGER                           :: IERR                ! Error value
INTEGER                           :: INPROC              ! Number of processes
INTEGER                           :: IRANK               ! Local process number
INTEGER                           :: ILOCAL_COMM         ! Local communicator
LOGICAL                           :: GOASIS              ! OASIS used(default=.false.)
LOGICAL                           :: GXIOS               ! XIOS used(default=.false.)
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
! --------------------------------------------------------------------------------------
! * 0. MPI and OASIS must be initialized before any DR_HOOK call
! --------------------------------------------------------------------------------------
!
 CALL trip_oasis_init(goasis,gxios,ilocal_comm,pruntime=zruntime)
!
#ifdef SFX_MPI
#ifdef SFX_MPL
IF (ilocal_comm/=0) THEN
  lmplusercomm = .true.
  mplusercomm = ilocal_comm
ENDIF
#endif
#endif
!
! --------------------------------------------------------------------------------------
! * 1. Alloc trip variables and open listing
! --------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_MASTER',0,zhook_handle)
!
 CALL trip_alloc_list(1)
!
 CALL init_trip_par
!
OPEN(unit=nlisting,file=clisting,form='FORMATTED',action='WRITE')
!
! --------------------------------------------------------------------------------------
! * 2. Check run attributes
! --------------------------------------------------------------------------------------
!
!Inquire if trip is parallel or not: TRIP is only a monoprocess model for now
!
inproc = nundef
irank  = nundef
!
#ifdef CPLOASIS || WXIOS
IF (ilocal_comm==0) THEN
  ilocal_comm = mpi_comm_world
ENDIF
 CALL mpi_comm_size(ilocal_comm,inproc,ierr)
 CALL mpi_comm_rank(ilocal_comm,irank,ierr)  
!
IF(inproc==nundef.OR.irank==nundef)THEN
  WRITE(nlisting,*)'TRIP_MASTER: PROBLEM WITH MPI, INPROC = ',inproc
  WRITE(nlisting,*)'TRIP_MASTER: PROBLEM WITH MPI, IRANK  = ',irank
  CALL abort_trip('TRIP_MASTER: PROBLEM WITH MPI')
ENDIF
#endif
!
IF(inproc>1.AND.inproc<nundef)THEN
  WRITE(nlisting,*)'TRIP_MASTER: TRIP NOT YET PARALLELIZED, NPROC SHOULD BE 1'
  CALL abort_trip('TRIP_MASTER: TRIP NOT YET PARALLELIZED')
ENDIF
!
IF(goasis)THEN
  WRITE(nlisting,*) '!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(nlisting,*) '    OASIS is used      ' 
  WRITE(nlisting,*) '                       '
  WRITE(nlisting,*) 'Number of processes   :', inproc
  WRITE(nlisting,*) 'Local process number  :', irank
  WRITE(nlisting,*) 'Local communicator    :', ilocal_comm
  WRITE(nlisting,*) '!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(nlisting,*) '                       '
ELSE
  WRITE(nlisting,*) '!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(nlisting,*) '   TRIP run offline    ' 
  WRITE(nlisting,*) '!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(nlisting,*) '                       '
ENDIF
!
! --------------------------------------------------------------------------------------
! * 3. read namelists
! --------------------------------------------------------------------------------------
!
 CALL read_nam_trip_run(nlisting)
!
 CALL read_nam_trip(nlisting)
!
IF(goasis)THEN
  CALL trip_oasis_read_nam(nlisting,zruntime)
ENDIF
!
! --------------------------------------------------------------------------------------
! * 4. TRIP initializations
! --------------------------------------------------------------------------------------
!
ytrip_cur => ytrip_list(1)
!
 CALL read_nam_trip_grid(ytrip_cur%TPG,nlisting)
!
 CALL init_trip(ytrip_cur%TPDG, ytrip_cur%TP, ytrip_cur%TPG, &
               iyear,imonth,iday,ztime,ilon,ilat,xtstep_run, &
               xtstep_diag,lrestart,gxios)
!
! --------------------------------------------------------------------------------------
! * 5. TRIP - OASIS  grid, partitions and local field definitions
! --------------------------------------------------------------------------------------
!
IF(goasis)THEN
  CALL trip_oasis_define(nlisting,ilon,ilat)
ENDIF
!
! --------------------------------------------------------------------------------------
! * 5.2 XIOS init
! --------------------------------------------------------------------------------------
!
#ifdef WXIOS
IF (gxios) THEN 
   CALL trip_xios_init(ytrip_cur%TPG,ilocal_comm,ilon,ilat,&
                       iyear,imonth,iday,ztime)
ENDIF
#endif
!
! --------------------------------------------------------------------------------------
! * 6. Get run configuration
! --------------------------------------------------------------------------------------
!
 CALL trip_run_conf(nlisting,goasis,iyear,imonth,iday,ztime, &
                   ilon,ilat,inb_tstep_run,zruntime         )
!
IF(goasis)THEN
  inb_ol  = 0
  ilon_ol = 0
  ilat_ol = 0
ELSE
  inb_ol  = inb_tstep_run
  ilon_ol = ilon
  ilat_ol = ilat
ENDIF
!
! --------------------------------------------------------------------------------------
! * 7. Read and prepare drainage and runoff if offline
! --------------------------------------------------------------------------------------
!
 CALL trip_run(ytrip_cur%TPDG, ytrip_cur%TP, ytrip_cur%TPG, &
              goasis,gxios,                     &
              nlisting,ilon,ilat,inb_tstep_run, &
              zruntime,ilon_ol,ilat_ol,inb_ol,  &
              iyear,imonth,iday,ztime           )
!
!-------------------------------------------------------------------------------
! * 9. Store run mean diagnostic and write restart
!-------------------------------------------------------------------------------
!
IF (gxios) THEN 
   CALL write_trip(nlisting,'dummy.nc','areacellr',ytrip_cur%TPG%GMASK,ytrip_cur%TPG%XAREA,oxios=.true.)
ELSEIF(lwr_diag)THEN
   CALL trip_diag_run(ytrip_cur%TPDG, ytrip_cur%TPG, &
                      nlisting,ilon,ilat,zruntime)
ENDIF
!
IF(lrestart)THEN
   CALL trip_restart(ytrip_cur%TP, ytrip_cur%TPG, &
                     nlisting,iyear,imonth,iday,ztime,ilon,ilat)
ENDIF
!
! --------------------------------------------------------------------------------------
! * 10. End of run
! --------------------------------------------------------------------------------------
!
 CLOSE(nlisting)
!
WRITE(*,*) ' '
WRITE(*,*) '    ------------------------------'
WRITE(*,*) '    | TRIP MASTER ENDS CORRECTLY |'
WRITE(*,*) '    ------------------------------'
WRITE(*,*) ' '
!
 CALL trip_deallo_list
!
IF (lhook) CALL dr_hook('TRIP_MASTER',1,zhook_handle)
!
! --------------------------------------------------------------------------------------
! * 11. MPI and OASIS must be finalized after the last DR_HOOK call
! --------------------------------------------------------------------------------------
!
 CALL trip_oasis_end(goasis,gxios)
!
!-------------------------------------------------------------------------------
END PROGRAM trip_master