trip_diag_cpl_esm.F90

Go to the documentation of this file.

SUBROUTINE trip_diag_cpl_esm (TP, TPG, &
                              PTSTEP_RUN,PDISCHARGE,PCALVING,PWTD,PFWTD)  
!     #################################################################
!
!!****  *TRIP_DIAG_CPL_ESM*  
!!
!!    PURPOSE
!!    -------
!
!     TRIP cpl diag compuation
!     
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/12/13 
!!      B. Decharme 10/2016  bug surface/groundwater coupling
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE modd_trip, ONLY : trip_t
USE modd_trip_grid, ONLY : trip_grid_t
!
USE modd_trip_par,   ONLY : xundef, xrholw
!
USE modd_trip_oasis, ONLY : lcpl_sea, lcpl_land, lcpl_gw,    &
                            lcpl_flood, lcpl_calvsea
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(trip_t), INTENT(INOUT) :: TP
TYPE(trip_grid_t), INTENT(INOUT) :: TPG
!
REAL,                 INTENT(IN) :: PTSTEP_RUN !Run  timestep                   [s]
REAL, DIMENSION(:,:), INTENT(IN) :: PDISCHARGE !Cumulated river discharges      [kg]
REAL, DIMENSION(:,:), INTENT(IN) :: PCALVING   !Input claving flux from glacier [kg/s]
REAL, DIMENSION(:,:), INTENT(IN) :: PWTD       !Water table depth               [m]
REAL, DIMENSION(:,:), INTENT(IN) :: PFWTD      !Fraction of Water table to rise
!
!*      0.2    declarations of local variables
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_DIAG_CPL_ESM',0,zhook_handle)
!
!*       1.      Actualisation of sea coupling diagnostic:
!               ------------------------------------------
!
!
! River discharges to ocean [kg/m2]
!
IF(lcpl_sea)THEN
  WHERE(tpg%NGRCN(:,:)==9.OR.tpg%NGRCN(:,:)==12)
    tp%XCPL_RIVDIS(:,:) = tp%XCPL_RIVDIS(:,:) + pdischarge(:,:) / tpg%XAREA(:,:)
  ENDWHERE
ENDIF
!
! Calving flux over greenland and antarctica [kg/m2]
!
IF(lcpl_calvsea)THEN
  WHERE(tpg%GMASK_GRE(:,:))
    tp%XCPL_CALVGRE(:,:) = tp%XCPL_CALVGRE(:,:) + pcalving(:,:) * ptstep_run / tpg%XAREA(:,:)
  ENDWHERE
  WHERE(tpg%GMASK_ANT(:,:))
    tp%XCPL_CALVANT(:,:) = tp%XCPL_CALVANT(:,:) + pcalving(:,:) * ptstep_run / tpg%XAREA(:,:)
  ENDWHERE
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       2.      Actualisation of land coupling diagnostic:
!               -------------------------------------------
!
IF(lcpl_land)THEN
!
! Water table depth (negative above the surface) and fraction of water table to rise
!
  IF(lcpl_gw)THEN
    WHERE(tpg%GMASK_GW(:,:))
          tp%XCPL_WTD (:,:) = pwtd(:,:)
          tp%XCPL_FWTD(:,:) = pfwtd(:,:)
    ELSEWHERE(tpg%GMASK(:,:))
          tp%XCPL_WTD (:,:) = xundef
          tp%XCPL_FWTD(:,:) = 0.0
    ENDWHERE
  ENDIF
!
! Flood fraction [-] and potential infiltration [kg/m2]
!       
  IF(lcpl_flood)THEN
    tp%XCPL_FFLOOD (:,:) = tp%XFFLOOD    (:,:)
    tp%XCPL_PIFLOOD(:,:) = tp%XFLOOD_STO (:,:) / tpg%XAREA(:,:)             
  ENDIF
!  
ENDIF
!
IF (lhook) CALL dr_hook('TRIP_DIAG_CPL_ESM',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE trip_diag_cpl_esm