average2_cover.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################
      SUBROUTINE average2_cover (U, &
                                 hprogram)
!     #########################
!
!!**** *AVERAGE2_COVER* computes the cover fractions
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/12/97
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_pgdwork,   ONLY : nsize, xsumcover
!
USE modd_pgd_grid,       ONLY : cgrid
!
USE modi_sum_on_all_procs
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),  INTENT(IN) :: hprogram      ! Type of program
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
REAL, DIMENSION(:), ALLOCATABLE :: zunity
!
INTEGER :: jcover, icpt ! loop counter on cover classes
REAL(KIND=JPRB) :: zhook_handle
!----------------------------------------------------------------------------
!
!*    1.     Average values
!            --------------
!
IF (lhook) CALL dr_hook('AVERAGE2_COVER',0,zhook_handle)
ALLOCATE(zunity(SIZE(nsize)))
zunity(:) = 0.
!
DO jcover=1,SIZE(xsumcover,2)
  icpt = sum_on_all_procs(hprogram,cgrid,xsumcover(:,jcover)/=0., 'HAL')
  IF (icpt>0) u%LCOVER(jcover) = .true.
ENDDO
!
ALLOCATE(u%XCOVER(SIZE(nsize),count(u%LCOVER)))
!
icpt = 0
DO jcover=1,SIZE(xsumcover,2)
  IF (u%LCOVER(jcover)) THEN
    icpt = icpt+1
    WHERE (nsize(:)/=0)
      u%XCOVER(:,icpt)=xsumcover(:,jcover) /nsize(:)
      zunity(:)=zunity(:) + u%XCOVER(:,icpt)
    ENDWHERE
  ENDIF
END DO
!
DO jcover=1,SIZE(u%XCOVER,2)
  WHERE (nsize(:) /=0 )
    u%XCOVER(:,jcover)=u%XCOVER(:,jcover) / zunity(:)
  END WHERE
END DO
!
!-------------------------------------------------------------------------------
DEALLOCATE(zunity)
IF (lhook) CALL dr_hook('AVERAGE2_COVER',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE average2_cover