trip_hs_vel.F90

Go to the documentation of this file.

!     #########
SUBROUTINE trip_hs_vel (PTSTEP,OMASK_VEL,PLEN,PWIDTH,PSLOPEBED,PN,PSURF_STO,PHS,PVEL)
!     ################################################################
!
!!****  *TRIP_HS_VEL*  
!!
!!    PURPOSE
!!    -------
!
!     Calculate the river height and velocity 
!     Where OMASK_VEL=true the Manning equation is used
!
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!
!     None
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/02/09 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
USE modn_trip,     ONLY : cvit, xcvel
USE modd_trip_par, ONLY : xundef, xm, xvelmin, &
                          xhsmin, xrholw
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abort_trip
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
REAL, INTENT(IN)                     :: PTSTEP ! Trip timestep value (10800s)
!
LOGICAL, DIMENSION(:,:), INTENT(IN)    :: OMASK_VEL  ! Variable velocity mask
REAL,    DIMENSION(:,:), INTENT(IN)    :: PLEN       ! river length       [m] 
REAL,    DIMENSION(:,:), INTENT(IN)    :: PWIDTH     ! river widths                 [m]
REAL,    DIMENSION(:,:), INTENT(IN)    :: PSLOPEBED  ! river bed slopes             [m/m]
REAL,    DIMENSION(:,:), INTENT(IN)    :: PN         ! Manning roughness coeficient [-] (0.03 to 0.065)
REAL,    DIMENSION(:,:), INTENT(IN)    :: PSURF_STO  ! river channel storage at t  [kg]
REAL,    DIMENSION(:,:), INTENT(OUT)   :: PHS   ! river channel height [m]
REAL,    DIMENSION(:,:), INTENT(OUT)   :: PVEL  ! River channel velocity  [m/s]
!
!*      0.2    declarations of local variables
!
REAL, PARAMETER :: ZLOG_MIN = 1.e-12
!
REAL, DIMENSION(SIZE(PLEN,1),SIZE(PLEN,2)) :: ZRADIUS
REAL, DIMENSION(SIZE(PLEN,1),SIZE(PLEN,2)) :: ZHS
REAL, DIMENSION(SIZE(PLEN,1),SIZE(PLEN,2)) :: ZVEL
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
! * Init
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_HS_VEL',0,zhook_handle)
!
zradius(:,:) = 0.0
zvel(:,:) = 0.0
zhs(:,:) = 0.0
!
!-------------------------------------------------------------------------------
! * River channel velocity             
!-------------------------------------------------------------------------------
!
!Constant streamflow velocity
phs(:,:)=xundef
pvel(:,:)=xcvel
!
IF(cvit == 'VAR')THEN
  WHERE(omask_vel(:,:))       
      !Variable streamflow velocity
      phs(:,:)=psurf_sto(:,:)/(xrholw*plen(:,:)*pwidth(:,:))
      zhs(:,:)=max(phs(:,:),zlog_min)
      zradius(:,:)=log(pwidth(:,:)*zhs(:,:)/(pwidth(:,:)+2.0*zhs(:,:)))
      zvel(:,:)=exp(xm*zradius(:,:))*sqrt(pslopebed(:,:))/pn(:,:)
      zvel(:,:)=max(xvelmin,zvel(:,:))
      zvel(:,:)=min(zvel(:,:),plen(:,:)/ptstep)
      !Velocity limitation if the river is very dry
      pvel(:,:)=zvel(:,:)*min(1.0,max(0.0,(phs(:,:)-xhsmin))/xhsmin)
  ENDWHERE
ENDIF
!
IF (lhook) CALL dr_hook('TRIP_HS_VEL',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE trip_hs_vel