read_nam_trip_grid.F90

Go to the documentation of this file.

!     #########
SUBROUTINE read_nam_trip_grid (TPG, &
                               KLISTING)
!############################
!
!!****  *READ_NAM_TRIP_GRID* - routine to read in namelist the TRIP horizontal grid
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    05/2008 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
USE modd_trip_grid, ONLY : trip_grid_t
!
USE modi_trip_posnam
USE modi_abort_trip
USE modi_open_trip_namelist
USE modi_close_trip_namelist
!
USE mode_trip_grid
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(trip_grid_t), INTENT(INOUT) :: TPG
!
INTEGER, INTENT(IN) :: KLISTING
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: ILUNAM ! namelist file  logical unit
INTEGER :: I
LOGICAL :: GFOUND
REAL    :: ZWORK
!
!
!*       0.3   Declarations of namelist
!              ------------------------
!
REAL    :: TLONMIN = 0.  ! minimum longitude (degrees)
REAL    :: TLONMAX = 0.  ! maximum longitude (degrees)
REAL    :: TLATMIN = 0.  ! minimum latitude  (degrees)
REAL    :: TLATMAX = 0.  ! maximum latitude  (degrees)
REAL    :: TRES    = 0.  ! 1deg or 0.5deg resolution
!
REAL, DIMENSION(:), ALLOCATABLE ::  ZLON
REAL, DIMENSION(:), ALLOCATABLE ::  ZLAT
!
INTEGER :: ILON,ILAT
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
NAMELIST/nam_trip_grid/tlonmin, tlonmax, tlatmin, tlatmax, tres
!
!------------------------------------------------------------------------------
!
!*       1.    opening of namelist
! 
IF (lhook) CALL dr_hook('READ_NAM_TRIP_GRID',0,zhook_handle)
!
 CALL open_trip_namelist(ilunam)
!
!---------------------------------------------------------------------------
!
!*       2.    Reading of projection parameters
!              --------------------------------
!
 CALL trip_posnam(ilunam,'NAM_TRIP_GRID',gfound,klisting)
IF (gfound) THEN
   READ(unit=ilunam,nml=nam_trip_grid)
ELSE
   WRITE(klisting,*)'READ_NAM_TRIP_GRID: NAM_TRIP_GRID not found in namelist'
   CALL abort_trip('READ_NAM_TRIP_GRID: NAM_TRIP_GRID not found in namelist')
ENDIF        
!
 CALL close_trip_namelist(ilunam)
!
IF(tres/=0.5.AND.tres/=1.0)THEN
  IF(tres<0.08.OR.tres>0.09)THEN
    WRITE(klisting,*)'Error : The resolution of the TRIP grid must be 1deg or 0.5deg '
    WRITE(klisting,*)'        or 0.083333deg over France                             '
    WRITE(klisting,*)'        In NAM_TRIP_GRID, TRES should be 0.083333 or 0.5 or 1. '
    CALL abort_trip('READ_NAM_TRIP_GRID: The resolution of the TRIP grid must be 1deg or 0.5deg or 0.083333deg')
  ELSE
    tres=REAL(nint(tres*12.))/12.    
  ENDIF
ENDIF
!
!---------------------------------------------------------------------------
!
!*       3.    Number of lattitude and longitude
!
ilon = int((tlonmax-tlonmin)/tres)
ilat = int((tlatmax-tlatmin)/tres)
!
!---------------------------------------------------------------------------
!
!*       4.    lattitude and longitude values
!
ALLOCATE(zlon(ilon))
ALLOCATE(zlat(ilat))
!
zwork = tlonmin-(tres/2.)
DO i=1,ilon
   zwork   = zwork + tres
   zlon(i) = zwork
ENDDO
!
zwork =tlatmin-(tres/2.)
DO i=1,ilat
   zwork   = zwork + tres
   zlat(i) = zwork
ENDDO
!
!---------------------------------------------------------------------------
!
!*       5.    All this information stored into PTRIP_GRID
!              -------------------------------------------
!
ALLOCATE(tpg%XTRIP_GRID(7+ilon+ilat))
tpg%XTRIP_GRID(:) = 0.0
!
 CALL put_trip_grid(tpg%XTRIP_GRID,tlonmin,tlonmax,tlatmin,tlatmax,tres,ilon,ilat,zlon,zlat)
!
DEALLOCATE(zlon)
DEALLOCATE(zlat)
!
IF (lhook) CALL dr_hook('READ_NAM_TRIP_GRID',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE read_nam_trip_grid