mode_trip_grid.F90

Go to the documentation of this file.

!##############################
MODULE mode_trip_grid
!##############################
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
!############################################################################
!############################################################################
!############################################################################
 CONTAINS
!############################################################################
!############################################################################
!############################################################################
!     ####################################################################
      SUBROUTINE put_trip_grid(PTRIP_GRID,PLONMIN,PLONMAX,PLATMIN, &
                                 PLATMAX,PRES,KLON,KLAT,PLON,PLAT    )  
!     ####################################################################
!
!!****  *PUT_TRIP_GRID* - routine to store in PTRIP_GRID the horizontal grid
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    05/2005 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
IMPLICIT NONE
!
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL,               INTENT(IN)  :: PLONMIN  ! minimum longitude
REAL,               INTENT(IN)  :: PLONMAX  ! maximum longitude
REAL,               INTENT(IN)  :: PLATMIN  ! minimum latitude
REAL,               INTENT(IN)  :: PLATMAX  ! maximum latitude
REAL,               INTENT(IN)  :: PRES     ! 1° or 0.5° resolution
INTEGER,            INTENT(IN)  :: KLON     ! number of points in longitude
INTEGER,            INTENT(IN)  :: KLAT     ! number of points in latitude
REAL, DIMENSION(:), INTENT(IN)  :: PLON     ! longitude
REAL, DIMENSION(:), INTENT(IN)  :: PLAT     ! latitude
REAL, DIMENSION(:), INTENT(OUT) :: PTRIP_GRID! parameters defining this grid
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MODE_TRIP_GRID:PUT_TRIP_GRID',0,zhook_handle)
ptrip_grid(1)             = plonmin
ptrip_grid(2)             = plonmax
ptrip_grid(3)             = platmin
ptrip_grid(4)             = platmax
ptrip_grid(5)             = pres
ptrip_grid(6)             = float(klon)
ptrip_grid(7)             = float(klat)
ptrip_grid(8:7+klon)      = plon
ptrip_grid(8+klon:7+klon+klat) = plat
IF (lhook) CALL dr_hook('MODE_TRIP_GRID:PUT_TRIP_GRID',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE put_trip_grid
!############################################################################
!############################################################################
!############################################################################
!     ####################################################################
      SUBROUTINE get_trip_grid(PTRIP_GRID,PLONMIN,PLONMAX,PLATMIN, &
                                 PLATMAX,PRES,KLON,KLAT,PLON,PLAT    )  
!     ####################################################################
!
!!****  *GET_TRIP_GRID* - routine to get from PTRIP_GRID the horizontal grid
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    05/2005 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
IMPLICIT NONE
!
!
!*       0.1   Declarations of arguments
!              -------------------------
!
REAL, DIMENSION(:), INTENT(IN)            :: PTRIP_GRID! parameters defining this grid
REAL,               INTENT(OUT), OPTIONAL :: PLONMIN  ! minimum longitude
REAL,               INTENT(OUT), OPTIONAL :: PLONMAX  ! maximum longitude
REAL,               INTENT(OUT), OPTIONAL :: PLATMIN  ! minimum latitude
REAL,               INTENT(OUT), OPTIONAL :: PLATMAX  ! maximum latitude
REAL,               INTENT(OUT), OPTIONAL :: PRES     ! 1° or 0.5° resolution
INTEGER,            INTENT(OUT), OPTIONAL :: KLON     ! number of points in longitude
INTEGER,            INTENT(OUT), OPTIONAL :: KLAT     ! number of points in latitude
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: PLON     ! longitude
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: PLAT     ! latitude
!
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER :: ILON, ILAT
INTEGER :: IL
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MODE_TRIP_GRID:GET_TRIP_GRID',0,zhook_handle)
ilon = nint(ptrip_grid(6))
ilat = nint(ptrip_grid(7))
!
IF (PRESENT(plonmin))  plonmin = ptrip_grid(1)
IF (PRESENT(plonmax))  plonmax = ptrip_grid(2)
IF (PRESENT(platmin))  platmin = ptrip_grid(3)
IF (PRESENT(platmax))  platmax = ptrip_grid(4)
IF (PRESENT(pres   ))  pres    = ptrip_grid(5)
IF (PRESENT(klon   ))  klon    = ilon
IF (PRESENT(klat   ))  klat    = ilat
IF (PRESENT(plon   ))  plon(:) = ptrip_grid(8:7+ilon)
IF (PRESENT(plat   ))  plat(:) = ptrip_grid(8+ilon:7+ilon+ilat)
IF (lhook) CALL dr_hook('MODE_TRIP_GRID:GET_TRIP_GRID',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE get_trip_grid
!---------------------------------------------------------------------------------
!
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!############################################################################
!
END MODULE mode_trip_grid