trip_gw_buffer_tank.F90

Go to the documentation of this file.

!     #########
      SUBROUTINE trip_gw_buffer_tank(PTSTEP,OPRINT,PAREA,OMASK_GW,PGROUND_STO,PGROUND_STO2,     &
                                     PDRAIN,PTAUG,PGOUT,PGSTO_ALL,PGSTO2_ALL,PGIN_ALL,PGOUT_ALL )  
!     #############################################################################
!
!!****  *TRIP_GW_BUFFER_TANK*  
!!
!!    PURPOSE
!!    -------
!
!     Calculate the storage in the next time step based on the storage
!     of current time step. The deep drainage is constant during the time step.
!
!     
!!**  METHOD
!!    ------
!
!     Direct calculation
!
!!    EXTERNAL
!!    --------
!
!     None
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/02/05 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modd_trip_par, ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, INTENT(IN)                     :: PTSTEP
!                                       KTSTEP = timestep value (=FRC) [s]
!                                              = 10800s
!
LOGICAL, INTENT(IN)                  :: OPRINT   !Printable budget key 
!
REAL,    DIMENSION(:,:), INTENT(IN)  :: PAREA      ! Grid-cell area    [m²]
LOGICAL, DIMENSION(:,:), INTENT(IN)  :: OMASK_GW   !Groundwater mask
!
REAL, DIMENSION(:,:), INTENT(IN)     :: PDRAIN, PTAUG
!                                       PDRAIN  = Surface runoff from ISBA    [kg/s]
!                                       PTAUG   = ground water transfer time  [s]
!
REAL, DIMENSION(:,:), INTENT(IN   )  :: PGROUND_STO
REAL, DIMENSION(:,:), INTENT(INOUT)  :: PGROUND_STO2
!                                       PGROUND_STO  = ground water storage at t    [kg]
!                                       PGROUND_STO2 = ground water storage at t+1  [kg]
!
REAL, DIMENSION(:,:), INTENT(OUT)    :: PGOUT
!                                       PGOUT = Outflow from the ground reservoir  
!
REAL,                 INTENT(OUT)    :: PGSTO_ALL,PGSTO2_ALL,PGIN_ALL,PGOUT_ALL
!                                       Final budget variable
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PGROUND_STO,1),SIZE(PGROUND_STO,2)) :: ZGSTOMAX
REAL, DIMENSION(SIZE(PGROUND_STO,1),SIZE(PGROUND_STO,2)) :: ZGOUT
REAL, DIMENSION(SIZE(PGROUND_STO,1),SIZE(PGROUND_STO,2)) :: ZDRAIN
REAL, DIMENSION(SIZE(PGROUND_STO,1),SIZE(PGROUND_STO,2)) :: ZDRAIN_NEG
!
INTEGER :: ILON, ILAT, JLON, JLAT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_GW_BUFFER_TANK',0,zhook_handle)
!
ilon = SIZE(parea,1)
ilat = SIZE(parea,2)
!
pground_sto2(:,:) = 0.0
pgout(:,:) = 0.0
!
zgstomax(:,:) = 0.0
zgout(:,:) = 0.0
!
zdrain(:,:) = max(0.0,pdrain(:,:))
zdrain_neg(:,:) = min(0.0,pdrain(:,:))
!
!-------------------------------------------------------------------------------
! * Groundwater case
!-------------------------------------------------------------------------------
!
DO jlat=1,ilat
   DO jlon=1,ilon
!   
      IF(omask_gw(jlon,jlat))THEN
!
!       ground water storage calculation dG/dt = Drain - G/tau
        pground_sto2(jlon,jlat) = pground_sto(jlon,jlat)*exp(-ptstep/ptaug(jlon,jlat)) &
                                + (1.0-exp(-ptstep/ptaug(jlon,jlat)))*zdrain(jlon,jlat)&
                                * ptaug(jlon,jlat)  
!
!       supress numerical artifacs
        zgstomax(jlon,jlat)=pground_sto(jlon,jlat)+zdrain(jlon,jlat)*ptstep      
        pground_sto2(jlon,jlat)=min(zgstomax(jlon,jlat),pground_sto2(jlon,jlat))
!
!       ground water discharge calculation                
        zgout(jlon,jlat)=(pground_sto(jlon,jlat)-pground_sto2(jlon,jlat))/ptstep+zdrain(jlon,jlat)
!      
!       supress numerical artifacs
        pgout(jlon,jlat)=max(0.0,zgout(jlon,jlat))
        pground_sto2(jlon,jlat) = pground_sto2(jlon,jlat) + (pgout(jlon,jlat)-zgout(jlon,jlat))
!      
!       account for negative drainage
        pground_sto2(jlon,jlat) = pground_sto2(jlon,jlat) + zdrain_neg(jlon,jlat)*ptstep
!        
     ENDIF
!     
   ENDDO
ENDDO        
!
!-------------------------------------------------------------------------------
! * No groundwater case
!-------------------------------------------------------------------------------
!
WHERE(.NOT.omask_gw(:,:)) pgout(:,:)=zdrain(:,:)
!
!-------------------------------------------------------------------------------
! * Budget calculation
!-------------------------------------------------------------------------------
!
IF(oprint)THEN
!
  pgsto_all  = 0.0
  pgsto2_all = 0.0
  pgin_all   = 0.0
  pgout_all  = 0.0
!
  WHERE(omask_gw(:,:)) zdrain(:,:)=zdrain(:,:)+zdrain_neg(:,:)
!
  DO jlat=1,ilat
     DO jlon=1,ilon
        IF(omask_gw(jlon,jlat))THEN
          pgsto_all  = pgsto_all  + pground_sto(jlon,jlat) / parea(jlon,jlat)
          pgsto2_all = pgsto2_all + pground_sto2(jlon,jlat) / parea(jlon,jlat)
          pgin_all   = pgin_all   + zdrain(jlon,jlat) / parea(jlon,jlat)
          pgout_all  = pgout_all  + pgout(jlon,jlat) / parea(jlon,jlat)
        ENDIF
     ENDDO
  ENDDO
!
ENDIF
!
IF (lhook) CALL dr_hook('TRIP_GW_BUFFER_TANK',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!-------------------------------------------------------------------------------
END SUBROUTINE trip_gw_buffer_tank