treat_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE treat_field (UG, U, USS, &
                              hprogram,hscheme,hfiletype,    &
                              hsubroutine,hfilename,hfield,   &
                              ppgdarray,hsftype               )  
!     ##############################################################
!
!!**** *TREAT_FIELD* chooses which treatment subroutine to use
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    11/09/95
!!
!!    Modification
!!    25/05/96    (V. Masson) remove useless case for HSUBROUTINE   
!!    29/11/2002  (D. Gazen)  add HSFTYPE argument + call to read_binllvfast routine
!!    03/2004     (V. MAsson) externalization
!!    04/2009     (B. Decharme) Special treatement for gaussian grid
!!    06/2009     (B. Decharme)  call Topographic index statistics calculation
!!    09/2010     (E. Kourzeneva) call reading of the lake database
!!    03/2012     (M. Lafaysse) NETCDF
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
!
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modi_get_luout
USE modi_read_direct
USE modi_read_direct_gauss
USE modi_read_latlon
USE modi_read_binllv
USE modi_read_binllvfast
USE modi_read_ascllv
 
USE modi_read_pgd_netcdf

USE modi_average2_mesh
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
USE modi_average2_cover
!
USE modi_average2_cti
USE modi_average2_ldb
!
USE modi_average2_orography
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
 CHARACTER(LEN=6),  INTENT(IN) :: hprogram      ! Type of program
 CHARACTER(LEN=6),  INTENT(IN) :: hscheme       ! Scheme treated
 CHARACTER(LEN=6),  INTENT(IN) :: hfiletype     ! Type of the data file
 CHARACTER(LEN=6),  INTENT(IN) :: hsubroutine   ! Name of the subroutine to call
 CHARACTER(LEN=28), INTENT(IN) :: hfilename     ! Name of the field file.
 CHARACTER(LEN=20), INTENT(IN) :: hfield        ! Name of the field.
REAL, DIMENSION(:), INTENT(INOUT), OPTIONAL :: ppgdarray ! field on MESONH grid
 CHARACTER(LEN=3),   INTENT(IN),    OPTIONAL :: hsftype
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER :: iluout
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TREAT_FIELD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*    1.     Selection of type of reading (and point by point treatment)
!            -----------------------------------------------------------
!
SELECT CASE (hfiletype)

   CASE ('DIRECT')
         IF(ug%CGRID=="GAUSS     " .OR. ug%CGRID=="IGN       " .OR. ug%CGRID=="LONLAT REG")THEN
           CALL read_direct_gauss(uss, &
                                  hprogram,hscheme,hsubroutine,hfilename,hfield)
         ELSE
           CALL read_direct(uss, &
                            hprogram,hscheme,hsubroutine,hfilename,hfield)
         ENDIF

   CASE ('BINLLV')
       CALL read_binllv(uss, &
                        hprogram,hsubroutine,hfilename)

   CASE ('BINLLF')
       CALL read_binllvfast(uss, &
                            hprogram,hsubroutine,hfilename)

   CASE ('ASCLLV')
       CALL read_ascllv(uss, &
                        hprogram,hsubroutine,hfilename)

   CASE ('LATLON')
       CALL read_latlon(uss, &
                        hprogram,hscheme,hsubroutine,hfilename)

   CASE ('NETCDF')
       CALL read_pgd_netcdf(uss, &
                            hprogram,hscheme,hsubroutine,hfilename,hfield)

   CASE default
     CALL abor1_sfx('TREAT_FIELD: FILE TYPE NOT SUPPORTED: '//hfiletype)

END SELECT
!
!-------------------------------------------------------------------------------
!
!*    2.     Call to the adequate subroutine (global treatment)
!            --------------------------------------------------
!
SELECT CASE (hsubroutine)

  CASE ('A_COVR')
    CALL average2_cover(u, &
                        hprogram)

  CASE ('A_OROG')
    CALL average2_orography(uss)

  CASE ('A_CTI ')
    CALL average2_cti

  CASE ('A_LDBD')
    CALL average2_ldb(ppgdarray,'D',1)

  CASE ('A_LDBS')
    CALL average2_ldb(ppgdarray,'S',1)
    
  CASE ('A_MESH')
    IF (.NOT. present(ppgdarray)) THEN
      WRITE(iluout,*) 'You asked to average a PGD field with A_MESH option,'
      WRITE(iluout,*) 'but you did not give the array to store this field'
      CALL abor1_sfx('TREAT_FIELD: ARRAY IS MISSING')
    END IF
    CALL average2_mesh(ppgdarray)

END SELECT
!
IF (lhook) CALL dr_hook('TREAT_FIELD',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE treat_field