trip_interface.F90

Go to the documentation of this file.

!#################################################################
SUBROUTINE trip_interface (TPDG, TP, TPG, &
                           KLISTING,KLON,KLAT,PTIME,PTIMEC,    &
                           OPRINT,KNB_TSTEP_RUN,KNB_TSTEP_DIAG,&
                           PTSTEP_RUN,PTSTEP_DIAG,PRUNOFF,     &
                           PDRAIN,PCALVING,PSRC_FLOOD,OXIOS    )
!#################################################################
!
!!****  *TRIP*  
!!
!!    PURPOSE
!!    -------
!
!     Driver for the TRIP river routing.
!     Here, we call the physical and the diag routines     
!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/02/05 
!!      Modif.      28/05/08 
!!      B. Decharme 10/2016  bug surface/groundwater coupling  
!!      S.Sénési    08/11/16 : interface to XIOS 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
!
USE modd_trip_diag, ONLY : trip_diag_t
USE modd_trip,      ONLY : trip_t
USE modd_trip_grid, ONLY : trip_grid_t
!
USE modn_trip_run,  ONLY : ldiag_misc, lwr_diag
!
USE modn_trip,      ONLY : cgroundw, lflood, xtstep
!
USE modd_trip_par,  ONLY : xrholw, xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_trip_hs_vel
USE modi_trip
USE modi_trip_diag_init
USE modi_trip_diag
USE modi_trip_diag_write
USE modi_trip_diag_cpl_esm
!
USE modi_gwf
USE modi_gwf_cpl_update
!
USE modi_abort_trip
!
USE modi_gwf
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(trip_diag_t), INTENT(INOUT) :: TPDG
TYPE(trip_t),      INTENT(INOUT) :: TP
TYPE(trip_grid_t), INTENT(INOUT) :: TPG
!
INTEGER,              INTENT(IN)    :: KLISTING       !Output file id
INTEGER,              INTENT(IN)    :: KLON           !Number of longitude
INTEGER,              INTENT(IN)    :: KLAT           !Number of latittude
REAL,                 INTENT(INOUT) :: PTIME          !Current time          (s)
REAL,                 INTENT(INOUT) :: PTIMEC         !Cumulated time        (s)
LOGICAL,              INTENT(IN)    :: OPRINT         !print option          [-]
INTEGER,              INTENT(IN)    :: KNB_TSTEP_RUN  !TSTEP_RUN counter     [-]
REAL,                 INTENT(IN)    :: PTSTEP_RUN     !Run  timestep         [s]
REAL,                 INTENT(IN)    :: PTSTEP_DIAG    !Diag timestep         [s]
INTEGER,              INTENT(INOUT) :: KNB_TSTEP_DIAG !DIAG call counter     [-]
LOGICAL,              INTENT(IN)    :: OXIOS          !Do we use XIOS
!
REAL, DIMENSION(:,:), INTENT(IN)    :: PRUNOFF   !Input surface runoff            [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)    :: PDRAIN    !Input free drainage             [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)    :: PCALVING  !Input claving flux from glacier [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)    :: PSRC_FLOOD! Input P-E-I flood source term  [kg/s]
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(KLON,KLAT) :: ZRUNOFF    !Input surface runoff          [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZDRAIN     !Input drainage + recharge     [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZSRC_FLOOD !Input P-E-I flood source term [kg/s]
!
REAL, DIMENSION(KLON,KLAT) :: ZSOUT      !streamflow                    [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZSIN       !grid-cell input streamflow    [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZVEL       !river velocity                [m/s]
REAL, DIMENSION(KLON,KLAT) :: ZHS        !River heigh                   [m]
REAL, DIMENSION(KLON,KLAT) :: ZGOUT      !Groundwater outflow           [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZGNEG      !Groundwater intflow (neg)     [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZWTD       !Water table depth for coupling[m]
REAL, DIMENSION(KLON,KLAT) :: ZFWTD      !fraction of water table to rise
REAL, DIMENSION(KLON,KLAT) :: ZQGCELL    !lateral groundwater exchanges [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZHGHS      !groundwater minus river heigh [m]
REAL, DIMENSION(KLON,KLAT) :: ZQFR       !floodplains to river exchange [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZQRF       !river to floodplains exchange [kg/s]
REAL, DIMENSION(KLON,KLAT) :: ZVFIN      !QRF velocity                  [m/s]
REAL, DIMENSION(KLON,KLAT) :: ZVFOUT     !QFR velocity                  [m/s]
REAL, DIMENSION(KLON,KLAT) :: ZHSF       !river minus flodd heigh       [m]
REAL, DIMENSION(KLON,KLAT) :: ZDISCHARGE !river discharges              [kg]
REAL, DIMENSION(KLON,KLAT) :: ZHG_OLD    !Water table depth at t-1      [m]
!
REAL                       :: ZGSTO_ALL  !Global groundwater storage at t    [kg]
REAL                       :: ZGSTO2_ALL !Global groundwater storage at t-1  [kg]
REAL                       :: ZGIN_ALL   !Global gw recharge + lateral input [kg/m2/s]
REAL                       :: ZGOUT_ALL  !Global gw outflow                  [kg/m2/s]
!
LOGICAL                    :: GWRDIAG
!
INTEGER :: JTSTEP, ITSTEP
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_INTERFACE',0,zhook_handle)
!
!-------------------------------------------------------------------------------
!
!*       0.     Initialize local variables:
!               ---------------------------
!
zsout(:,:) = 0.0
zsin(:,:) = 0.0
zvel(:,:) = 0.0
zhs(:,:) = 0.0
zgout(:,:) = 0.0
zgneg(:,:) = 0.0
zwtd(:,:) = 0.0
zfwtd(:,:) = 0.0
zqgcell(:,:) = 0.0
zhghs(:,:) = 0.0
zqfr(:,:) = 0.0
zqrf(:,:) = 0.0
zvfin(:,:) = 0.0
zvfout(:,:) = 0.0
zhsf(:,:) = 0.0
zdischarge(:,:) = 0.0
zhg_old(:,:) = 0.0
!
!-------------------------------------------------------------------------------
!
zgsto_all  = 0.0
zgsto2_all = 0.0
zgin_all   = 0.0
zgout_all  = 0.0
!
!-------------------------------------------------------------------------------
!
!Surface runoff treatment
!
zrunoff(:,:) = prunoff(:,:)
!
!Drainage and Calving treatment 
!calving over greenland and antarctica directly to ocean
!
WHERE(tpg%GMASK(:,:).AND..NOT.tpg%GMASK_GRE(:,:).AND..NOT.tpg%GMASK_ANT(:,:))
  zdrain(:,:) = pdrain(:,:)+pcalving(:,:)
ELSEWHERE
  zdrain(:,:) = pdrain(:,:)
ENDWHERE
!
! Flood treatment
!
IF(lflood)THEN 
  zsrc_flood(:,:) = psrc_flood(:,:)
  WHERE(tp%XFFLOOD(:,:)==1.0.AND.zsrc_flood(:,:)>0.0)
        zrunoff(:,:) = zrunoff(:,:) + psrc_flood(:,:)
        zsrc_flood(:,:) = 0.0
  ENDWHERE
ELSE
  zsrc_flood(:,:) = 0.0
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       1.     Initialize local diag :
!               -----------------------
!
 CALL trip_diag_init(zsout,zsin,zvel,zhs,zgout,zgneg,zhg_old,  &
                    zwtd,zfwtd,zqgcell,zhghs,                  &
                    zqfr,zqrf,zvfin,zvfout,zhsf,zdischarge,    &
                    zgsto_all,zgsto2_all,zgin_all,zgout_all    )
!
!-------------------------------------------------------------------------------
!
!*       2.     Initialize river height and velocity :
!               --------------------------------------
!
 CALL trip_hs_vel(xtstep,tpg%GMASK_VEL,tpg%XLEN,tp%XWIDTH, &
                 tp%XSLOPEBED,tp%XN,tp%XSURF_STO,zhs,zvel )
!
!-------------------------------------------------------------------------------
!
!*       3.     Call Groundwater dynamic :
!               --------------------------
!
IF(cgroundw=='DIF')THEN
!
!  * Groundwater actualization
!
  CALL gwf(tpg, &
           klon,klat,oprint,ptstep_run,xtstep,      &
           tpg%GMASK_GW,tp%XNUM_AQUI,zdrain,        &
           tpg%XLEN,tp%XWIDTH,tp%XHC_BED,           &
           tp%XTOPO_RIV,tp%XTAUG,tpg%XAREA,         &
           tp%XTRANS,tp%XWEFF,tp%XTABGW_F,          &
           tp%XTABGW_H,zhs,tp%XHGROUND,zhg_old,     &
           psurf_sto=tp%XSURF_STO,pqgcell=zqgcell,  &
           pwtd=zwtd,pfwtd=zfwtd,phghs=zhghs,       &
           pgout=zgout,pgneg=zgneg,                 &
           pgsto_all=zgsto_all,                     &
           pgsto2_all=zgsto2_all,                   &
           pgin_all=zgin_all,pgout_all=zgout_all    )
!
!  * Velocity actualization
!   
   CALL trip_hs_vel(xtstep,tpg%GMASK_VEL, &
                    tpg%XLEN,tp%XWIDTH,   &
                    tp%XSLOPEBED,tp%XN,   &
                    tp%XSURF_STO,zhs,zvel )  
!            
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       4.     Call Trip river routines and actualisation of diagnostic :
!               ----------------------------------------------------------
!
itstep = int(ptstep_run/xtstep)
!
DO jtstep=1,itstep !TRIP time step loop
!
  CALL trip(klisting,cgroundw,lflood,oprint,xtstep,       &
            tpg%NGRCN,tpg%NSEQ,tpg%NNEXTX,tpg%NNEXTY,     &
            tpg%NSEQMAX,tpg%XAREA,tpg%XLEN,               &
            tpg%GMASK_GW,tpg%GMASK_VEL,tpg%GMASK_FLD,     &
            tp%XTAUG,tp%XFLOOD_LEN,tp%XSLOPEBED,          &
            tp%XWIDTH,tp%XN,tp%XN_FLOOD,tp%XHC_BED,       &
            tp%XWFLOOD,tp%XTAB_F,tp%XTAB_H,               &
            tp%XTAB_VF,zdrain,zrunoff,zsrc_flood,zhs,zvel,&
            tp%XGROUND_STO,tp%XSURF_STO,tp%XFLOOD_STO,    &
            zsout,zgout,tp%XHFLOOD,tp%XFFLOOD,            &
            zqfr,zqrf,zvfin,zvfout,zhsf,zsin,knb_tstep_run,       &
            jtstep,itstep,zgsto_all,zgsto2_all,zgin_all,zgout_all,&
            tp%XHGROUND,tp%XWEFF)
!
!  * Actualisation of diagnostic  
!
   IF(cgroundw=='DIF')THEN
      CALL gwf_cpl_update(tp%XTABGW_H,tp%XTABGW_F,tpg%GMASK_GW,&
                          tp%XTOPO_RIV,tp%XHC_BED,tp%XHGROUND, &
                          zhg_old,zwtd,zfwtd                   )   
   ENDIF
!
   CALL trip_diag(tpdg, tp, tpg, &
                  xtstep,zsout,zsin,zvel,zhs,zgout,zgneg,    &
                  zwtd,zfwtd,zqgcell,zhghs,                  &
                  zqfr,zqrf,zvfin,zvfout,zhsf,zsrc_flood,    &
                  zdrain,zrunoff,zdischarge                  )
!
!  * Velocity actualization
!   
   CALL trip_hs_vel(xtstep,tpg%GMASK_VEL, &
                    tpg%XLEN,tp%XWIDTH,   &
                    tp%XSLOPEBED,tp%XN,   &
                    tp%XSURF_STO,zhs,zvel )  
!
!  * Time actualization  
!
   ptime  = ptime  + xtstep
   ptimec = ptimec + xtstep
!
!  * Write diagnostic  
!
   gwrdiag = (lwr_diag.AND.mod(ptimec,ptstep_diag) == 0.)
!
   IF (gwrdiag) THEN
      knb_tstep_diag = knb_tstep_diag + 1
      CALL trip_diag_write(tpdg, tpg, &
                           klisting,klon,klat,knb_tstep_diag,ptstep_diag,oxios)
   ENDIF
!
!  * end 
!
   IF(oprint)WRITE(klisting,*)' '
!
ENDDO ! * End TRIP time step loop
!
!
!-------------------------------------------------------------------------------
!
!*       5.      Actualisation of coupling diagnostic:
!               --------------------------------------
!
 CALL trip_diag_cpl_esm(tp, tpg, &
                       ptstep_run,zdischarge,pcalving,zwtd,zfwtd)
!
IF (lhook) CALL dr_hook('TRIP_INTERFACE',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
!
END SUBROUTINE trip_interface