trip_oasis_read_nam.F90

Go to the documentation of this file.

!#########
SUBROUTINE trip_oasis_read_nam(KLISTING,PRUNTIME)
!#######################################################
!
!!****  *TRIP_OASIS_READ_NAM* - routine to read the configuration for TRIP-OASIS coupling
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    05/2008 
!!      B. Decharme 10/2016  bug surface/groundwater coupling
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modn_trip_run, ONLY : xtstep_run
!
USE modn_trip, ONLY : lflood, cgroundw
!
USE modn_trip_oasis
USE modd_trip_oasis, ONLY : lcpl_land, lcpl_sea,     &
                            lcpl_gw, lcpl_calving,   &
                            lcpl_flood, lcpl_calvsea
!
USE modi_trip_posnam
USE modi_abort_trip
USE modi_open_trip_namelist
USE modi_close_trip_namelist
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
INTEGER, INTENT(IN)           :: KLISTING
REAL,    INTENT(IN), OPTIONAL :: PRUNTIME
!
!
!*       0.2   Declarations of local parameter
!              -------------------------------
!
INTEGER,          PARAMETER :: KIN   = 1
INTEGER,          PARAMETER :: KOUT  = 0
 CHARACTER(LEN=5), PARAMETER :: YLAND = 'land'
 CHARACTER(LEN=5), PARAMETER :: YSEA  = 'ocean'
!
!
!*       0.3   Declarations of local variables
!              -------------------------------
!
LOGICAL           :: GFOUND         ! Return code when searching namelist
INTEGER           :: INAM           ! logical unit of namelist file
 CHARACTER(LEN=20) :: YKEY
 CHARACTER(LEN=50) :: YCOMMENT
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('TRIP_OASIS_READ_NAM',0,zhook_handle)
!
!
!*       1.     Read namelists and check status :
!               --------------------------------
!
lcpl_land    = .false.
lcpl_calving = .false.
lcpl_gw      = .false.
lcpl_flood   = .false.
lcpl_sea     = .false.
lcpl_calvsea = .false.
!
 CALL open_trip_namelist(inam)
!
 CALL trip_posnam(inam,'NAM_TRIP_LAND_CPL',gfound,klisting)
!
IF (gfound) THEN
   READ(unit=inam,nml=nam_trip_land_cpl)
ELSE
   WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
   WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
   WRITE(klisting,*)'NAM_TRIP_LAND_CPL not found : TRIP not coupled with land surface'
   WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
   WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
ENDIF
!
 CALL trip_posnam(inam,'NAM_TRIP_SEA_CPL',gfound,klisting)
!
IF (gfound) THEN
   READ(unit=inam,nml=nam_trip_sea_cpl)
ELSE
   WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
   WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
   WRITE(klisting,*)'NAM_TRIP_SEA_CPL not found : TRIP not coupled with oceanic model'
   WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
   WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
ENDIF
!
 CALL close_trip_namelist(inam)
!
IF(xtstep_cpl_land>0.0)lcpl_land=.true.
IF(xtstep_cpl_sea >0.0)lcpl_sea =.true.
!
IF(.NOT.lcpl_land.AND..NOT.lcpl_sea)THEN
  CALL abort_trip('TRIP_OASIS_READ_NAM: OASIS USED BUT NAMELIST NOT FOUND')
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       2.     Check status for required field and time step consistency
!               ---------------------------------------------------------
!
! * Land surface variables for Trip - Oasis coupling
!
IF(lcpl_land)THEN
!
  IF(PRESENT(pruntime))THEN
    IF(xtstep_run>xtstep_cpl_land)THEN
       xtstep_run=xtstep_cpl_land
       WRITE(klisting,*)'! XTSTEP_RUN is superiror to  XTSTEP_CPL_LAND     !'     
       WRITE(klisting,*)'! Applied solution : XTSTEP_RUN = XTSTEP_CPL_LAND !'     
    ELSEIF(mod(xtstep_cpl_land,xtstep_run)/=0.)THEN
       WRITE(klisting,*)'! XTSTEP_RUN and XTSTEP_CPL_LAND are not good !!!'     
       WRITE(klisting,*)'! XTSTEP_RUN =',xtstep_run,'XTSTEP_CPL_LAND =',xtstep_cpl_land
       CALL abort_trip('TRIP_OASIS_READ_NAM: XTSTEP_RUN and XTSTEP_CPL_LAND are not good !!!')
    ENDIF
  ENDIF
!
! Land Input variable
!
  ykey  ='CRUNOFF'
  ycomment='Surface runoff'
  CALL check_trip_field(crunoff,ykey,ycomment,yland,kin)
!
  ykey  ='CDRAIN'
  ycomment='Deep drainage'
  CALL check_trip_field(cdrain,ykey,ycomment,yland,kin)
!
! Particular case due to calving case
!
  IF(len_trim(ccalving)>0)THEN
!
    lcpl_calving = .true.
!
    ykey  ='CCALVING'
    ycomment='Calving flux from land glacier'
    CALL check_trip_field(ccalving,ykey,ycomment,yland,kin)
!
  ENDIF
!
! Particular case due to groundwater scheme
!          
  IF(len_trim(cwtd)>0.OR.len_trim(cfwtd)>0)THEN
    lcpl_gw = .true.
  ENDIF
!
  IF(lcpl_gw)THEN
!
!   Output variable
!
    ykey  ='CWTD'
    ycomment='Water table depth'
    CALL check_trip_field(cwtd,ykey,ycomment,yland,kout)
!
    ykey  ='CFWTD'
    ycomment='Fraction of WTD to rise'
    CALL check_trip_field(cfwtd,ykey,ycomment,yland,kout)
!
    IF(cgroundw/='DIF')THEN
      WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
      WRITE(klisting,*)'!!!   Groundwater/surface coupling is asked   !!!'
      WRITE(klisting,*)'!!!   But CGROUNDW /= DIF in NAM_TRIP         !!!'
      WRITE(klisting,*)'!!!   Please check your TRIP_OPTIONS.nam      !!!'
      WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
      CALL abort_trip('TRIP_OASIS_READ_NAM: Groundwater/surface coupling but not groundwater scheme')
    ENDIF
!
  ENDIF
!
! Particular case due to floodplains
!          
  IF(len_trim(csrcflood)>0.OR.len_trim(cfflood)>0.OR.len_trim(cpiflood)>0)THEN
    lcpl_flood = .true.
  ENDIF
!
  IF(lcpl_flood)THEN
!
!   Input variable
!
    ykey  ='CSRCFLOOD'
    ycomment='flood freshwater flux'
    CALL check_trip_field(csrcflood,ykey,ycomment,yland,kin)
!
!   Output variable
!
    ykey  ='CFFLOOD'
    ycomment='Flood fraction'
    CALL check_trip_field(cfflood,ykey,ycomment,yland,kout)
!
    ykey  ='CPIFLOOD'
    ycomment='Flood potential infiltration'
    CALL check_trip_field(cpiflood,ykey,ycomment,yland,kout)
!
    IF(.NOT.lflood)THEN
      WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
      WRITE(klisting,*)'!!!   Floodplains coupling with LSM is asked   !!!'
      WRITE(klisting,*)'!!!   But LFLOOD = FALSE in NAM_TRIP           !!!'
      WRITE(klisting,*)'!!!   Please check your TRIP_OPTIONS.nam       !!!'
      WRITE(klisting,*)'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
      CALL abort_trip('TRIP_OASIS_READ_NAM: Floodplains coupling but not Floodplains scheme')
    ENDIF 
!
  ENDIF
!
ENDIF
!
IF(PRESENT(pruntime))THEN
  IF(mod(pruntime,xtstep_run)/=0.)THEN
    WRITE(klisting,*)'! MOD(PRUNTIME,XTSTEP_RUN)/=0 !!!'     
    WRITE(klisting,*)'! XTSTEP_RUN must be a multiple of $RUNTIME in oasis namcouple !!!' 
    WRITE(klisting,*)'XTSTEP_RUN =',xtstep_run,'$RUNTIME =',pruntime
    CALL abort_trip('TRIP_OASIS_READ_NAM: XTSTEP_RUN must be a multiple of $RUNTIME in oasis namcouple !!!')
  ENDIF
ENDIF
!
! * Sea variables for Trip - Oasis coupling 
!
IF(lcpl_sea)THEN
!
  IF(lcpl_land.AND.mod(xtstep_cpl_sea,xtstep_cpl_land)/=0.)THEN
    WRITE(klisting,*)'! XTSTEP_CPL_LAND and XTSTEP_CPL_SEA are not good !!!'     
    WRITE(klisting,*)'! XTSTEP_CPL_LAND =',xtstep_cpl_land,'XTSTEP_CPL_SEA =',xtstep_cpl_sea
    IF(xtstep_cpl_land>xtstep_cpl_sea) &
    WRITE(klisting,*)'! XTSTEP_CPL_LAND is superiror to XTSTEP_CPL_SEA     !'     
    CALL abort_trip('TRIP_OASIS_READ_NAM: XTSTEP_CPL_LAND and XTSTEP_CPL_SEA are not good !!!')
  ENDIF
!
  IF(PRESENT(pruntime))THEN
    IF(mod(xtstep_cpl_sea,xtstep_run)/=0.)THEN
      WRITE(klisting,*)'! XTSTEP_RUN and XTSTEP_CPL_SEA are not good !!!'     
      WRITE(klisting,*)'! XTSTEP_RUN =',xtstep_run,'XTSTEP_CPL_SEA =',xtstep_cpl_sea
      IF(xtstep_run>xtstep_cpl_sea) &
      WRITE(klisting,*)'! XTSTEP_RUN is superiror to  XTSTEP_CPL_SEA     !'     
      CALL abort_trip('TRIP_OASIS_READ_NAM: XTSTEP_RUN and XTSTEP_CPL_SEA are not good !!!')
    ENDIF
  ENDIF
!
! Sea Output variables
!
  ykey  ='CRIVDIS'
  ycomment='River discharge'
  CALL check_trip_field(crivdis,ykey,ycomment,ysea,kout)
!
! Particular case due to calving case
!
  IF(len_trim(ccalvgre)>0.OR.len_trim(ccalvant)>0)THEN
    lcpl_calvsea=.true.
  ENDIF
!
  IF(lcpl_calvsea)THEN
!
!   Output variable
!
    ykey  ='CCALVGRE'
    ycomment='Calving flux over greenland'
    CALL check_trip_field(ccalvgre,ykey,ycomment,ysea,kout)
!
    ykey  ='CCALVANT'
    ycomment='Calving flux over antarctica'
    CALL check_trip_field(ccalvant,ykey,ycomment,ysea,kout)
!
  ENDIF
!
ENDIF
!
IF (lhook) CALL dr_hook('TRIP_OASIS_READ_NAM',1,zhook_handle)
!
!-------------------------------------------------------------------------------
 CONTAINS
!-------------------------------------------------------------------------------
!
SUBROUTINE check_trip_field(HFIELD,HKEY,HCOMMENT,HTYP,KID)
!
IMPLICIT NONE
!
 CHARACTER(LEN=*), INTENT(IN) :: HFIELD
 CHARACTER(LEN=*), INTENT(IN) :: HKEY
 CHARACTER(LEN=*), INTENT(IN) :: HCOMMENT
 CHARACTER(LEN=*), INTENT(IN) :: HTYP
INTEGER,          INTENT(IN) :: KID
!
 CHARACTER(LEN=20)  :: YWORK
 CHARACTER(LEN=20)  :: YNAMELIST
 CHARACTER(LEN=128) :: YCOMMENT1
 CHARACTER(LEN=128) :: YCOMMENT2
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
IF (lhook) CALL dr_hook('TRIP_OASIS_READ_NAM:CHECK_TRIP_FIELD',0,zhook_handle)
!
IF(len_trim(hfield)==0)THEN
!
  IF(kid==0)THEN
    ywork=trim(htyp)//' - TRIP'
  ELSE
    ywork='TRIP - '//trim(htyp)
  ENDIF
!
  SELECT CASE (htyp)
     CASE('land')
          ynamelist='NAM_TRIP_LAND_CPL'
     CASE('ocean')
          ynamelist='NAM_TRIP_SEA_CPL'
     CASE DEFAULT
          CALL abort_trip('TRIP_OASIS_READ_NAM: TYPE NOT SUPPORTED OR IMPLEMENTD : '//trim(htyp))               
  END SELECT
!
  ycomment1= 'TRIP_OASIS_READ_NAM: '//trim(hcomment)//' is required by '//trim(ywork)//' coupling'
  ycomment2= 'TRIP_OASIS_READ_NAM: Namelist key '//trim(hkey)//' is not in '//trim(ynamelist)
!
  WRITE(klisting,*)trim(ycomment1)
  WRITE(klisting,*)trim(ycomment2)
  CALL abort_trip(ycomment1)
!  
ENDIF
!
IF (lhook) CALL dr_hook('TRIP_OASIS_READ_NAM:CHECK_TRIP_FIELD',1,zhook_handle)
!
END SUBROUTINE check_trip_field
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE trip_oasis_read_nam