average2_ldb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################
      SUBROUTINE average2_ldb(PPGDARRAY,HTYPE,KSTAT)
!     #########################
!
!!**** *AVERAGE2_LDB* 
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    S. Faroux         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    17/02/11
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_pgdwork,   ONLY : nsize, xtng
USE modd_data_lake, ONLY : xboundgraddepth_ldb, xboundgradstatus_ldb, &
                           xcentrgraddepth_ldb, ncentrgradstatus_ldb, &
                           xsmall_dummy
!
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
REAL,    DIMENSION(:), INTENT(OUT) :: ppgdarray
 CHARACTER(LEN=1), INTENT(IN) :: htype
INTEGER, INTENT(IN)          :: kstat
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(:), ALLOCATABLE :: zbound, zcentr
REAL :: zfrac, zmax, zpdf, zave
!
INTEGER :: igrad_mode
INTEGER :: jgrad, ji
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!*    1.     Average values
!            --------------
!
IF (lhook) CALL dr_hook('AVERAGE2_LDB',0,zhook_handle)
!
SELECT CASE (htype)
!
  CASE('D')
    ALLOCATE(zbound(SIZE(xboundgraddepth_ldb)))
    zbound(:) = xboundgraddepth_ldb(:)
    ALLOCATE(zcentr(SIZE(xcentrgraddepth_ldb)))
    zcentr(:) = xcentrgraddepth_ldb(:)    
!
  CASE('S')
    ALLOCATE(zbound(SIZE(xboundgradstatus_ldb)))
    zbound(:) = xboundgradstatus_ldb(:)
    ALLOCATE(zcentr(SIZE(ncentrgradstatus_ldb)))
    zcentr(:) = ncentrgradstatus_ldb(:)
!
  CASE default
    CALL abor1_sfx("AVERAGE1_LDB: HTYPE NOT SUPPORTED")
!
END SELECT
!
!
DO ji = 1,SIZE(xtng,1)
  !
  DO jgrad = 1,SIZE(xtng,2)
    IF (nsize(ji).NE.0) xtng(ji,jgrad) = xtng(ji,jgrad)/nsize(ji)
  ENDDO
  !
  !2 because first centre is for values lower than 0
  zfrac = sum(xtng(ji,2:SIZE(xtng,2)))
  !
  zmax = xsmall_dummy
  igrad_mode = 2
  !
  IF (kstat.EQ.1) THEN
    !
    DO jgrad = 2, SIZE(xtng,2)
      zpdf = xtng(ji,jgrad) / (zbound(jgrad)-zbound(jgrad-1))
      IF (zpdf.GT.zmax) THEN
        zmax = zpdf
        igrad_mode = jgrad
      ENDIF
    ENDDO
    !
    IF (zfrac.GT.0.) THEN
      ppgdarray(ji) = zcentr(igrad_mode)
    ELSE
      ppgdarray(ji) = 0.
    ENDIF
    !
  ELSEIF (kstat.EQ.2) THEN
    !
    zave = 0.
    DO jgrad = 2, SIZE(xtng,2)
      zave = zave + zcentr(jgrad) * xtng(ji,jgrad)
    ENDDO
    !
    IF (zfrac.LT.0.00001) THEN
      ppgdarray(ji) = 0.
    ELSE
      ppgdarray(ji) = zave / zfrac
    ENDIF 
    !
  ENDIF
  !
ENDDO
!
DEALLOCATE(zbound)
DEALLOCATE(zcentr)
!
IF (lhook) CALL dr_hook('AVERAGE2_LDB',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average2_ldb