trip_xios_init.F90

Go to the documentation of this file.

SUBROUTINE trip_xios_init(TPG,KLOCAL_COMM,KLON,KLAT,KYEAR,KMONTH,KDAY,PTIME)
!!
!!
!!     PURPOSE
!!     --------
!!
!!     Initialize Xios context and declare Trip domain to XIOS
!!
!!
!!     METHOD
!!     ------
!!
!!
!!     EXTERNAL
!!     --------
!!
!!     XIOS library
!!
!!     REFERENCE
!!     ---------
!!
!!     Y.Meurdesoif, 2015 : XIOS ....
!!
!!
!!     AUTHOR
!!     ------
!!
!!     S.Senesi - CNRM
!!
!!     MODIFICATION
!!     --------------
!!
!!     Original    10/2016
!!     S.Sénési    08/11/16 : interface to XIOS
!!
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_trip_par, ONLY : xundef
USE modn_trip_run, ONLY : cmodel_name, xtstep_diag
USE modd_trip_grid, ONLY : trip_grid_t
!
USE modi_get_lonlat_trip
!
#ifdef WXIOS
USE xios
#endif
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
TYPE(trip_grid_t), INTENT(INOUT)  :: TPG
INTEGER, INTENT(IN)               :: KLOCAL_COMM ! value of local communicator
INTEGER, INTENT(IN)               :: KLON        ! Number of longitude
INTEGER, INTENT(IN)               :: KLAT        ! Number of latittude
INTEGER, INTENT(IN)               :: KYEAR   !date UTC
INTEGER, INTENT(IN)               :: KMONTH  !date UTC
INTEGER, INTENT(IN)               :: KDAY    !date UTC
REAL   , INTENT(IN)               :: PTIME   ! current time (s)
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(:),ALLOCATABLE    :: ZLON
REAL, DIMENSION(:),ALLOCATABLE    :: ZLAT
!
#ifdef WXIOS
INTEGER              :: IREFYEAR
TYPE(xios_duration)  :: DTIME
TYPE(xios_date)      :: TDATE
#endif
INTEGER              :: NHOURS,NMINUTES,NSECONDS
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_XIOS_INIT',0,zhook_handle)
!
#ifdef WXIOS
!
 CALL xios_context_initialize(cmodel_name,klocal_comm)
 CALL xios_set_current_context(cmodel_name)
!
nhours=int(ptime/3600)
nminutes=int((ptime - nhours*3600)/60)
nseconds=int(ptime - nhours*3600 -nminutes*60)
IF (.NOT.(xios_getvar('ref_year',irefyear))) irefyear=1850
 CALL xios_define_calendar("Gregorian", &
     start_date=xios_date(kyear,kmonth,kday,nhours,nminutes,nseconds), &
     time_origin=xios_date(irefyear,1,1,0,0,0))
!
dtime%SECOND=xtstep_diag
!
 CALL xios_set_timestep(dtime)
!
 CALL xios_set_domain_attr("trip_grid",data_dim=2,type="rectilinear")
 CALL xios_set_domain_attr("trip_grid",ni_glo=klon,ni=klon,ibegin=0)
 CALL xios_set_domain_attr("trip_grid",nj_glo=klat,nj=klat,jbegin=0)
!
ALLOCATE(zlon(klon),zlat(klat))
zlon(:)=xundef ; zlat(:)=xundef
 CALL get_lonlat_trip(tpg, klon,klat,zlon,zlat)
 CALL xios_set_domain_attr("trip_grid",lonvalue_1d=zlon,latvalue_1d=zlat)
DEALLOCATE(zlon,zlat)
!
 CALL xios_close_context_definition()
!
#endif
!
IF (lhook) CALL dr_hook('TRIP_XIOS_INIT',1,zhook_handle)
!
!-------------------------------------------------------------------------------
END SUBROUTINE trip_xios_init