read_ascllv.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_ascllv (USS, &
                              hprogram,hsubroutine,hfilename)
!     ##############################################################
!
!!**** *READ_ASCLLV* reads a binary latlonvalue file and call treatment 
!!                   subroutine
!!
!!    PURPOSE
!!    -------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson          Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/09/95
!!                03/2004  externalization (V. Masson)
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_pgd_grid,   ONLY : llatlonmask
!
USE modi_open_file
USE modi_close_file
USE modi_pt_by_pt_treatment
USE modi_get_luout
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
 CHARACTER(LEN=6),  INTENT(IN) :: hprogram      ! Type of program
 CHARACTER(LEN=6),  INTENT(IN) :: hsubroutine   ! Name of the subroutine to call
 CHARACTER(LEN=28), INTENT(IN) :: hfilename     ! Name of the field file.
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER      :: iglb                       ! logical unit
!
INTEGER      :: jlat, jlon                 ! indexes of OLATLONMASK array
REAL         :: zvalue                     ! values of a data point
REAL         :: zlat                       ! latitude of data point
REAL         :: zlon                       ! longitude of data point
!
INTEGER      :: iluout                     ! output listing
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!*    1.      Open the file
!             -------------
!
IF (lhook) CALL dr_hook('READ_ASCLLV',0,zhook_handle)
 CALL open_file('ASCII ',iglb,hfilename,'FORMATTED',haction='READ')
!
 CALL get_luout(hprogram,iluout)
!
!----------------------------------------------------------------------------
DO
!----------------------------------------------------------------------------
!
!*    3.     Reading of a data point
!            -----------------------
!
  READ(iglb,*,end=99) zlat,zlon,zvalue
!
!----------------------------------------------------------------------------
!
!*    4.     Test if point is in MESO-NH domain
!            ----------------------------------
!
  zlon=zlon+nint((180.-zlon)/360.)*360.
  !
  jlat = 1 + int( ( zlat + 90. ) * 2. )
  jlat = min(jlat,360)
  jlon = 1 + int( ( zlon       ) * 2. )
  jlon = min(jlon,720)
  !
  IF (.NOT. llatlonmask(jlon,jlat)) cycle
!
!-------------------------------------------------------------------------------
!
!*    5.     Call to the adequate subroutine (point by point treatment)
!            ----------------------------------------------------------
!     
  CALL pt_by_pt_treatment(uss, &
                          iluout,  (/ zlat /) , (/ zlon /) , (/ zvalue /) , &
                            hsubroutine                                       )  
!
!-------------------------------------------------------------------------------
ENDDO
!
!----------------------------------------------------------------------------
!
!*    8.    Closing of the data file
!           ------------------------
!
99 CONTINUE
 CALL close_file('ASCII ',iglb)
IF (lhook) CALL dr_hook('READ_ASCLLV',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE read_ascllv