trip_posnam.F90

Go to the documentation of this file.

!!    ##############################################
      SUBROUTINE trip_posnam(KULNAM,HDNAML,OFOUND,KLISTING)
!!    ##############################################
!!
!!*** *TRIP_POSNAM*
!!
!!    PURPOSE
!!    -------
!     To position namelist file at correct place for reading
!     namelist CDNAML.
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENT
!!    -----------------
!!
!!    REFERENCE
!!    ----------
!!       ECMWF Research Department documentation of the IFS (Hamrud)
!!
!!    AUTHOR
!!    -------
!!    I. Mallet  15/10/01 
!!
!!    MODIFICATIONS
!!    --------------
!!       I. Mallet  15/10/01     adaptation to MesoNH (F90 norm)
!------------------------------------------------------------------------------
!
USE modi_abort_trip
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.    DECLARATIONS
!              ------------
!
!*       0.1   Declarations of arguments
!
INTEGER,          INTENT(IN) :: KULNAM
 CHARACTER(LEN=*), INTENT(IN) :: HDNAML
LOGICAL,          INTENT(OUT):: OFOUND
INTEGER, OPTIONAL,INTENT(IN) :: KLISTING
!
!*       0.2   Declarations of local variables
!
 CHARACTER(LEN=120) :: YLINE
 CHARACTER(LEN=1)   :: YLTEST
INTEGER            :: ILEN,ILEY,INDL,IND1,IRET
INTEGER            :: J,JA, JFILE
LOGICAL            :: LLOPENED
!
 CHARACTER(LEN=1),DIMENSION(26) :: YLO=(/'a','b','c','d','e','f','g','h', &
     'i','j','k','l','m','n','o','p','q','r','s','t','u','v','w','x','y','z'/)
 CHARACTER(LEN=1),DIMENSION(26) :: YUP=(/'A','B','C','D','E','F','G','H', &
     'I','J','K','L','M','N','O','P','Q','R','S','T','U','V','W','X','Y','Z'/)
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!*       1.    POSITION FILE
!              -------------
!
IF (lhook) CALL dr_hook('TRIP_POSNAM',0,zhook_handle)
ofound=.false.
ilen=len(hdnaml)
!
!      CONTINUE READING THE FILE, THEN REWIND IF NOT FOUND
DO jfile=1,2
  search_nam : DO
    yline=' '
    READ(unit=kulnam,fmt='(A)',iostat=iret,end=100) yline
!   If file does not exist, most compilers would just create it and jump 
!   to the END label ; but a few of them would report an error:         
    IF (iret /=0 ) THEN                 
      INQUIRE(kulnam,opened=llopened)
      IF (llopened) THEN
        IF (PRESENT(klisting)) &
          WRITE(klisting,fmt=*) 'MODE_POS_TRIP : error reading from unit ',&
                               kulnam,' file ',hdnaml,' line ',yline
        CALL abort_trip('MODE_POS_TRIP: read error in namelist file') 
      ELSE
        EXIT search_nam
      END IF
    ELSE   
!     FIRST SEARCH for "&" IN THE LINE, THEN CORRECT LINE AND TEST :
      indl=index(yline,'&')
      IF (indl .NE. 0 ) THEN
        iley=len(yline)
        DO j=1,iley
          DO ja=1,26
            IF (yline(j:j)==ylo(ja)) yline(j:j)=yup(ja) 
          END DO
        END DO
        ind1=index(yline,'&'//hdnaml)
        IF(ind1.NE.0) THEN
          yltest=yline(ind1+ilen+1:ind1+ilen+1)
          IF(yltest == ' ') THEN
!           NAMELIST FOUND : RETURN
            backspace(kulnam)
            ofound=.true.
            IF (PRESENT(klisting)) WRITE(klisting,fmt=*) '-- namelist ',hdnaml,' read'
            IF (lhook) CALL dr_hook('TRIP_POSNAM',1,zhook_handle)
            RETURN
          ENDIF
        ENDIF
      ENDIF
    ENDIF
  ENDDO search_nam
  100  CONTINUE
  IF(jfile == 1) rewind(kulnam)
ENDDO

backspace(kulnam)
! end of file: namelist name not found
IF (PRESENT(klisting)) &
WRITE(klisting,fmt=*)  &
'-- namelist ',hdnaml,' not found: default values used if required'
IF (lhook) CALL dr_hook('TRIP_POSNAM',1,zhook_handle)
!------------------------------------------------------------------
END SUBROUTINE trip_posnam