average2_orography.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########################
      SUBROUTINE average2_orography (USS)
!     #########################
!
!!**** *AVERAGE2_OROGRAPHY* computes the cover fractions
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson         Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/12/97
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_pgdwork,       ONLY : nsize, xsumval, xsumval2, lssqo, xssqo, nsso
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
!*    0.2    Declaration of other local variables
!            ------------------------------------
!
!
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
INTEGER                  :: jl
REAL,    DIMENSION(NSSO) :: zmaxx
REAL,    DIMENSION(NSSO) :: zmaxy
LOGICAL, DIMENSION(NSSO) :: gsegx
LOGICAL, DIMENSION(NSSO) :: gsegy
REAL(KIND=JPRB) :: zhook_handle
!
!----------------------------------------------------------------------------
!
!*    1.     Mean orography
!            --------------
!
IF (lhook) CALL dr_hook('AVERAGE2_OROGRAPHY',0,zhook_handle)
WHERE (nsize(:)/=0)
  uss%XAVG_ZS(:)=xsumval(:)/nsize(:)
END WHERE
!
!-------------------------------------------------------------------------------
!
!*    2.     Standard deviation
!            ------------------
!
WHERE (nsize(:)/=0)
  uss%XSSO_STDEV(:)=sqrt( max(0.,xsumval2(:)/nsize(:) - uss%XAVG_ZS(:)*uss%XAVG_ZS(:)) )
END WHERE
!
!-------------------------------------------------------------------------------
!
!*    3.     Silhouette orography
!            --------------------
!
DO jl=1,SIZE(uss%XSIL_ZS)
  IF (nsize(jl)==0) cycle
  zmaxx(:) = maxval(xssqo(:,:,jl),dim=2)
  gsegx(:) = any(lssqo(:,:,jl),dim=2)
  zmaxy(:) = maxval(xssqo(:,:,jl),dim=1)
  gsegy(:) = any(lssqo(:,:,jl),dim=1)
  uss%XSIL_ZS(jl) =0.5*(  sum(zmaxx(:),mask=gsegx(:)) / count(gsegx(:)) &
                      + sum(zmaxy(:),mask=gsegy(:)) / count(gsegy(:)) )  
  
END DO
IF (lhook) CALL dr_hook('AVERAGE2_OROGRAPHY',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE average2_orography