trip_oasis_define.F90

Go to the documentation of this file.

!#########
SUBROUTINE trip_oasis_define(KLISTING,KLON,KLAT)
!###############################################
!
!!****  *TRIP_OASIS_DEFINE* - Definitions for exchange of coupling fields
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      B. Decharme   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2013
!!      B. Decharme 10/2016  bug surface/groundwater coupling
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE modn_trip_oasis
USE modd_trip_oasis
!
USE modd_trip_par, ONLY : nundef
!
USE modd_trip_oasis
!
USE mode_trip_grid
!
USE modi_abort_trip
USE modi_get_lonlat_trip
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
#ifdef CPLOASIS
USE mod_oasis
#endif
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
INTEGER, INTENT(IN)    :: KLISTING 
INTEGER, INTENT(IN)    :: KLON
INTEGER, INTENT(IN)    :: KLAT
!
!*       0.2   Declarations of local parameter
!              -------------------------------
!
INTEGER,               PARAMETER  :: IG_PARSIZE   = 3       ! Size of array decomposition
INTEGER, DIMENSION(2), PARAMETER  :: IVAR_NODIMS  = (/2,1/) ! rank and number of bundles in coupling field
!
!*       0.3   Declarations of local variables
!              -------------------------------
!
INTEGER, DIMENSION(IG_PARSIZE) :: IPARAL      ! Decomposition for each proc
INTEGER, DIMENSION(2,2)        :: IVAR_SHAPE  ! indexes for the coupling field local dimension
!
INTEGER                        :: IPART_ID ! Local partition ID
INTEGER                        :: IERR     ! Error info
!
LOGICAL                        :: GFOUND   ! Return code when searching namelist
INTEGER                        :: INAM     ! logical unit of namelist file
!
INTEGER                        :: JLON, JLAT, JC, IFLAG
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_OASIS_DEFINE',0,zhook_handle)
!
!-------------------------------------------------------------------------------
#ifdef CPLOASIS
!-------------------------------------------------------------------------------
!
!*       1.     Define parallel partitions:
!               ---------------------------
!
! TRIP is for now a monoprocess model: the entire field will be exchanged by the process. 
!
iparal(clim_strategy) = clim_serial
iparal(clim_offset  ) = 0
iparal(clim_length  ) = klon*klat
!
 CALL oasis_def_partition(ipart_id,iparal(:),ierr)
!
IF(ierr/=oasis_ok)THEN
   WRITE(klisting,*)'TRIP_OASIS_DEFINE: OASIS def partition problem, err = ',ierr
   CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def partition problem')
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       2.     Coupling fields shape :
!               -----------------------
!
ivar_shape(1,1)= 1
ivar_shape(1,2)= klon
ivar_shape(2,1)= 1
ivar_shape(2,2)= klat
!
!
!-------------------------------------------------------------------------------
!
!*       3.     Sea variables for Trip - Oasis coupling :
!               -----------------------------------------
!
IF(lcpl_sea)THEN
!
! Output river discharge to ocean
  CALL oasis_def_var(nrivdis_id,crivdis,ipart_id,ivar_nodims,oasis_out,ivar_shape,oasis_double,ierr)
  IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for River discharge to ocean')
!
! Particular case for Calving fluxes
!
  IF(lcpl_calvsea)THEN
!
!   Output calving flux over Greenland
    CALL oasis_def_var(ncalvgre_id,ccalvgre,ipart_id,ivar_nodims,oasis_out,ivar_shape,oasis_double,ierr)
    IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for Calving flux over Greenland')
!
!   Output calving flux over Antarctica
    CALL oasis_def_var(ncalvant_id,ccalvant,ipart_id,ivar_nodims,oasis_out,ivar_shape,oasis_double,ierr)
    IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for Calving flux over Antarctica')
!
  ENDIF
!
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       4.     Land surface variables for trip - Oasis coupling :
!               ----------------------------------------------------
!
!
IF(lcpl_land)THEN
!
! Input surface runoff
  CALL oasis_def_var(nrunoff_id,crunoff,ipart_id,ivar_nodims,oasis_in,ivar_shape,oasis_double,ierr)
  IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for Surface runoff')
!
! Input calving flux
!
  IF(lcpl_calving)THEN
    CALL oasis_def_var(ncalving_id,ccalving,ipart_id,ivar_nodims,oasis_in,ivar_shape,oasis_double,ierr)  
    IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for calvin flux')
  ENDIF
!
! Inputd deep drainage
  CALL oasis_def_var(ndrain_id,cdrain,ipart_id,ivar_nodims,oasis_in,ivar_shape,oasis_double,ierr)  
  IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for Deep drainage')
!
! Particular case due to water table depth / surface coupling
!
  IF(lcpl_gw)THEN
!
!   Output Water table depth
    CALL oasis_def_var(nwtd_id,cwtd,ipart_id,ivar_nodims,oasis_out,ivar_shape,oasis_double,ierr)  
    IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for Water table depth')
!          
!   Output grid-cell fraction of WTD to rise
    CALL oasis_def_var(nfwtd_id,cfwtd,ipart_id,ivar_nodims,oasis_out,ivar_shape,oasis_double,ierr)  
    IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for fraction of WTD to rise')
!
  ENDIF
!
! Particular case due to floodplains coupling
!
  IF(lcpl_flood)THEN
!
!   Iutput Flood freshwater flux
    CALL oasis_def_var(nsrcflood_id,csrcflood,ipart_id,ivar_nodims,oasis_in,ivar_shape,oasis_double,ierr)  
    IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for Flood precip interception')
!          
!   Output floodplains fraction
    CALL oasis_def_var(nfflood_id,cfflood,ipart_id,ivar_nodims,oasis_out,ivar_shape,oasis_double,ierr)  
    IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for Floodplains fraction')
!          
!   Output floodplains potential infiltration
    CALL oasis_def_var(npiflood_id,cpiflood,ipart_id,ivar_nodims,oasis_out,ivar_shape,oasis_double,ierr)  
    IF(ierr/=oasis_ok) CALL abort_trip('TRIP_OASIS_DEFINE: OASIS def var problem for Floodplains potential infiltration')
!    
  ENDIF
!
ENDIF
!
!-------------------------------------------------------------------------------
!
!*       5.     End of declaration phase:
!               --------------
!
 CALL oasis_enddef(ierr)
!
IF(ierr/=oasis_ok)THEN
   WRITE(klisting,*)'TRIP_OASIS_DEFINE: OASIS enddef problem, err = ',ierr
   CALL abort_trip('TRIP_OASIS_DEFINE: OASIS enddef problem')
ENDIF
!
!-------------------------------------------------------------------------------
#endif
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_OASIS_DEFINE',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE trip_oasis_define