average2_mesh.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average2_mesh(PPGDARRAY)
!     #########################################
!
!!**** *AVERAGE2_MESH* computes a PGD field
!!
!!    PURPOSE
!!    -------
!!
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    12/09/95
!!     V. Masson  03/2004  externalization
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_pgdwork,        ONLY : nsize, xsumval, catype, &
                                nvalnbr, nvalcount, xvallist
USE modd_data_cover_par, ONLY : xcdref
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
REAL,    DIMENSION(:), INTENT(INOUT) :: ppgdarray ! Mesonh field
REAL(KIND=JPRB) :: zhook_handle
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
INTEGER :: jloop ! loop counter on grid points
INTEGER :: jval  ! loop counter on values encountered in grid mesh
INTEGER :: imax  ! Maximum of times a value has been encountered in the grid mesh
INTEGER :: ival  ! Index of this value
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('AVERAGE2_MESH',0,zhook_handle)
SELECT CASE (catype)

  CASE ('ARI')
  WHERE (nsize(:)/=0)
    ppgdarray(:)=xsumval(:)/nsize(:)
  ENDWHERE

  CASE ('INV')
  WHERE (nsize(:)/=0)
    ppgdarray(:)=nsize(:)/xsumval(:)
  ENDWHERE

  CASE ('CDN')
  WHERE (nsize(:)/=0)
    ppgdarray(:)=xcdref/exp(sqrt(nsize(:)/xsumval(:)))
  ENDWHERE

  CASE ('MAJ')
  DO jloop=1,SIZE(nsize)
    IF(nsize(jloop)==0) cycle
    !* determines the index of the value which has been the most encountered
    !  in the grid mesh
    imax=0
    DO jval=1,nvalnbr(jloop)
      IF (nvalcount(jloop,jval)>imax) THEN
        imax=nvalcount(jloop,jval)
        ival = jval
      END IF
    END DO
    !* sets this value to the PGD field
    ppgdarray(jloop)=xvallist(jloop,ival)
  END DO

END SELECT
IF (lhook) CALL dr_hook('AVERAGE2_MESH',1,zhook_handle)

!-------------------------------------------------------------------------------
!
END SUBROUTINE average2_mesh