trip.F90

Go to the documentation of this file.

!     #########
      SUBROUTINE trip (KLISTING,HGROUNDW,OFLOOD,OPRINT,PTSTEP,            &
                         KGRCN,KSEQ,KNEXTX,KNEXTY,KSEQMAX,PAREA,PLEN,     &
                         OMASK_GW,OMASK_VEL,OMASK_FLD,                    &
                         PTAUG,PFLOOD_LEN,PSLOPEBED,PWIDTH,PN,            &
                         PN_FLOOD,PHC_BED,PWFLOOD,PTAB_F,PTAB_H,PTAB_VF,  &
                         PDRAIN,PRUNOFF,PSOURCE,PHS,PVEL,                 &
                         PGROUND_STO,PSURF_STO,                           &
                         PFLOOD_STO,PSOUT,PGOUT,PHFLOOD,                  &
                         PFFLOOD,PQFR,PQRF,PVFIN,PVFOUT,                  &
                         PHSF,PSIN,KTRIP,KTSEPT,KTSTEP_END,               &  
                         PGSTO_ALL,PGSTO2_ALL,PGIN_ALL,PGOUT_ALL,         &
                         PHGROUND,PWEFF                                   )
!     ###################################################################
!
!!****  *TRIP*  
!!
!!    PURPOSE
!!    -------
!
!     TRIP river routing and Floodplains schemes.
!     
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/02/05 
!!      Modif.      28/05/08 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_trip_par, ONLY : xrholw,xsea,xyear
!
USE modi_trip_gw_buffer_tank
USE modi_trip_surface_water
USE modi_trip_surface_flood
!
USE modi_trip_update_and_conserv
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
INTEGER, INTENT(IN)                  :: KLISTING
INTEGER, INTENT(IN)                  :: KTRIP
INTEGER, INTENT(IN)                  :: KTSEPT
INTEGER, INTENT(IN)                  :: KTSTEP_END
!
 CHARACTER(LEN=3), INTENT(IN)         :: HGROUNDW !Groundwater scheme key
!
LOGICAL, INTENT(IN)                  :: OFLOOD   !Flood scheme key
LOGICAL, INTENT(IN)                  :: OPRINT   !Printable budget key 
!
REAL, INTENT(IN)                     :: PTSTEP   !Trip timestep
!
INTEGER, INTENT(IN)                  :: KSEQMAX  !maximum down flow
INTEGER, DIMENSION(:,:),INTENT(IN)   :: KGRCN    !Flow direction (1->8)
INTEGER, DIMENSION(:,:),INTENT(IN)   :: KSEQ     !River sequence
INTEGER, DIMENSION(:,:),INTENT(IN)   :: KNEXTX   !returns x and y point
INTEGER, DIMENSION(:,:),INTENT(IN)   :: KNEXTY   !of destination grid
!
LOGICAL, DIMENSION(:,:), INTENT(IN)  :: OMASK_GW   !Groundwater mask
LOGICAL, DIMENSION(:,:), INTENT(IN)  :: OMASK_VEL  !Variable velocity mask
LOGICAL, DIMENSION(:,:), INTENT(IN)  :: OMASK_FLD  !Floodplain mask
!
REAL,DIMENSION(:,:), INTENT(IN)      :: PTAUG      ! ground water transfer time  [s]
REAL,DIMENSION(:,:), INTENT(IN)      :: PLEN       ! river length       [m] 
REAL,DIMENSION(:,:), INTENT(IN)      :: PSLOPEBED  ! river bed slopes             [m/m]
REAL,DIMENSION(:,:), INTENT(IN)      :: PWIDTH     ! river widths                 [m]
REAL,DIMENSION(:,:), INTENT(IN)      :: PN         ! Manning roughness coeficient [-] (0.03 to 0.065)
REAL,DIMENSION(:,:), INTENT(IN)      :: PN_FLOOD   ! Manning coeficient over floodplains   [-] (0.1)
REAL,DIMENSION(:,:), INTENT(IN)      :: PHC_BED    ! River bed depth              [m]
REAL,DIMENSION(:,:), INTENT(IN)      :: PSOURCE    ! precip-infiltration-evaporation [kg/s]
REAL,DIMENSION(:,:), INTENT(IN)      :: PAREA      ! Grid-cell area    [m2]
REAL,DIMENSION(:,:), INTENT(IN)      :: PDRAIN     ! Subsurface runoff from ISBA [kg/s]
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PRUNOFF    ! Surface runoff from ISBA    [kg/s]
!
REAL,DIMENSION(:,:), INTENT(IN)      :: PHS   ! River height [m]
REAL,DIMENSION(:,:), INTENT(IN)      :: PVEL  ! River channel velocity  [m/s]
!
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PHFLOOD    ! Floodplain water depth       [m]
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PWFLOOD    ! Floodplain width             [m]
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PFLOOD_LEN ! Floodplain length along the river [m]
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PFFLOOD    ! Fraction of flood [-]
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PSURF_STO  ! river channel storage at t    [kg]
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PGROUND_STO! groundwater storage at t    [kg]
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PFLOOD_STO ! Floodplain water storage at t [kg]
!
REAL,DIMENSION(:,:), INTENT(OUT)     :: PSOUT ! Outflow from the surface river reservoir [kg/s]
REAL,DIMENSION(:,:), INTENT(OUT)     :: PSIN  ! Inflow to the surface river reservoir [kg/s]
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PGOUT ! ground water outflow        [kg/s]
REAL,DIMENSION(:,:), INTENT(OUT)     :: PQFR  ! Flood flow to river
REAL,DIMENSION(:,:), INTENT(OUT)     :: PQRF  ! River flow to floodplain
!
REAL,DIMENSION(:,:), INTENT(OUT)     :: PVFIN ! River flow to flood velocity [m/s]
REAL,DIMENSION(:,:), INTENT(OUT)     :: PVFOUT! Flood flow to river velocity [m/s]
REAL,DIMENSION(:,:), INTENT(OUT)     :: PHSF  ! River-Floodplain depth comparison [m]
!
REAL,DIMENSION(:,:,:), INTENT(IN)    :: PTAB_F  ! Flood fraction array
REAL,DIMENSION(:,:,:), INTENT(IN)    :: PTAB_H  ! Topo height array
REAL,DIMENSION(:,:,:), INTENT(IN)    :: PTAB_VF ! Flood volume array
!
REAL,                 INTENT(INOUT)  :: PGSTO_ALL  !Global groundwater storage at t    [kg]
REAL,                 INTENT(INOUT)  :: PGSTO2_ALL !Global groundwater storage at t-1  [kg]
REAL,                 INTENT(INOUT)  :: PGIN_ALL   !Global gw recharge + lateral input [kg/m2/s]
REAL,                 INTENT(INOUT)  :: PGOUT_ALL  !Global gw outflow                  [kg/m2/s]
!
REAL,DIMENSION(:,:), INTENT(INOUT)   :: PHGROUND   ! water table elevation         [m]
REAL,DIMENSION(:,:), INTENT(IN)      :: PWEFF      ! Effective porosity            [-]
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PLEN,1),SIZE(PLEN,2)) :: ZSURF_STO2  ! river channel storage at t+1     [kg]    
REAL, DIMENSION(SIZE(PLEN,1),SIZE(PLEN,2)) :: ZGROUND_STO2! Groundwater storage at t+1       [kg] 
REAL, DIMENSION(SIZE(PLEN,1),SIZE(PLEN,2)) :: ZFLOOD_STO2 ! Floodplain water storage at t+1  [kg] 
REAL, DIMENSION(SIZE(PLEN,1),SIZE(PLEN,2)) :: ZQFR
REAL, DIMENSION(SIZE(PLEN,1),SIZE(PLEN,2)) :: ZQRF
!
REAL    ::   ZFSTO_ALL, ZFSTO2_ALL, ZSOURCE_ALL, ZSSTO_ALL, ZSSTO2_ALL, &
             ZSIN_ALL, ZDRUN_ALL, ZSOUT_ALL, ZVEL_ALL, ZFIN_ALL,        &
             ZFOUT_ALL, ZHS_ALL,ZHF_ALL,ZFF_ALL, ZRECUP_ALL 
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
! * Init
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP',0,zhook_handle)
!
zfsto_all   = 0.0
zfsto2_all  = 0.0
zsource_all = 0.0
zssto_all   = 0.0
zssto2_all  = 0.0
zsin_all    = 0.0
zdrun_all   = 0.0
zsout_all   = 0.0
zvel_all    = 0.0
zfin_all    = 0.0
zfout_all   = 0.0
zhs_all     = 0.0
zhf_all     = 0.0
zff_all     = 0.0
zrecup_all  = 0.0
!
zsurf_sto2(:,:) = 0.0
zground_sto2(:,:) = 0.0
zflood_sto2(:,:) = 0.0
!
zqfr(:,:) = 0.0
zqrf(:,:) = 0.0
!
!-------------------------------------------------------------------------------
! *  Ground water storage
!-------------------------------------------------------------------------------
!
IF(hgroundw=='DEF')THEN
!
   pgout(:,:)=max(pdrain(:,:),0.0)
!
ELSEIF(hgroundw=='CST')THEN
!        
  CALL trip_gw_buffer_tank(ptstep,oprint,parea,omask_gw,pground_sto,zground_sto2,    &
                           pdrain,ptaug,pgout,pgsto_all,pgsto2_all,pgin_all,pgout_all)  
!
ENDIF
!
!-------------------------------------------------------------------------------
! * Floodplains storage
!-------------------------------------------------------------------------------
!
IF(oflood)THEN    
!        
   CALL trip_surface_flood(klisting,ptstep,oprint,omask_fld,        &
                           ptab_f,ptab_h,ptab_vf,parea,pvel,        &
                           plen,pwidth,pn_flood,phc_bed,            &
                           phs,psurf_sto,pflood_sto,psource,        &
                           zflood_sto2,phflood,pfflood,pflood_len,  &
                           pwflood,pqfr,pqrf,pvfin,pvfout,phsf,     &
                           zfsto_all,zfsto2_all,zsource_all,        &
                           zfin_all,zfout_all,zhf_all,zff_all       )
!
   zqfr(:,:) = pqfr(:,:)
   zqrf(:,:) = pqrf(:,:)
!
ENDIF
!
!-------------------------------------------------------------------------------
! * Surface water storage
!-------------------------------------------------------------------------------
!       
 CALL trip_surface_water(klisting,ptstep,kgrcn,kseq,knextx,knexty,kseqmax, &
                        oprint,omask_vel,plen,prunoff,                    &
                        pvel,phs,psurf_sto,zsurf_sto2,pgout,psin,psout,   &
                        parea,zqfr,zqrf,                                  &
                        zssto_all,zssto2_all,zsin_all,zdrun_all,          &
                        zsout_all,zvel_all,zhs_all                        )
!
!-------------------------------------------------------------------------------
! * Update all reservoir and conserve water mass as possible
!-------------------------------------------------------------------------------
!
 CALL trip_update_and_conserv(oprint,oflood,hgroundw,parea,pweff,   &
                             zsurf_sto2,zflood_sto2,zground_sto2,  &
                             psurf_sto,pflood_sto,pground_sto,     &
                             omask_gw,phground,zrecup_all          )
!
!-------------------------------------------------------------------------------
! * Writting the budget
!-------------------------------------------------------------------------------
!
IF(oprint.AND.ktrip==1.AND.ktsept==1)THEN
!
  WRITE(klisting,*)''
  WRITE(klisting,*)'        START RUN ISBA-TRIP-FP     '
  WRITE(klisting,*)'          Budget en  kg/m2         '
  WRITE(klisting,*)''
  WRITE(klisting,'(a90)')'RUN TSTEP   S_err    F_err  G_err    MR(mm/y) Vel(m/s)     Hs       Hf        Ff    UNCSV'
  WRITE(klisting,*)''
!  
ENDIF
!
IF(oprint) THEN
!
    WRITE(klisting,'(i3,1x,i3,3(2x,g8.2),f8.2,f8.2,8(2x,f8.3))')         &
    ktrip,ktsept,                                                        &
!   surface budget S_err
    (zssto_all-zssto2_all)+ptstep*(zsin_all-zsout_all),                  &
!   floodplains budget F_err
    (zfsto_all-zfsto2_all)+ptstep*(zsource_all+zfin_all-zfout_all),      &
!   ground budget G_err
    (pgsto_all-pgsto2_all)+ptstep*(pgin_all-pgout_all),                  &
!   output flow to the sea, MR(mm/y) 
    (zssto_all-zssto2_all +ptstep*zdrun_all)/xsea*xyear*REAL(KTSTEP_END),&
!   mean flow velocity, Vel(m/s), and mean stream depth, Hs (m) 
!   mean floddplains depth, Hf (m), and mean flood fraction, Ff (%) 
    zvel_all,zhs_all,zhf_all,100.*zff_all,zrecup_all
!    
ENDIF
!
IF (lhook) CALL dr_hook('TRIP',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
END SUBROUTINE trip