trip_diag.F90

Go to the documentation of this file.

SUBROUTINE trip_diag(TPDG, TP, TPG, &
                     PTSTEP,PSOUT,PSIN,PVEL,PHS,PGOUT,PGNEG,    &
                     PWTD,PFWTD,PQGCELL,PHGHS,                  &
                     PQFR,PQRF,PVFIN,PVFOUT,PHSF,PSRC_FLOOD,    &
                     PDRAIN,PRUNOFF,PDISCHARGE                  )  
!     #####################################################
!
!!****  *TRIP_DIAG*  
!!
!!    PURPOSE
!!    -------
!
!     TRIP diag compuation
!     
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    12/12/13 
!!      09/16   B. Decharme  limit wtd to -1000m
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE modd_trip_diag, ONLY : trip_diag_t
USE modd_trip, ONLY : trip_t
USE modd_trip_grid, ONLY : trip_grid_t
!
USE modn_trip_run,   ONLY : ldiag_misc
USE modd_trip_oasis, ONLY : lcpl_land
!
USE modn_trip,       ONLY : cgroundw, cvit, lflood
!
USE modd_trip_par,   ONLY : xrholw, xgwdzmax
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(trip_diag_t), INTENT(INOUT) :: TPDG
TYPE(trip_t), INTENT(INOUT) :: TP
TYPE(trip_grid_t), INTENT(INOUT) :: TPG
!
REAL,                 INTENT(IN)  :: PTSTEP     !Time step                     [s]
!
REAL, DIMENSION(:,:), INTENT(IN)  :: PSOUT      !streamflow                    [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PSIN       !grid-cell input streamflow    [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PVEL       !river velocity                [m/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PHS        !River heigh                   [m]
REAL, DIMENSION(:,:), INTENT(IN)  :: PGOUT      !Groundwater outflow           [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PGNEG      !Groundwater intflow (neg)     [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PWTD       !Water table depth for coupling[m]
REAL, DIMENSION(:,:), INTENT(IN)  :: PFWTD      !Fraction of water table to rise
REAL, DIMENSION(:,:), INTENT(IN)  :: PQGCELL    !lateral groundwater exchanges [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PHGHS      !groundwater minus river heigh [m]
REAL, DIMENSION(:,:), INTENT(IN)  :: PQFR       !floodplains to river exchange [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PQRF       !river to floodplains exchange [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PVFIN      !QRF velocity                  [m/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PVFOUT     !QFR velocity                  [m/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PHSF       !river minus flodd heigh       [m]
REAL, DIMENSION(:,:), INTENT(IN)  :: PSRC_FLOOD !P-E-I flood source term       [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PDRAIN     !Input drainage or recharge    [kg/s]
REAL, DIMENSION(:,:), INTENT(IN)  :: PRUNOFF    !Input surface runoff          [kg/s]
!
REAL, DIMENSION(:,:), INTENT(OUT) :: PDISCHARGE !Cumulated river discharges    [kg]
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PSOUT,1),SIZE(PSOUT,2)) :: ZGROUND_STO
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_DIAG',0,zhook_handle)
!
! * Actualisation of river discharge diags
!       
pdischarge(:,:) = pdischarge(:,:) + psout(:,:) * ptstep          ![kg]
tpdg%TDIAG%XQDIS(:,:) = tpdg%TDIAG%XQDIS(:,:) + psout(:,:) * ptstep / xrholw ![m3]
!
! * Actualisation of input total flux in the river   
!   
IF(ldiag_misc)THEN
  tpdg%TDIAG%XQIN(:,:) = tpdg%TDIAG%XQIN (:,:) + psin(:,:) * ptstep / xrholw
ENDIF
!
! * Actualisation of input surface runoff and drainage (or recharge)
!
IF(lcpl_land.AND.ldiag_misc)THEN
  tpdg%TDIAG%XRUNOFF(:,:) = tpdg%TDIAG%XRUNOFF(:,:) + prunoff(:,:) * ptstep / tpg%XAREA(:,:)
  tpdg%TDIAG%XDRAIN (:,:) = tpdg%TDIAG%XDRAIN (:,:) + pdrain(:,:) * ptstep / tpg%XAREA(:,:)
ENDIF
!
! * Actualisation of stream reservoir
!
tpdg%TDIAG%XSURF_STO(:,:) = tpdg%TDIAG%XSURF_STO(:,:) + tp%XSURF_STO(:,:) * ptstep / tpg%XAREA(:,:)
!
! * Actualisation of variable velocity diagnostic variables   
!
IF(cvit=='VAR')THEN
   tpdg%TDIAG%XVEL(:,:) = tpdg%TDIAG%XVEL(:,:) + pvel(:,:) * ptstep
   tpdg%TDIAG%XHS (:,:) = tpdg%TDIAG%XHS (:,:) + phs(:,:) * ptstep
ENDIF
!
! * Actualisation of groundwater diagnostic variables   
!   
IF(cgroundw/='DEF')THEN
  tpdg%TDIAG%XQGF(:,:) = tpdg%TDIAG%XQGF(:,:) + (pgout(:,:)+pgneg(:,:)) * ptstep / xrholw
ENDIF
!  
IF(cgroundw=='CST')THEN  
!
  tpdg%TDIAG%XGROUND_STO(:,:) = tpdg%TDIAG%XGROUND_STO(:,:) + tp%XGROUND_STO(:,:) * ptstep / tpg%XAREA(:,:)
!
ELSEIF(cgroundw=='DIF')THEN
!
  zground_sto(:,:) = (xgwdzmax+pwtd(:,:)) * tp%XWEFF(:,:) * xrholw
!
  tpdg%TDIAG%XGROUND_STO(:,:) = tpdg%TDIAG%XGROUND_STO(:,:) + zground_sto(:,:) * ptstep 
  tpdg%TDIAG%XHGROUND   (:,:) = tpdg%TDIAG%XHGROUND   (:,:) + tp%XHGROUND   (:,:) * ptstep
  tpdg%TDIAG%XWTD       (:,:) = tpdg%TDIAG%XWTD       (:,:) + pwtd(:,:) * ptstep
  tpdg%TDIAG%XFWTD      (:,:) = tpdg%TDIAG%XFWTD      (:,:) + pfwtd(:,:) * ptstep
  IF(ldiag_misc)THEN
    tpdg%TDIAG%XQGCELL (:,:) = tpdg%TDIAG%XQGCELL (:,:) + pqgcell(:,:) * ptstep / xrholw
    tpdg%TDIAG%XHGHS   (:,:) = tpdg%TDIAG%XHGHS   (:,:) + phghs(:,:) * ptstep
  ENDIF 
!
ENDIF
!
! * Actualisation of flooding scheme diagnostic variables   
!
IF(lflood)THEN          
   tpdg%TDIAG%XFLOOD_STO(:,:) = tpdg%TDIAG%XFLOOD_STO(:,:) + tp%XFLOOD_STO(:,:) * ptstep / tpg%XAREA(:,:)
   tpdg%TDIAG%XFF       (:,:) = tpdg%TDIAG%XFF       (:,:) + tp%XFFLOOD   (:,:) * ptstep
   tpdg%TDIAG%XHF       (:,:) = tpdg%TDIAG%XHF       (:,:) + tp%XHFLOOD   (:,:) * ptstep
   IF(ldiag_misc)THEN
     tpdg%TDIAG%XQFR   (:,:) = tpdg%TDIAG%XQFR   (:,:) + pqfr(:,:) * ptstep / xrholw
     tpdg%TDIAG%XQRF   (:,:) = tpdg%TDIAG%XQRF   (:,:) + pqrf(:,:) * ptstep / xrholw
     tpdg%TDIAG%XVFIN  (:,:) = tpdg%TDIAG%XVFIN  (:,:) + pvfin(:,:) * ptstep
     tpdg%TDIAG%XVFOUT (:,:) = tpdg%TDIAG%XVFOUT (:,:) + pvfout(:,:) * ptstep
     tpdg%TDIAG%XWF    (:,:) = tpdg%TDIAG%XWF    (:,:) + tp%XWFLOOD      (:,:) * ptstep
     tpdg%TDIAG%XLF    (:,:) = tpdg%TDIAG%XLF    (:,:) + tp%XFLOOD_LEN   (:,:) * ptstep
     tpdg%TDIAG%XHSF   (:,:) = tpdg%TDIAG%XHSF   (:,:) + phsf(:,:) * ptstep
     tpdg%TDIAG%XSOURCE(:,:) = tpdg%TDIAG%XSOURCE(:,:) + psrc_flood(:,:) * ptstep / tpg%XAREA(:,:)
   ENDIF  
ENDIF
!
IF (lhook) CALL dr_hook('TRIP_DIAG',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE trip_diag