trip_oasis_init.F90

Go to the documentation of this file.

SUBROUTINE trip_oasis_init(OOASIS,OXIOS,KLOCAL_COMM,PRUNTIME,LPREP)
!!
!!
!!     PURPOSE
!!     --------
!!
!!     Initialize jointly coupled mode and XIOS communication
!!
!!
!!     METHOD
!!     ------
!!
!!     If XIOS is used, it will init Oasis
!!     OASIS-MCT interface must be initialized before any DR_HOOK call
!!
!!
!!     EXTERNAL
!!     --------
!!
!!     XIOS library
!!
!!     REFERENCE
!!     ---------
!!
!!     S. Valcke et al., 2013: OASIS-MCT User Guide 
!!     CERFACS, Toulouse, France, 50 pp.
!!     https://verc.enes.org/oasis/oasis-dedicated-user-support-1/documentation/oasis3-mct-user-guide
!!
!!     Y.Meurdesoif, 2015 : XIOS ....
!!
!!     AUTHOR
!!     ------
!!
!!     B. Decharme, CNRM
!!
!!     MODIFICATION
!!     --------------
!!
!!     Original    10/2013
!!     09/2016 - S.Senesi - Add XIOS setup
!!
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modn_trip_run, ONLY : cnamelist, cmodel_name
!
#ifdef CPLOASIS
USE mod_oasis
#endif
#ifdef WXIOS
USE xios
#endif
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
LOGICAL, INTENT(OUT)           :: OOASIS      ! key to use OASIS
LOGICAL, INTENT(OUT)           :: OXIOS       ! key to use XIOS
INTEGER, INTENT(OUT)           :: KLOCAL_COMM ! value of local communicator
REAL   , INTENT(OUT), OPTIONAL :: PRUNTIME    ! total simulated time (s)
LOGICAL, INTENT(IN),  OPTIONAL :: LPREP
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
 CHARACTER(LEN=9)   :: YWORD, YTIMERUN
 CHARACTER(LEN=1000):: YLINE, YFOUND
INTEGER            :: IERR
INTEGER            :: ICOMP_ID
INTEGER            :: ITIMERUN
LOGICAL            :: GFOUND
!
!*       0.3   Declarations of namelist variables
!              ----------------------------------
!
LOGICAL               :: GPREP
!
LOGICAL               :: LOASIS      ! key to use OASIS
LOGICAL               :: LXIOS       ! key to use XIOS
!
NAMELIST/nam_oasis/loasis,lxios,cmodel_name
!
!-------------------------------------------------------------------------------
!
! ATTENTION : Do not introduce DR_HOOK in this routine
!
!*       0.     Initialization:
!               ---------------
!
gprep = .false.
IF(PRESENT(lprep)) gprep = lprep
!
loasis = .false.
lxios  = .false.
!
IF(PRESENT(pruntime)) pruntime = 0.0
!
!-------------------------------------------------------------------------------
!
!*       1.     Read namelist:
!               --------------
!
OPEN(unit=11,file=cnamelist,action='READ',form="FORMATTED",position="REWIND",status='OLD',iostat=ierr)   
!
IF (ierr /= 0) THEN
   WRITE(*,'(A)' )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
   WRITE(*,'(2A)')'TRIP_OASIS_INIT: TRIP NAMELIST NOT FOUND: ',trim(cnamelist)
   WRITE(*,'(A)' )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
   CALL abort
   stop
ENDIF
!
READ (unit=11,nml=nam_oasis,iostat=ierr)
!
 CLOSE(unit=11)
!
IF(gprep) lxios = .false.
!
!-------------------------------------------------------------------------------
!
!*       2.     Put specified param for OASIS coupling
!               --------------------------------------
!
ooasis   = loasis
oxios    = lxios
!
IF(loasis)THEN
#ifdef CPLOASIS
  WRITE(*,'(A)')'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(*,'(A)')'OASIS used for model : ',trim(cmodel_name)
  WRITE(*,'(A)')'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
#else
  WRITE(*,'(A)')'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(*,'(A)')'TRIP_OASIS_INIT: When OASIS used, TRIP must be compiled with -DCPLOASIS cpp key'
  WRITE(*,'(A)')'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  CALL abort
  stop 
#endif
ENDIF
!
IF(lxios)THEN
#ifdef WXIOS
  WRITE(*,'(A)')'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(*,'(A)')'XIOS used for model : ',trim(cmodel_name)
  WRITE(*,'(A)')'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
#else
  WRITE(*,'(A)')'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  WRITE(*,'(A)')'TRIP_OASIS_INIT: When XIOS used, TRIP must be compiled with -DWXIOS cpp key'
  WRITE(*,'(A)')'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
  CALL abort
  stop 
#endif
ENDIF
!
IF (lxios) THEN
#ifdef WXIOS
  CALL xios_initialize(cmodel_name,return_comm=klocal_comm)
#endif
ELSE
!
  IF ( .NOT. loasis) THEN 

    klocal_comm=0
    RETURN

  ELSE
!
!-------------------------------------------------------------------------------
#ifdef CPLOASIS
!-------------------------------------------------------------------------------
!
!*       3.     Setup OASIS
!               -----------
!
    CALL oasis_init_comp(icomp_id,cmodel_name,ierr) 
!   
    IF (ierr/=oasis_ok) THEN
      WRITE(*,'(A)'   )'TRIP : Error initializing OASIS'
      WRITE(*,'(A,I4)')'TRIP : Return code from oasis_init_comp : ',ierr
      CALL oasis_abort(icomp_id,cmodel_name,'TRIP_OASIS_INIT: Error initializing OASIS')
      CALL abort
      stop
    ENDIF
!
!-------------------------------------------------------------------------------
!
!*       4.     Get local communicator
!               ----------------------
!
    CALL oasis_get_localcomm(klocal_comm,ierr)
!   
    IF (ierr/=oasis_ok) THEN
      WRITE(*,'(A)'   )'TRIP : Error getting local communicator from OASIS'
      WRITE(*,'(A,I4)')'TRIP : Return code from oasis_get_local_comm : ',ierr
      CALL oasis_abort(icomp_id,cmodel_name,'TRIP_OASIS_INIT: Error getting local communicator')
      CALL abort
      stop
    ENDIF
!
!-------------------------------------------------------------------------------
#endif
!-------------------------------------------------------------------------------
  ENDIF
ENDIF
!
IF (loasis) THEN 
  !
  !*       5.     Read total simulated time in namcouple
  !               --------------------------------------
  !
  IF(.NOT.PRESENT(pruntime))THEN
    RETURN
  ENDIF
  !
  OPEN (unit=11,file ='namcouple',status='OLD',form ='FORMATTED',position="REWIND",iostat=ierr)
  IF (ierr /= 0) THEN
    WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
    WRITE(*,'(A)'   )'TRIP : OASIS namcouple not found'
    WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
    CALL abort
    stop
  ENDIF
!
  ytimerun=' $RUNTIME'
  itimerun=-1
!
  DO WHILE (itimerun==-1)
    READ (unit = 11,fmt = '(A9)',iostat=ierr) yword
    IF(ierr/=0)THEN
      WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
      WRITE(*,'(A)'   )'TRIP : Problem $RUNTIME empty in namcouple'
      WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!' 
      CALL abort
      stop           
    ENDIF  
    IF (yword==ytimerun)THEN
      READ (unit = 11,fmt = '(A1000)',iostat=ierr) yline
      IF(ierr/=0)THEN
        WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
        WRITE(*,'(A)'   )'TRIP : Problem looking for $RUNTIME in namcouple'
        WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!' 
        CALL abort
        stop           
      ENDIF
      CALL trip_found_timerun (yline, yfound, 1000, gfound)
      IF (gfound) THEN
        READ (yfound,fmt = '(I100)',iostat=ierr) itimerun
        IF(ierr/=0)THEN
          WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
          WRITE(*,'(A)'   )'TRIP : Problem reading $RUNTIME in namcouple'
          WRITE(*,'(2A)'  )'$RUNTIME = ', trim(yfound)
          WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!' 
          CALL abort
          stop
        ENDIF
      ENDIF
    ENDIF
  ENDDO
  CLOSE(11)
!
  pruntime = REAL(itimerun)
!
  WRITE(*,'(A)' )'-----------------------------'
!
ENDIF
!
!-------------------------------------------------------------------------------
 CONTAINS
!-------------------------------------------------------------------------------
!
SUBROUTINE trip_found_timerun(HIN, HOUT, KLEN, OFOUND)
!
IMPLICIT NONE
!
INTEGER ,          INTENT (IN   ) :: KLEN
 CHARACTER (LEN=*), INTENT (INOUT) :: HIN 
 CHARACTER (LEN=*), INTENT (INOUT) :: HOUT
LOGICAL,           INTENT (OUT  ) :: OFOUND
!
!* ---------------------------- Local declarations -------------------
!
 CHARACTER(LEN=1), PARAMETER :: YBLANK = ' '
 CHARACTER(LEN=1), PARAMETER :: YNADA  = '#'

 CHARACTER(LEN=KLEN) :: YLINE
 CHARACTER(LEN=KLEN) :: YWORK
!
INTEGER             :: ILEN
INTEGER             :: IERR
!
!
!*    1. Skip line if it is a comment
!        ----------------------------
!
DO WHILE (hin(1:1)==ynada)
   READ (unit = 11, fmt = '(A9)',iostat=ierr) yline 
   IF(ierr/=0)THEN
       WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!'
       WRITE(*,'(A)'   )'TRIP : Problem looking for $RUNTINE line in namcouple'
       WRITE(*,'(A)'   )'!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!' 
       CALL abort
       stop           
   ENDIF
   hin(1:klen) = yline(1:klen)
ENDDO 
!
!* Fill HOUT with blanks
!
hout = yblank
!
!* Fill temporary string and remove leading blanks
!
ywork = adjustl(hin)
!
IF(len_trim(ywork)<=0)THEN
   ofound = .false.
   RETURN
ENDIF
!
!* Find the length of this set of characters
!
ilen = index(ywork,yblank) - 1
!
!* Copy to HOUT
!
hout(1:ilen) = ywork(1:ilen)
!
ofound = .true.
!
END SUBROUTINE trip_found_timerun
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE trip_oasis_init