trip_restart.F90

Go to the documentation of this file.

!#########
SUBROUTINE trip_restart (TP, TPG, &
                         KLISTING,KYEAR,KMONTH,KDAY,PTIME,KLON,KLAT)
!############################################
!
!!****  *TRIP_RESTART*  
!!
!!    PURPOSE
!!    -------
!
!     TRIP river routing restart.
!     
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    28/05/05 
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE modd_trip, ONLY : trip_t
USE modd_trip_grid, ONLY : trip_grid_t
!
USE mode_rw_trip
!
USE modn_trip,      ONLY : cgroundw, lflood
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(trip_t), INTENT(INOUT) :: TP
TYPE(trip_grid_t), INTENT(INOUT) :: TPG
!
INTEGER, INTENT(IN)             :: KLISTING
INTEGER, INTENT(IN)             :: KYEAR
INTEGER, INTENT(IN)             :: KMONTH
INTEGER, INTENT(IN)             :: KDAY
REAL,    INTENT(IN)             :: PTIME
INTEGER, INTENT(IN)             :: KLON
INTEGER, INTENT(IN)             :: KLAT
!
!*      0.2    declarations of local variables
!
LOGICAL,           PARAMETER :: LDOUBLE=.true.
!
 CHARACTER(LEN=15), PARAMETER :: YFILE ='TRIP_RESTART.nc'
 CHARACTER(LEN=20)            :: YVNAME
!
LOGICAL,DIMENSION(KLON,KLAT) :: LMASK
LOGICAL,DIMENSION(KLON,KLAT) :: LMASK_GW
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
! * Store output in diag file
!
IF (lhook) CALL dr_hook('TRIP_RESTART',0,zhook_handle)
!
! * Current date
!
 CALL write_trip_date(klisting,yfile,kyear,kmonth,kday,ptime)
!
! * Trip mask
!
lmask(:,:) = tpg%GMASK(:,:)
!
! * Groundwater specific mask
!
IF(cgroundw/='DEF')THEN
  lmask_gw(:,:) = tpg%GMASK_GW(:,:)        
ENDIF
!
! * Write variables
!
yvname = 'SURF_STO'
 CALL write_trip(klisting,yfile,yvname,lmask,tp%XSURF_STO,odouble=ldouble)
!
IF(cgroundw=='CST')THEN
  yvname = 'GROUND_STO'
  CALL write_trip(klisting,yfile,yvname,lmask_gw,tp%XGROUND_STO,odouble=ldouble)
  ELSEIF(cgroundw=='DIF')THEN
  yvname = 'HGROUND'   
  CALL write_trip(klisting,yfile,yvname,lmask_gw,tp%XHGROUND,odouble=ldouble)
ENDIF
!
IF(lflood)THEN
  yvname = 'FLOOD_STO'
  CALL write_trip(klisting,yfile,yvname,lmask,tp%XFLOOD_STO,odouble=ldouble)           
  yvname = 'FFLOOD'
  CALL write_trip(klisting,yfile,yvname,lmask,tp%XFFLOOD,odouble=ldouble)        
  yvname = 'HFLOOD'
  CALL write_trip(klisting,yfile,yvname,lmask,tp%XHFLOOD,odouble=ldouble)        
ENDIF
!
IF (lhook) CALL dr_hook('TRIP_RESTART',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE trip_restart