trip_run.F90

Go to the documentation of this file.

SUBROUTINE trip_run (TPDG, TP, TPG, &
                     OOASIS, OXIOS,                   &
                    KLISTING,KLON,KLAT,KNB_TSTEP_RUN, &
                    PRUNTIME,KLON_OL,KLAT_OL,KNB_OL,  &
                    KYEAR,KMONTH,KDAY,PTIME           )
!#############################################
!
!!****  *TRIP_RUN*  
!!
!!    PURPOSE
!!    -------
!!   
!!    Run trip
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    06/08 
!!      B. Decharme 10/2016  bug surface/groundwater coupling   
!!      S.Sénési    08/11/16 : interface to XIOS
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_trip_diag, ONLY : trip_diag_t
USE modd_trip,      ONLY : trip_t
USE modd_trip_grid, ONLY : trip_grid_t
!
USE modd_trip_listing
!
USE modn_trip_run, ONLY : lrestart, lprint,   &
                          xtstep_run, xtstep_diag
!
USE modd_trip_par, ONLY : xundef, nundef, xday
!
USE modi_trip_forcing
USE modi_trip_interface
USE modi_trip_date
!
USE modi_trip_oasis_recv
USE modi_trip_oasis_send
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!-------------------------------------------------------------------------------
!
!*      0.1    declarations of arguments
!
!
TYPE(trip_diag_t), INTENT(INOUT) :: TPDG
TYPE(trip_t),      INTENT(INOUT) :: TP
TYPE(trip_grid_t), INTENT(INOUT) :: TPG
!
LOGICAL, INTENT(IN)  :: OOASIS        ! Oasis coupling or not
LOGICAL, INTENT(IN)  :: OXIOS         ! Do we use XIOS
!
INTEGER, INTENT(IN)  :: KLISTING      ! Listing ID
INTEGER, INTENT(IN)  :: KLON          ! Number of longitude
INTEGER, INTENT(IN)  :: KLAT          ! Number of latittude
INTEGER, INTENT(IN)  :: KNB_TSTEP_RUN ! number of time step in the run
REAL,    INTENT(IN)  :: PRUNTIME      ! total simulated time
!
INTEGER, INTENT(IN)  :: KLON_OL       ! Number of longitude if forcing offline
INTEGER, INTENT(IN)  :: KLAT_OL       ! Number of latittude if forcing offline
INTEGER, INTENT(IN)  :: KNB_OL        ! number of time step if forcing offline
!
INTEGER, INTENT(OUT) :: KYEAR         ! current year         (UTC)
INTEGER, INTENT(OUT) :: KMONTH        ! current month        (UTC)
INTEGER, INTENT(OUT) :: KDAY          ! current day          (UTC)
REAL,    INTENT(OUT) :: PTIME         ! current time           (s)
!
!-------------------------------------------------------------------------------
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(KLON_OL,KLAT_OL,KNB_OL) :: ZDRAIN_OL         ! Drainage from the forcing file          (kg)
REAL, DIMENSION(KLON_OL,KLAT_OL,KNB_OL) :: ZRUNOFF_OL        ! Surface runoff from the forcing file    (kg)
REAL, DIMENSION(KLON_OL,KLAT_OL,KNB_OL) :: ZSRC_FLOOD_OL     ! Flood source term from the forcing file (kg)
!
REAL, DIMENSION(KLON,KLAT) :: ZRUNOFF           ! Surface runoff               (kg/s)
REAL, DIMENSION(KLON,KLAT) :: ZDRAIN            ! Drainage                     (kg/s)
REAL, DIMENSION(KLON,KLAT) :: ZCALVING          ! Calving flux                 (kg/s)
REAL, DIMENSION(KLON,KLAT) :: ZSRC_FLOOD        ! Input P-E-I flood source term(kg/s)
!
REAL                       :: ZTIMEC            ! cumulated current time (s)
REAL                       :: ZTIME_CPL         ! Coupling time
INTEGER                    :: JNB_TSTEP_RUN     ! TSTEP_RUN counter 
INTEGER                    :: JNB_TSTEP_DIAG    ! DIAG call counter 
INTEGER                    :: ICOUNT
 CHARACTER(LEN=3)          :: YWORK
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
! --------------------------------------------------------------------------------------
! * 1. Initialize
! --------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_RUN',0,zhook_handle)
!
zrunoff(:,:) = xundef
zdrain(:,:) = xundef
zcalving(:,:) = xundef
zsrc_flood(:,:) = xundef
!
! --------------------------------------------------------------------------------------
! * 2. Read and prepare drainage and runoff if offline
! --------------------------------------------------------------------------------------
!
IF(.NOT.ooasis)THEN
  zdrain_ol(:,:,:) = xundef
  zrunoff_ol(:,:,:) = xundef
  zsrc_flood_ol(:,:,:) = xundef
  CALL trip_forcing(tpg, &
                    klisting,klon,klat,knb_tstep_run, &
                    zdrain_ol,zrunoff_ol,zsrc_flood_ol)
ENDIF
!
! --------------------------------------------------------------------------------------
! * 3. Temporal loops
! --------------------------------------------------------------------------------------
!
ztimec         = 0
icount         = 0
jnb_tstep_diag = 0
!
DO jnb_tstep_run = 1, knb_tstep_run
!
! * TRIP INPUT FLUXES (kg/s)
!
   IF(ooasis)THEN           
     CALL trip_oasis_recv(tp, tpg, &
                          klisting,klon,klat,ztimec,zrunoff,  &
                          zdrain,zcalving,zsrc_flood          )
   ELSE
     zdrain(:,:) = zdrain_ol(:,:,jnb_tstep_run) / xtstep_run
     zrunoff(:,:) = zrunoff_ol(:,:,jnb_tstep_run) / xtstep_run
     zsrc_flood(:,:) = zsrc_flood_ol(:,:,jnb_tstep_run) / xtstep_run
     zcalving(:,:) = 0.0
   ENDIF
!
! * TRIP PHYSIC CALL
!
   CALL trip_interface(tpdg, tp, tpg, &
                       klisting,klon,klat,ptime,ztimec,    &
                       lprint,jnb_tstep_run,jnb_tstep_diag,&
                       xtstep_run,xtstep_diag,zrunoff,     &
                       zdrain,zcalving,zsrc_flood,oxios    )
!
! * TRIP OUTPUT FLUXES
!
   IF(ooasis)THEN
     ztime_cpl=ztimec-xtstep_run
     CALL trip_oasis_send(tp, tpg, &
                          klisting,klon,klat,ztime_cpl)
   ENDIF
!                   
   IF (lprint.AND.mod(ztimec,xday)==0.0) THEN
      icount = icount +1
      WRITE(*,'(A10,I5,A2,I5)')'TRIP DAY :',icount,' /',int(pruntime/xday)
   ENDIF
!
! * TRIP DATE INCREMENT
!
   CALL trip_date(kyear,kmonth,kday,ptime)
!
ENDDO
!
! --------------------------------------------------------------------------------------
! * 4. End TRIP run
! --------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_RUN',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE trip_run