coupling_isban.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ###############################################################################
SUBROUTINE coupling_isba_n (DTCO, UG, U, USS, IM, DTGD, DTGR, TGRO, DST, SLT,   &
                             hprogram, hcoupling,                                              &
                 ptstep, kyear, kmonth, kday, ptime, ki, ksv, ksw, ptsun, pzenith, pzenith2, &
                 pzref, puref, pzs, pu, pv, pqa, pta, prhoa, psv, pco2, hsv,                 &
                 prain, psnow, plw, pdir_sw, psca_sw, psw_bands, pps, ppa,                   &
                 psftq, psfth, psfts, psfco2, psfu, psfv,                                    &
                 ptrad, pdir_alb, psca_alb, pemis, ptsurf, pz0, pz0h, pqsurf,                &
                 ppew_a_coef, ppew_b_coef,                                                   &
                 ppet_a_coef, ppeq_a_coef, ppet_b_coef, ppeq_b_coef,                         &
                 htest                                                                       )  
!     ###############################################################################
!
!!****  *COUPLING_ISBA_n * - Driver for ISBA time step   
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!! First, all actions dependant on each patch is donbe independantly
!!     (loop on patches)
!! Second, actions common to all patches (e.g. prescription of new vegetation)
!! Third, energy fluxes are averaged
!!
!! Nota that chemical fluxes are also treated.
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      P Le Moigne 11/2004 add new diagnostics for isba
!!      A.Bogatchev 09/2005 EBA snow option
!!      P Le Moigne 09/2005 AGS modifs of L. Jarlan
!!      P Le Moigne 02/2006 z0h with snow
!!      P.Le Moigne 06/2006 seeding and irrigation
!!      B. Decharme   2008  reset the subgrid topographic effect on the forcing
!!                          PSNV allways <= PSNG
!!                          News diag
!!                          Flooding scheme and allows TRIP variables coupling
!!      A.L. Gibelin 04/2009 : Add respiration diagnostics
!!      A.L. Gibelin 04/2009 : BIOMASS and RESP_BIOMASS arrays 
!!      A.L. Gibelin 04/2009 : TAU_WOOD for NCB option 
!!      A.L. Gibelin 05/2009 : Add carbon spinup
!!      A.L. Gibelin 06/2009 : Soil carbon variables for CNT option
!!      A.L. Gibelin 07/2009 : Suppress RDK and transform GPP as a diagnostic
!!      A.L. Gibelin 07/2009 : Suppress PPST and PPSTF as outputs
!!        S.Lafont   01/2011 : add PTSTEP as arg of diag_misc
!!       B.Decharme  09/2012 : Bug in hydro_glacier calculation with ES or Crocus
!!                             New wind implicitation
!!                             New soil carbon spinup and diag
!!                             Isba budget
!!      F. Bouttier  01/2013 : Apply random perturbations for ensembles
!!      B. Decharme  04/2013 new coupling variables
!!                           Subsurface runoff if SGH (DIF option only)
!!                   07/2013 Surface / Water table depth coupling
!!      P Samuelsson 10/2014 : MEB
!!      P. LeMoigne  12/2014 EBA scheme update
!!      R. Seferian  05/2015 : Add coupling fiels to vegetation_evol call
!!      B. Decharme    01/16 : Bug with flood budget
!!      B. Decharme    01/16 : Bug when vegetation veg, z0 and emis are imposed whith interactive vegetation
!!-------------------------------------------------------------------
!
USE modd_surfex_n, ONLY : isba_model_t
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_data_teb_garden_n, ONLY : data_teb_garden_t
USE modd_data_teb_greenroof_n, ONLY : data_teb_greenroof_t
USE modd_teb_greenroof_option_n, ONLY : teb_greenroof_options_t
USE modd_dst_n, ONLY : dst_t
USE modd_slt_n, ONLY : slt_t
!
USE modd_reprod_oper, ONLY : cimplicit_wind
!
USE modd_csts,         ONLY : xrd, xrv, xp00, xcpd, xpi, xavogadro, xmd
USE modd_co2v_par,     ONLY : xmco2, xspin_co2
!
USE modd_surf_par,     ONLY : xundef
USE modd_snow_par,     ONLY : xz0sn
USE modd_type_date_surf
!
USE modd_surf_atm,    ONLY : lnosof
!
USE modd_dst_surf
USE modd_slt_surf
USE mode_dslt_surf
USE mode_meb
!
!
!                         

USE modd_data_cover_par, ONLY : nvt_no, nvt_rock
!
USE modd_agri,           ONLY : lagrip
USE modd_deepsoil,       ONLY : ldeepsoil
!
#ifdef TOPD
USE modd_coupling_topd,  ONLY : lcoupl_topd, nmaskt_patch
#endif
!
USE modi_irrigation_update
USE modi_add_forecast_to_date_surf
USE modi_z0eff
USE modi_isba
USE modi_average_flux
USE modi_average_phy
USE modi_average_rad
USE modi_average_diag_isba_n
USE modi_vegetation_evol
USE modi_vegetation_update
USE modi_albedo_veg_update
USE modi_carbon_evol
USE modi_subscale_z0eff
USE modi_soil_albedo
USE modi_albedo
USE modi_diag_inline_isba_n
USE modi_diag_evap_isba_n
USE modi_diag_misc_isba_n
!
USE modi_update_rad_isba_n
USE modi_deepsoil_update
USE modi_isba_sgh_update
USE modi_isba_flood_properties
USE modi_diag_cpl_esm_isba
USE modi_hydro_glacier
USE modi_isba_albedo
USE modi_carbon_spinup
USE modi_pack_isba_patch_n    
USE modi_pack_isba_patch_get_size_n
USE modi_pack_ch_isba_patch_n     
USE modi_pack_diag_patch_n
USE modi_pack_diag_patch_get_size_n
USE modi_unpack_isba_patch_n     
USE modi_unpack_ch_isba_patch_n     
USE modi_unpack_diag_patch_n     
USE modi_ch_aer_dep
USE modi_abor1_sfx
USE modi_average_diag_evap_isba_n
USE modi_average_diag_misc_isba_n
USE modi_ch_bvocem_n
USE modi_soilemisno_n
USE modi_ch_dep_isba
USE modi_dslt_dep
USE modi_coupling_dst_n
USE modi_coupling_surf_topd
USE modi_isba_budget_init
USE modi_isba_budget
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(isba_model_t), INTENT(INOUT) :: im
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(data_teb_garden_t), INTENT(INOUT) :: dtgd
TYPE(data_teb_greenroof_t), INTENT(INOUT) :: dtgr
TYPE(teb_greenroof_options_t), INTENT(INOUT) :: tgro
TYPE(dst_t), INTENT(INOUT) :: dst
TYPE(slt_t), INTENT(INOUT) :: slt
!
 CHARACTER(LEN=6),    INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=1),    INTENT(IN)  :: hcoupling ! type of coupling
                                              ! 'E' : explicit
                                              ! 'I' : implicit
INTEGER,             INTENT(IN)  :: kyear     ! current year (UTC)
INTEGER,             INTENT(IN)  :: kmonth    ! current month (UTC)
INTEGER,             INTENT(IN)  :: kday      ! current day (UTC)
REAL,                INTENT(IN)  :: ptime     ! current time since midnight (UTC, s)
INTEGER,             INTENT(IN)  :: ki        ! number of points
INTEGER,             INTENT(IN)  :: ksv       ! number of scalars
INTEGER,             INTENT(IN)  :: ksw       ! number of short-wave spectral bands
REAL, DIMENSION(KI), INTENT(IN)  :: ptsun     ! solar time                    (s from midnight)
REAL,                INTENT(IN)  :: ptstep    ! atmospheric time-step                 (s)
REAL, DIMENSION(KI), INTENT(IN)  :: pzref     ! height of T,q forcing                 (m)
REAL, DIMENSION(KI), INTENT(IN)  :: puref     ! height of wind forcing                (m)
!
REAL, DIMENSION(KI), INTENT(IN)  :: pta       ! air temperature forcing               (K)
REAL, DIMENSION(KI), INTENT(IN)  :: pqa       ! air humidity forcing                  (kg/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: prhoa     ! air density                           (kg/m3)
REAL, DIMENSION(KI,KSV),INTENT(IN) :: psv     ! scalar variables
!                                             ! chemistry:   first char. in HSV: '#'  (molecule/m3)
!   
 CHARACTER(LEN=6), DIMENSION(KSV),INTENT(IN):: hsv  ! name of all scalar variables!
REAL, DIMENSION(KI), INTENT(IN)  :: pu        ! zonal wind                            (m/s)
REAL, DIMENSION(KI), INTENT(IN)  :: pv        ! meridian wind                         (m/s)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: pdir_sw ! direct  solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI,KSW),INTENT(IN) :: psca_sw ! diffuse solar radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KSW),INTENT(IN)  :: psw_bands ! mean wavelength of each shortwave band (m)
REAL, DIMENSION(KI), INTENT(IN)  :: pzenith   ! zenithal angle at t  (radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: pzenith2  ! zenithal angle at t+1(radian from the vertical)
REAL, DIMENSION(KI), INTENT(IN)  :: plw       ! longwave radiation (on horizontal surf.)
!                                             !                                       (W/m2)
REAL, DIMENSION(KI), INTENT(IN)  :: pps       ! pressure at atmospheric model surface (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: ppa       ! pressure at forcing level             (Pa)
REAL, DIMENSION(KI), INTENT(IN)  :: pzs       ! atmospheric model orography           (m)
REAL, DIMENSION(KI), INTENT(IN)  :: pco2      ! CO2 concentration in the air          (kg_CO2/m3)
REAL, DIMENSION(KI), INTENT(IN)  :: psnow     ! snow precipitation                    (kg/m2/s)
REAL, DIMENSION(KI), INTENT(IN)  :: prain     ! liquid precipitation                  (kg/m2/s)
!
!
REAL, DIMENSION(KI), INTENT(OUT) :: psfth     ! flux of heat                          (W/m2)
REAL, DIMENSION(KI), INTENT(OUT) :: psftq     ! flux of water vapor                   (kg/m2/s)
REAL, DIMENSION(KI), INTENT(OUT) :: psfu      ! zonal momentum flux                   (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: psfv      ! meridian momentum flux                (Pa)
REAL, DIMENSION(KI), INTENT(OUT) :: psfco2    ! flux of CO2 positive toward the atmosphere (m/s*kg_CO2/kg_air)
REAL, DIMENSION(KI,KSV),INTENT(OUT):: psfts   ! flux of scalar var.                   (kg/m2/s)
!
REAL, DIMENSION(KI), INTENT(OUT) :: ptrad     ! radiative temperature                 (K)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: pdir_alb! direct albedo for each spectral band  (-)
REAL, DIMENSION(KI,KSW),INTENT(OUT):: psca_alb! diffuse albedo for each spectral band (-)
REAL, DIMENSION(KI), INTENT(OUT) :: pemis     ! emissivity                            (-)
!
REAL, DIMENSION(KI), INTENT(OUT) :: ptsurf    ! surface effective temperature         (K)
REAL, DIMENSION(KI), INTENT(OUT) :: pz0       ! roughness length for momentum         (m)
REAL, DIMENSION(KI), INTENT(OUT) :: pz0h      ! roughness length for heat             (m)
REAL, DIMENSION(KI), INTENT(OUT) :: pqsurf    ! specific humidity at surface          (kg/kg)
!
REAL, DIMENSION(KI), INTENT(IN) :: ppew_a_coef! implicit coefficients
REAL, DIMENSION(KI), INTENT(IN) :: ppew_b_coef! needed if HCOUPLING='I'
REAL, DIMENSION(KI), INTENT(IN) :: ppet_a_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppeq_a_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppet_b_coef
REAL, DIMENSION(KI), INTENT(IN) :: ppeq_b_coef
 CHARACTER(LEN=2),    INTENT(IN) :: htest ! must be equal to 'OK'
!
!
!*      0.2    declarations of local variables
!
!* forcing variables
!
REAL, DIMENSION(KI)     :: zwind    ! lowest atmospheric level wind speed           (m/s)
REAL, DIMENSION(KI)     :: zdir     ! wind direction                        (rad from N clockwise)
REAL, DIMENSION(KI)     :: zexna    ! Exner function at lowest atmospheric level    (-)
REAL, DIMENSION(KI)     :: zexns    ! Exner function at surface                     (-)
REAL, DIMENSION(KI)     :: zalfa    ! Wind direction                                (-)
REAL, DIMENSION(KI)     :: zqa      ! specific humidity                             (kg/kg)
REAL, DIMENSION(KI)     :: zco2     ! CO2 concentration                             (kg/kg)
REAL                    :: zspinco2 ! CO2 concentration                             (ppmv)
REAL, DIMENSION(KI)     :: zpeq_a_coef ! specific humidity implicit
REAL, DIMENSION(KI)     :: zpeq_b_coef ! coefficients (hum. in kg/kg)
!
INTEGER                 ::ispinend
!
! Patch outputs:
!
REAL, DIMENSION(KI,IM%I%NPATCH) :: zsfth_tile     ! surface heat flux (W/m2)
REAL, DIMENSION(KI,IM%I%NPATCH) :: zsftq_tile     ! surface vapor flux (kg/m2/s)
REAL, DIMENSION(KI,IM%I%NPATCH) :: zsfco2_tile    ! surface CO2 flux positive toward the atmosphere (m/s*kg_CO2/kg_air)
REAL, DIMENSION(KI,IM%I%NPATCH) :: zsfu_tile      ! zonal momentum flux
REAL, DIMENSION(KI,IM%I%NPATCH) :: zsfv_tile      ! meridian momentum flux
REAL, DIMENSION(KI,IM%I%NPATCH) :: ztrad_tile     ! radiative surface temperature
REAL, DIMENSION(KI,IM%I%NPATCH) :: zemis_tile     ! emissivity
REAL, DIMENSION(KI,IM%I%NPATCH) :: ztsurf_tile    ! surface effective temperature
REAL, DIMENSION(KI,IM%I%NPATCH) :: zz0_tile       ! roughness length for momentum
REAL, DIMENSION(KI,IM%I%NPATCH) :: zz0h_tile      ! roughness length for heat
REAL, DIMENSION(KI,IM%I%NPATCH) :: zqsurf_tile    ! specific humidity at surface
REAL, DIMENSION(KI,KSW,IM%I%NPATCH) :: zdir_alb_tile  ! direct albedo
REAL, DIMENSION(KI,KSW,IM%I%NPATCH) :: zsca_alb_tile  ! diffuse albedo
REAL, DIMENSION(KI,KSV,IM%I%NPATCH) :: zsfts_tile     ! scalar surface flux
!
REAL, DIMENSION(KI, IM%I%NPATCH) :: zcpl_drain     ! For the coupling with TRIP
REAL, DIMENSION(KI, IM%I%NPATCH) :: zcpl_runoff    ! For the coupling with TRIP
REAL, DIMENSION(KI, IM%I%NPATCH) :: zcpl_eflood    ! For the coupling with TRIP
REAL, DIMENSION(KI, IM%I%NPATCH) :: zcpl_pflood    ! For the coupling with TRIP
REAL, DIMENSION(KI, IM%I%NPATCH) :: zcpl_iflood    ! For the coupling with TRIP
REAL, DIMENSION(KI, IM%I%NPATCH) :: zcpl_iceflux
!
! for chemical computations
!
REAL, DIMENSION(KI, IM%I%NPATCH) :: zsw_forbio
!
REAL                       :: zconvertfacm0_slt, zconvertfacm0_dst
REAL                       :: zconvertfacm3_slt, zconvertfacm3_dst
REAL                       :: zconvertfacm6_slt, zconvertfacm6_dst
!
! dimensions and loop counters
!
INTEGER :: iswb   ! number of spectral shortwave bands
INTEGER :: jswb   ! loop on number of spectral shortwave bands
INTEGER :: jpatch ! loop on patches
INTEGER :: jsv, idst, imoment, ii
INTEGER :: jlayer, jmode, jsv_idx
!
! logical units
!
INTEGER :: jj
LOGICAL :: lupdated              ! T if VEGETATION_UPDATE has reset fields
!
REAL(KIND=JPRB) :: zhook_handle
!
! --------------------------------------------------------------------------------------
IF (lhook) CALL dr_hook('COUPLING_ISBA_N',0,zhook_handle)
IF (htest/='OK') THEN
  CALL abor1_sfx('COUPLING_ISBAN: FATAL ERROR DURING ARGUMENT TRANSFER')
END IF
! --------------------------------------------------------------------------------------
!
!*      1.     Initializations
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Allocations:
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
zsfth_tile(:,:)   = xundef
zsftq_tile(:,:)   = xundef
zsfco2_tile(:,:)   = xundef
zsfu_tile(:,:)   = xundef
zsfv_tile(:,:)   = xundef
ztrad_tile(:,:)   = xundef
zemis_tile(:,:)   = xundef
zdir_alb_tile(:,:,:) = xundef
zsca_alb_tile(:,:,:) = xundef
ztsurf_tile(:,:)   = xundef
zz0_tile(:,:)   = xundef
zz0h_tile(:,:)   = xundef
zqsurf_tile(:,:)   = xundef
!
zsfts_tile(:,:,:) = 0.
!
zcpl_drain(:,:)   = 0.0
zcpl_runoff(:,:)  = 0.0
zcpl_eflood(:,:)  = 0.0
zcpl_pflood(:,:)  = 0.0
zcpl_iflood(:,:)  = 0.0
zcpl_iceflux(:,:) = 0.0
!
zsw_forbio(:,:)   =  xundef
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Forcing Modifications:
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
zdir=0.
!
DO jj=1,SIZE(pqa) 
! specific humidity (conversion from kg/m3 to kg/kg)
!
  zqa(jj) = pqa(jj) / prhoa(jj)
  zpeq_a_coef(jj) = ppeq_a_coef(jj) / prhoa(jj)
  zpeq_b_coef(jj) = ppeq_b_coef(jj) / prhoa(jj)
!
  zco2(jj) = pco2(jj) / prhoa(jj)
!
! Other forcing variables depending on incoming forcing (argument list)JJ
!
  zexns(jj)   = (pps(jj)/xp00)**(xrd/xcpd)
  zexna(jj)   = (ppa(jj)/xp00)**(xrd/xcpd)
!
!* wind strength
!
  zwind(jj) = sqrt(pu(jj)**2+pv(jj)**2)
!
!* wind direction
!
  IF (zwind(jj)>0.)  zdir(jj)=atan2(pu(jj),pv(jj))
!
!* angle between z0eff J axis and wind direction (rad., clockwise)
!
  zalfa(jj) = zdir(jj) - im%I%XZ0EFFJPDIR(jj) * xpi/180.

  IF (zalfa(jj)<-xpi) zalfa(jj) = zalfa(jj) + 2.*xpi
  IF (zalfa(jj)>=xpi) zalfa(jj) = zalfa(jj) - 2.*xpi
!
ENDDO
!
!* number of shortwave spectral bands
!
iswb = ksw
!
!* irrigation
!
IF (lagrip .AND. (im%I%CPHOTO=='LAI' .OR. im%I%CPHOTO=='LST' .OR. &
                im%I%CPHOTO=='NIT'.OR. im%I%CPHOTO=='NCB') ) THEN
   CALL irrigation_update(im%AG, &
                          im%I%XIRRIG,ptstep,kmonth,kday,ptime,               &
                            im%I%TSEED(:,:)%TDATE%MONTH,im%I%TSEED(:,:)%TDATE%DAY,   &
                            im%I%TREAP(:,:)%TDATE%MONTH,im%I%TREAP(:,:)%TDATE%DAY    )  
ENDIF
!
!* Actualization of the SGH variable (Fmu, Fsat)
!
 CALL isba_sgh_update(im%IG, im%I, &
                      im%I%CISBA,im%I%CRUNOFF,im%I%CRAIN,prain,im%I%XMUF,im%I%XFSAT,im%I%XTOPQS)
!
!
!* Actualization of deep soil characteristics
!
IF (ldeepsoil) THEN
   CALL deepsoil_update(im%I, &
                        im%I%TTIME%TDATE%MONTH)
ENDIF
!
!* Actualization of soil and wood carbon spinup
!
! During soil carbon spinup with ISBA-CC: 
!        (1) Atmospheric CO2 concentration fixed to Pre-industrial CO2 consentration XCO2_START
!        (2) Atmospheric CO2 concentration rampin up from XCO2_START to XCO2_END
!
IF(im%I%LSPINUPCARBS.OR.im%I%LSPINUPCARBW)THEN
!
  ispinend=im%I%NNBYEARSPINS-nint(im%I%NNBYEARSPINS*xspin_co2)
!  
  im%I%LAGRI_TO_GRASS = .false.
!
  IF ( im%I%LSPINUPCARBS .AND. (im%I%NNBYEARSOLD <= ispinend) ) THEN
!
   im%I%LAGRI_TO_GRASS = .true.
!
   zco2(:) = im%I%XCO2_START * 1.e-6 * xmco2 / xmd
!
  ELSEIF(im%I%LSPINUPCARBS .AND. (im%I%NNBYEARSOLD > ispinend) .AND. &
                  (im%I%NNBYEARSOLD <= im%I%NNBYEARSPINS) )THEN
!
   zspinco2 = im%I%XCO2_START + (im%I%XCO2_END-im%I%XCO2_START) * &
                REAL(IM%I%NNBYEARSOLD - ISPINEND) / REAL(im%i%nnbyearspins - ispinend)
!
   zco2(:) = zspinco2 * 1.e-6 * xmco2 / xmd
!
  ENDIF
!
  CALL carbon_spinup(im%I%TTIME%TDATE%MONTH,im%I%TTIME%TDATE%DAY,im%I%TTIME%TIME,       &
                     im%I%LSPINUPCARBS, im%I%LSPINUPCARBW, im%I%XSPINMAXS, im%I%XSPINMAXW,   &
                     im%I%NNBYEARSPINS, im%I%NNBYEARSPINW, im%I%NNBYEARSOLD, im%I%CPHOTO,    &
                     im%I%CRESPSL, im%I%NSPINS, im%I%NSPINW                             )
!
ENDIF
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Time evolution
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
im%I%TTIME%TIME = im%I%TTIME%TIME + ptstep
 CALL add_forecast_to_date_surf(im%I%TTIME%TDATE%YEAR,im%I%TTIME%TDATE%MONTH,&
                im%I%TTIME%TDATE%DAY,im%I%TTIME%TIME)
!
! --------------------------------------------------------------------------------------
!
!*      2.     Physical evolution
!
! --------------------------------------------------------------------------------------
! Patch Dependent Calculations
! --------------------------------------------------------------------------------------
!
patch_loop: DO jpatch=1,im%I%NPATCH
!
  IF (im%I%NSIZE_NATURE_P(jpatch) == 0 ) cycle
!
! Pack dummy arguments for each patch:
!
#ifdef TOPD
  IF (lcoupl_topd)nmaskt_patch(:)=im%I%NR_NATURE_P(:,jpatch)
#endif
  CALL treat_patch(im%I%NSIZE_NATURE_P(jpatch),im%I%NR_NATURE_P(:,jpatch))
!
ENDDO patch_loop
!
! --------------------------------------------------------------------------------------
! SFX - RRM coupling update if used :
! --------------------------------------------------------------------------------------
!
IF(im%I%LCPL_RRM)THEN
  CALL diag_cpl_esm_isba(im%I, &
                         ptstep,zcpl_drain,zcpl_runoff,zcpl_eflood, &
                           zcpl_pflood,zcpl_iflood,zcpl_iceflux     )  
ENDIF
!
! --------------------------------------------------------------------------------------
! Vegetation update (in case of non-interactive vegetation):
! Or
! Vegetation albedo only update (in case of interactive vegetation):
! --------------------------------------------------------------------------------------
!
lupdated=.false.
IF ((im%I%CPHOTO=='NON' .OR. im%I%CPHOTO=='AGS' .OR. im%I%CPHOTO=='AST') .AND. im%I%LVEGUPD) THEN
     CALL vegetation_update(dtco, im%DTI, dtgd, dtgr, im%IG, im%I, tgro, &
                            ptstep,im%I%TTIME,im%I%XCOVER, im%I%LCOVER,                 &
                         im%I%CISBA,im%I%LECOCLIMAP,im%I%CPHOTO,lagrip,im%I%LTR_ML,'NAT',    &
                         im%I%XLAI,im%I%XVEG,im%I%XZ0,                                  &
                         im%I%XALBNIR,im%I%XALBVIS,im%I%XALBUV,im%I%XEMIS,                   &
                         im%I%XRSMIN,im%I%XGAMMA,im%I%XWRMAX_CF,                        &
                         im%I%XRGL,im%I%XCV,                                       &
                         im%I%XGMES,im%I%XBSLAI,im%I%XLAIMIN,im%I%XSEFOLD,im%I%XGC,im%I%XDMAX,    &
                         im%I%XF2I, im%I%LSTRESS,                                  &
                         im%I%XAOSIP,im%I%XAOSIM,im%I%XAOSJP,im%I%XAOSJM,                    &
                         im%I%XHO2IP,im%I%XHO2IM,im%I%XHO2JP,im%I%XHO2JM,                    &
                         im%I%XZ0EFFIP,im%I%XZ0EFFIM,im%I%XZ0EFFJP,im%I%XZ0EFFJM,            &
                         im%I%CALBEDO, im%I%XALBNIR_VEG, im%I%XALBVIS_VEG, im%I%XALBUV_VEG,  &
                         im%I%XALBNIR_SOIL, im%I%XALBVIS_SOIL, im%I%XALBUV_SOIL,        &
                         im%I%XCE_NITRO, im%I%XCF_NITRO, im%I%XCNA_NITRO,               &
                         im%I%TSEED, im%I%TREAP, im%I%XWATSUP, im%I%XIRRIG,                  &
                         im%I%XGNDLITTER, im%I%XRGLGV,im%I%XGAMMAGV,                     &
                         im%I%XRSMINGV, im%I%XWRMAX_CFGV,                          &
                         im%I%XH_VEG, im%I%XLAIGV, im%I%XZ0LITTER, lupdated             )  
!
ELSEIF ((im%I%CPHOTO=='LAI'.OR.im%I%CPHOTO=='LST'.OR.im%I%CPHOTO=='NIT'.OR.im%I%CPHOTO=='NCB').AND.im%I%LVEGUPD) THEN
!
  CALL albedo_veg_update(dtco, im%DTI, im%IG, im%I, &
                         ptstep,im%I%TTIME,im%I%XCOVER, im%I%LCOVER,                    &
                         im%I%CISBA,im%I%LECOCLIMAP,im%I%CPHOTO,lagrip,im%I%LTR_ML,'NAT',    &
                         im%I%XVEG,im%I%XALBNIR,im%I%XALBVIS,im%I%XALBUV,                    &
                         im%I%CALBEDO, im%I%XALBNIR_VEG, im%I%XALBVIS_VEG, im%I%XALBUV_VEG,  &
                         im%I%XALBNIR_SOIL, im%I%XALBVIS_SOIL, im%I%XALBUV_SOIL         )
END IF
!
IF(im%I%LPERTSURF.AND.lupdated) THEN
  ! random perturbation for ensembles:
  ! reset these fields to their original values, as in compute_isba_parameters
  im%I%XVEG(:,1) = im%I%XPERTVEG(:)
  im%I%XLAI(:,1) = im%I%XPERTLAI(:)
  im%I%XCV(:,1)  = im%I%XPERTCV(:)
  ! reapply original perturbation patterns
  WHERE(im%I%XALBNIR(:,1)/=xundef)  im%I%XALBNIR(:,1) =im%I%XALBNIR(:,1) *( 1.+ im%I%XPERTALB(:) )
  WHERE(im%I%XALBVIS(:,1)/=xundef)  im%I%XALBVIS(:,1) =im%I%XALBVIS(:,1) *( 1.+ im%I%XPERTALB(:) )
  WHERE(im%I%XALBUV(:,1)/=xundef)   im%I%XALBUV(:,1)  =im%I%XALBUV(:,1)  *( 1.+ im%I%XPERTALB(:) )
  WHERE(im%I%XZ0(:,1)/=xundef)      im%I%XZ0(:,1)     =im%I%XZ0(:,1)     *( 1.+ im%I%XPERTZ0(:) )
  WHERE(im%I%XZ0EFFIP(:,1)/=xundef) im%I%XZ0EFFIP(:,1)=im%I%XZ0EFFIP(:,1)*( 1.+ im%I%XPERTZ0(:) )
  WHERE(im%I%XZ0EFFIM(:,1)/=xundef) im%I%XZ0EFFIM(:,1)=im%I%XZ0EFFIM(:,1)*( 1.+ im%I%XPERTZ0(:) )
  WHERE(im%I%XZ0EFFJP(:,1)/=xundef) im%I%XZ0EFFJP(:,1)=im%I%XZ0EFFJP(:,1)*( 1.+ im%I%XPERTZ0(:) )
  WHERE(im%I%XZ0EFFJM(:,1)/=xundef) im%I%XZ0EFFJM(:,1)=im%I%XZ0EFFJM(:,1)*( 1.+ im%I%XPERTZ0(:) )

ENDIF
!
! --------------------------------------------------------------------------------------
! Outputs for the atmospheric model or update the snow/flood fraction at time t+1
! --------------------------------------------------------------------------------------
! Grid box average fluxes/properties: Arguments and standard diagnostics at time t+1
!
 CALL average_flux(im%I%XPATCH,                                             &
                  zsfth_tile, zsftq_tile, zsfts_tile, zsfco2_tile,    &
                  zsfu_tile, zsfv_tile,                               &                   
                  psfth, psftq, psfts, psfco2,                        &
                  psfu, psfv                                          )  
!
!
!-------------------------------------------------------------------------------
!Physical properties see by the atmosphere in order to close the energy budget 
!between surfex and the atmosphere. All variables should be at t+1 but very 
!difficult to do. Maybe it will be done later. However, Ts is at time t+1
!-------------------------------------------------------------------------------
!   
 CALL average_phy(im%I%XPATCH,                                         &
                  ztsurf_tile, zz0_tile, zz0h_tile, zqsurf_tile,  &    
                  puref, pzref, ptsurf, pz0, pz0h, pqsurf         )
!
!-------------------------------------------------------------------------------------
!Radiative properties at time t+1 (see by the atmosphere) in order to close
!the energy budget between surfex and the atmosphere
!-------------------------------------------------------------------------------------
!
 CALL update_rad_isba_n(im%I, &
                        im%I%LFLOOD, im%I%TSNOW%SCHEME, pzenith2, psw_bands,      &
                       im%I%XVEG, im%I%XLAI, im%I%XZ0,                                 &
                       im%I%LMEB_PATCH,im%I%XLAIGV,im%I%XGNDLITTER,im%I%XZ0LITTER,im%I%XH_VEG,   &
                       im%I%XALBNIR, im%I%XALBVIS, im%I%XALBUV, im%I%XEMIS,                 &
                       zdir_alb_tile,zsca_alb_tile,zemis_tile,          &
                       pdir_sw, psca_sw,                                &
                       im%I%XALBNIR_VEG, im%I%XALBNIR_SOIL,                       &
                       im%I%XALBVIS_VEG, im%I%XALBVIS_SOIL                        )
!
 CALL average_rad(im%I%XPATCH,                                              &
                 zdir_alb_tile, zsca_alb_tile, zemis_tile, ztrad_tile, &
                 pdir_alb,      psca_alb,      im%I%XEMIS_NAT,  im%I%XTSRAD_NAT  )  
!
pemis = im%I%XEMIS_NAT
ptrad = im%I%XTSRAD_NAT
!
!-------------------------------------------------------------------------------------
!
! Any additional diagnostics (stored in MODD_DIAG_ISBA_n)
!
 CALL average_diag_isba_n(im%DGEI, im%DGI, im%I, &
                          puref,pzref,psfco2,ptrad)
!
! Cumulated diagnostics (stored in MODD_DIAG_EVAP_ISBA_n)
!
 CALL average_diag_evap_isba_n(im%DGEI, im%I, &
                               ptstep,prain,psnow)
!
! Miscellaneous diagnostics (stored in MODD_DIAG_MISC_ISBA_n)
!
 CALL average_diag_misc_isba_n(im%DGMI, im%I)
!
!--------------------------------------------------------------------------------------
!
 CALL coupling_surf_topd(im%DGEI, im%DGMI, im%IG, im%I, ug, u, &
                         hprogram,u%NDIM_FULL)
!
! --------------------------------------------------------------------------------------
! Snow/Flood fractions, albedo and emissivity update :
! --------------------------------------------------------------------------------------
!
! --------------------------------------------------------------------------------------
! Chemical fluxes :
! --------------------------------------------------------------------------------------
!
IF (im%CHI%SVI%NBEQ>0 .AND. im%CHI%LCH_BIO_FLUX) THEN
 CALL ch_bvocem_n(im%CHI, im%GB, im%I, &
                  zsw_forbio,prhoa,psfts)
ENDIF
!
!SOILNOX
IF (im%CHI%LCH_NO_FLUX) THEN
  CALL soilemisno_n(im%GB, im%I, &
                    pu,pv)
ENDIF
!
!==========================================================================================
!
IF (lhook) CALL dr_hook('COUPLING_ISBA_N',1,zhook_handle)
 CONTAINS
!
!=======================================================================================
SUBROUTINE treat_patch(KSIZE,KMASK)
!
IMPLICIT NONE
!
INTEGER, INTENT(IN)               :: ksize
INTEGER, INTENT(IN), DIMENSION(KI) :: kmask
!
REAL, DIMENSION(KSIZE) :: zp_zref    ! height of T,q forcing                 (m)
REAL, DIMENSION(KSIZE) :: zp_uref    ! height of wind forcing                (m)
REAL, DIMENSION(KSIZE) :: zp_u       ! zonal wind                            (m/s)
REAL, DIMENSION(KSIZE) :: zp_v       ! meridian wind                         (m/s)
REAL, DIMENSION(KSIZE) :: zp_wind    ! wind                                  (m/s)
REAL, DIMENSION(KSIZE) :: zp_dir     ! wind direction                        (rad from N clockwise)
REAL, DIMENSION(KSIZE) :: zp_qa      ! air specific humidity forcing         (kg/kg)
REAL, DIMENSION(KSIZE) :: zp_ta      ! air temperature forcing               (K)
REAL, DIMENSION(KSIZE) :: zp_co2     ! CO2 concentration in the air          (kg/kg)
REAL, DIMENSION(KSIZE,KSV) :: zp_sv      ! scalar concentration in the air       (kg/kg)
REAL, DIMENSION(KSIZE) :: zp_zenith  ! zenithal angle        radian from the vertical)
REAL, DIMENSION(KSIZE) :: zp_pew_a_coef ! implicit coefficients
REAL, DIMENSION(KSIZE) :: zp_pew_b_coef ! needed if HCOUPLING='I'
REAL, DIMENSION(KSIZE) :: zp_pet_a_coef
REAL, DIMENSION(KSIZE) :: zp_pet_b_coef
REAL, DIMENSION(KSIZE) :: zp_peq_a_coef
REAL, DIMENSION(KSIZE) :: zp_peq_b_coef
REAL, DIMENSION(KSIZE) :: zp_rain    ! liquid precipitation                  (kg/m2/s)
REAL, DIMENSION(KSIZE) :: zp_snow    ! snow precipitation                    (kg/m2/s)
REAL, DIMENSION(KSIZE) :: zp_lw      ! longwave radiation (W/m2)
REAL, DIMENSION(KSIZE,ISWB) :: zp_dir_sw  ! direct  solar radiation (W/m2)
REAL, DIMENSION(KSIZE,ISWB) :: zp_sca_sw  ! diffuse solar radiation (W/m2)
REAL, DIMENSION(KSIZE) :: zp_ps      ! pressure at atmospheric model surface (Pa)
REAL, DIMENSION(KSIZE) :: zp_pa      ! pressure at forcing level             (Pa)
REAL, DIMENSION(KSIZE) :: zp_zs      ! atmospheric model orography           (m)
REAL, DIMENSION(KSIZE) :: zp_sftq    ! flux of water vapor <w'q'>            (kg.m-2.s-1)
REAL, DIMENSION(KSIZE) :: zp_sfth    ! flux of temperature <w'T'>            (W/m2)
REAL, DIMENSION(KSIZE,KSV) :: zp_sfts    ! flux of scalar      <w'sv'>           (mkg/kg/s)
REAL, DIMENSION(KSIZE) :: zp_sfco2   ! flux of CO2 positive toward the atmosphere (m/s*kg_CO2/kg_air)
REAL, DIMENSION(KSIZE) :: zp_ustar   ! friction velocity                     (m/s)
REAL, DIMENSION(KSIZE) :: zp_sfu     ! zonal momentum flux                   (pa)
REAL, DIMENSION(KSIZE) :: zp_sfv     ! meridian momentum flux                (pa)
REAL, DIMENSION(KSIZE) :: zp_trad    ! radiative temperature                 (K)
REAL, DIMENSION(KSIZE) :: zp_tsurf   ! surface effective temperature (K)
REAL, DIMENSION(KSIZE) :: zp_z0      ! roughness length for momentum (m)
REAL, DIMENSION(KSIZE) :: zp_z0h     ! roughness length for heat     (m)
REAL, DIMENSION(KSIZE) :: zp_qsurf   ! specific humidity at surface  (kg/kg)
!
!*  other forcing variables (packed for each patch)
!
REAL, DIMENSION(KSIZE) :: zp_rhoa    ! lowest atmospheric level air density          (kg/m3)
REAL, DIMENSION(KSIZE) :: zp_exna    ! Exner function at lowest atmospheric level    (-)
REAL, DIMENSION(KSIZE) :: zp_exns    ! Exner function at surface                     (-)
REAL, DIMENSION(KSIZE) :: zp_alfa    ! Wind direction   (-)
!
!*  working variables (packed for each patch)
!
REAL, DIMENSION(KSIZE)      :: zp_albnir_tveg         ! total vegetation albedo in ir
REAL, DIMENSION(KSIZE)      :: zp_albnir_tsoil        ! total soil albedo in ir
REAL, DIMENSION(KSIZE)      :: zp_albvis_tveg         ! total vegetation albedo in vis
REAL, DIMENSION(KSIZE)      :: zp_albvis_tsoil        ! total soil albedo in vis
REAL, DIMENSION(KSIZE) :: zp_emis                      ! emissivity
REAL, DIMENSION(KSIZE) :: zp_global_sw                 ! global incoming SW rad.
REAL, DIMENSION(KSIZE) :: zp_slope_cos                 ! typical slope in the grid cosine
!
REAL, DIMENSION(KSIZE) :: zp_z0flood  !Floodplain 
REAL, DIMENSION(KSIZE) :: zp_ffgnos   !Floodplain fraction over the ground without snow
REAL, DIMENSION(KSIZE) :: zp_ffvnos   !Floodplain fraction over vegetation without snow
!
REAL, DIMENSION(KSIZE,IM%I%NNBIOMASS) :: zp_resp_biomass_inst         ! instantaneous biomass respiration (kgCO2/kgair m/s)
!
!*  Aggregated coeffs for evaporative flux calculations
!
REAL, DIMENSION(KSIZE) :: zp_ac_agg      ! aggregated aerodynamic resistance
REAL, DIMENSION(KSIZE) :: zp_hu_agg      ! aggregated relative humidity
!
!*  For multi-energy balance
!
REAL, DIMENSION(KSIZE) :: zpalphan                     ! snow/canopy transition coefficient
REAL, DIMENSION(KSIZE) :: zsnowdepth                   ! total snow depth
REAL, DIMENSION(KSIZE) :: zz0g_without_snow            ! roughness length for momentum at snow-free canopy floor
REAL, DIMENSION(KSIZE) :: zz0_mebv                     ! roughness length for momentum over MEB vegetation part of patch
REAL, DIMENSION(KSIZE) :: zz0h_mebv                    ! roughness length for heat over MEB vegetation part of path
REAL, DIMENSION(KSIZE) :: zz0eff_mebv                  ! roughness length for momentum over MEB vegetation part of patch
REAL, DIMENSION(KSIZE) :: zz0_mebn                     ! roughness length for momentum over MEB snow part of patch
REAL, DIMENSION(KSIZE) :: zz0h_mebn                    ! roughness length for heat over MEB snow part of path
REAL, DIMENSION(KSIZE) :: zz0eff_mebn                  ! roughness length for momentum over MEB snow part of patch
! Temporary
REAL, DIMENSION(KSIZE) :: zp_meb_sca_sw                ! diffuse incoming SW rad.
!
!*  ISBA water and energy budget
!
REAL, DIMENSION(KSIZE) :: zp_wg_ini
REAL, DIMENSION(KSIZE) :: zp_wgi_ini
REAL, DIMENSION(KSIZE) :: zp_wr_ini
REAL, DIMENSION(KSIZE) :: zp_swe_ini
!
! miscellaneous
!
REAL, DIMENSION(KSIZE)               :: zp_deep_flux ! Flux at the bottom of the soil
REAL, DIMENSION(KSIZE)               :: zp_tdeep_a   ! coefficient for implicitation of Tdeep
REAL, DIMENSION(KSIZE)               :: zirrig_gr    ! green roof ground irrigation rate 
!
! For multi-energy balance
LOGICAL :: gmeb  ! True if multi-energy balance should be used for the specific patch
!
INTEGER :: jj, ji, jk
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('COUPLING_ISBA_n:TREAT_PATCH',0,zhook_handle)
!
!--------------------------------------------------------------------------------------
!
! Pack isba forcing outputs
!
IF (im%I%NPATCH==1) THEN
   zp_zenith(:)     = pzenith(:)
   zp_zref(:)       = pzref(:)
   zp_uref(:)       = puref(:)
   zp_wind(:)       = zwind(:)
   zp_u(:)          = pu(:)
   zp_v(:)          = pv(:)
   zp_dir(:)        = zdir(:)
   zp_qa(:)         = zqa(:)
   zp_ta(:)         = pta(:)
   zp_co2(:)        = zco2(:)
   zp_sv(:,:)       = psv(:,:)
   zp_pew_a_coef(:) = ppew_a_coef(:)
   zp_pew_b_coef(:) = ppew_b_coef(:)
   zp_pet_a_coef(:) = ppet_a_coef(:)
   zp_pet_b_coef(:) = ppet_b_coef(:)
   zp_peq_a_coef(:) = zpeq_a_coef(:)
   zp_peq_b_coef(:) = zpeq_b_coef(:)
   zp_rain(:)       = prain(:)
   zp_snow(:)       = psnow(:)
   zp_lw(:)         = plw(:)
   zp_dir_sw(:,:)   = pdir_sw(:,:)
   zp_sca_sw(:,:)   = psca_sw(:,:)
   zp_ps(:)         = pps(:)
   zp_pa(:)         = ppa(:)
   zp_zs(:)         = pzs(:)
!
   zp_rhoa(:)       = prhoa(:)
   zp_exna(:)       = zexna(:)
   zp_exns(:)       = zexns(:)
   zp_alfa(:)       = zalfa(:)
ELSE
!cdir nodep
!cdir unroll=8
  DO jj=1,ksize
   ji = kmask(jj)
   zp_zenith(jj)     = pzenith(ji)
   zp_zref(jj)       = pzref(ji)
   zp_uref(jj)       = puref(ji)
   zp_wind(jj)       = zwind(ji)
   zp_u(jj)          = pu(ji)
   zp_v(jj)          = pv(ji)
   zp_dir(jj)        = zdir(ji)
   zp_qa(jj)         = zqa(ji)
   zp_ta(jj)         = pta(ji)
   zp_co2(jj)        = zco2(ji)
   zp_pew_a_coef(jj) = ppew_a_coef(ji)
   zp_pew_b_coef(jj) = ppew_b_coef(ji)
   zp_pet_a_coef(jj) = ppet_a_coef(ji)
   zp_pet_b_coef(jj) = ppet_b_coef(ji)
   zp_peq_a_coef(jj) = zpeq_a_coef(ji)
   zp_peq_b_coef(jj) = zpeq_b_coef(ji)
   zp_rain(jj)       = prain(ji)
   zp_snow(jj)       = psnow(ji)
   zp_lw(jj)         = plw(ji)
   zp_ps(jj)         = pps(ji)
   zp_pa(jj)         = ppa(ji)
   zp_zs(jj)         = pzs(ji)
!
   zp_rhoa(jj)       = prhoa(ji)
   zp_exna(jj)       = zexna(ji)
   zp_exns(jj)       = zexns(ji)
   zp_alfa(jj)       = zalfa(ji)
  ENDDO
!
  DO jk=1,ksv
!cdir nodep
!cdir unroll=8
    DO jj=1,ksize
      ji=kmask(jj)
      zp_sv(jj,jk) = psv(ji,jk)
    ENDDO
  ENDDO
!
  DO jk=1,SIZE(pdir_sw,2)
!cdir nodep
!cdir unroll=8
    DO jj=1,ksize
      ji=kmask(jj)
      zp_dir_sw(jj,jk) = pdir_sw(ji,jk)
      zp_sca_sw(jj,jk) = psca_sw(ji,jk)
    ENDDO
  ENDDO
!
ENDIF
!
!--------------------------------------------------------------------------------------
!
! For multi-energy balance
   gmeb=im%I%LMEB_PATCH(jpatch)
!
! Pack ISBA input and prognostic variables (modd_isban) for each patch:
!
 CALL pack_isba_patch_get_size_n(im%I, im%PKI, &
                                 jpatch)
!
 CALL pack_diag_patch_get_size_n(im%DGEI, im%DGI, im%DGMI, im%I, im%PKDI, &
                                 jpatch)
!
 CALL pack_isba_patch_n(im%AG, im%IG, im%I, im%PKI, &
                        kmask,ksize,jpatch)     
!
! Pack chemistry input and prognostic variables (modd_ch_isban) for each patch:
!
IF (im%CHI%SVI%NBEQ>0) THEN
  IF( im%CHI%CCH_DRY_DEP == "WES89") THEN
    CALL pack_ch_isba_patch_n(im%CHI, im%PKCI, &
                              kmask,ksize,im%I%NPATCH,jpatch)     
  END IF
END IF
!
! Allocate ISBA diagnostics for each patch:
!
 CALL pack_diag_patch_n(im%DGEI, im%DGI, im%DGMI, im%I, im%PKDI, &
                        ksize,iswb,jpatch)     
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Cosine of the slope typically encoutered in the grid mesh (including subgrid orography)
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
zp_slope_cos(:) = 1./sqrt(1.+im%PKI%XP_SSO_SLOPE(:)**2)
IF(lnosof)zp_slope_cos(:) = 1.0
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Snow fractions
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! now caculated at the initialization and at the end of the time step 
! (see update_frac_alb_emis_isban.f90) in order to close the energy budget
! between surfex and the atmosphere. This fact do not change the offline runs.
!
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! No implicitation of Tdeep
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
zp_tdeep_a = 0.
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Flood properties 
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
IF(im%I%LFLOOD)THEN
  CALL isba_flood_properties(im%PKI%XP_LAI,im%PKI%XP_FFLOOD,im%PKI%XP_FFROZEN,  &
                             zp_z0flood,zp_ffgnos,zp_ffvnos)  
ELSE
  zp_z0flood = xundef
  zp_ffgnos  = 0.0
  zp_ffvnos  = 0.0
ENDIF
!
! For multi-energy balance
   IF(gmeb)THEN
     zsnowdepth(:) = sum(im%PKI%XP_SNOWSWE(:,:)/im%PKI%XP_SNOWRHO(:,:),2)
     zpalphan(:)=mebpalphan(zsnowdepth,im%PKI%XP_H_VEG)
   ENDIF
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Surface Roughness lengths (m):
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
!* effective roughness
!
 CALL z0eff(im%I, &
            im%I%CROUGH, gmeb, zp_alfa, zp_zref, zp_uref, &
            im%PKI%XP_Z0, im%PKI%XP_Z0REL, im%PKI%XP_PSN,   &
            zpalphan,im%PKI%XP_Z0LITTER, im%PKI%XP_SNOWSWE(:,1),           &
     im%PKI%XP_Z0EFFIP,im%PKI%XP_Z0EFFIM,im%PKI%XP_Z0EFFJP, &
     im%PKI%XP_Z0EFFJM, im%PKI%XP_FF, zp_z0flood,     &
     im%PKI%XP_AOSIP,im%PKI%XP_AOSIM,im%PKI%XP_AOSJP,im%PKI%XP_AOSJM,         &
     im%PKI%XP_HO2IP,im%PKI%XP_HO2IM,im%PKI%XP_HO2JP,im%PKI%XP_HO2JM,        &
     im%PKI%XP_Z0_O_Z0H, im%PKDI%XP_Z0_WITH_SNOW, im%PKDI%XP_Z0H_WITH_SNOW, &
     im%PKDI%XP_Z0EFF, zz0g_without_snow,                                 &
     zz0_mebv,zz0h_mebv,zz0eff_mebv,                                     &
     zz0_mebn,zz0h_mebn,zz0eff_mebn                                      )
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Shortwave computations for outputs (albedo for radiative scheme)
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! now caculated at the initialization and at the end of the time step 
! (see update_frac_alb_emis_isban.f90) in order to close the energy budget
! between surfex and the atmosphere. This fact do not change the offline runs.
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Shortwave computations for ISBA inputs (global snow-free albedo)
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
! ISBA needs global incoming solar radiation: it currently does
! not distinguish between the scattered and direct components,
! or between different wavelengths.
!
!
!* Snow-free surface albedo for each wavelength
!
 CALL isba_albedo(im%I%TSNOW%SCHEME, im%I%LTR_ML, gmeb,                &
                   zp_dir_sw, zp_sca_sw, psw_bands,iswb,                 &
                   im%PKI%XP_ALBNIR, im%PKI%XP_ALBVIS, im%PKI%XP_ALBUV,                       &
                   im%PKI%XP_ALBNIR_VEG, im%PKI%XP_ALBVIS_VEG, im%PKI%XP_ALBUV_VEG,           &
                   im%PKI%XP_ALBNIR_SOIL, im%PKI%XP_ALBVIS_SOIL, im%PKI%XP_ALBUV_SOIL,        &
                   im%PKI%XP_ALBF, im%PKI%XP_FFV, im%PKI%XP_FFG,    & 
                   zp_global_sw, im%PKDI%XP_SNOWFREE_ALB, im%PKDI%XP_SNOWFREE_ALB_VEG,   &
                   im%PKDI%XP_SNOWFREE_ALB_SOIL, zp_meb_sca_sw,                  &
                   zp_albnir_tveg, zp_albvis_tveg,                       &
                   zp_albnir_tsoil, zp_albvis_tsoil                      )  
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Intialize computation of ISBA water and energy budget
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
 CALL isba_budget_init(im%DGEI, &
                       im%I%CISBA,im%I%TSNOW%SCHEME,            &
                      im%PKI%XP_WG,im%PKI%XP_WGI,im%PKI%XP_WR,im%PKI%XP_SNOWSWE, &
                      im%PKI%XP_DG, im%PKI%XP_DZG, zp_wg_ini,      &
                      zp_wgi_ini, zp_wr_ini,         &
                      zp_swe_ini                     )
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Over Natural Land Surfaces:
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
zirrig_gr(:)= 0.
!
 CALL isba(im%I%CISBA, im%I%CPHOTO, im%I%LTR_ML, im%I%CRUNOFF, im%I%CKSAT, im%I%CRAIN, &
           im%I%CHORT, im%I%CC1DRY, im%I%CSCOND, im%I%TSNOW%SCHEME, im%I%CSNOWRES, &
           im%I%CCPSURF, im%I%CSOILFRZ, im%I%CDIFSFCOND, im%I%TTIME, im%I%LFLOOD, &
           im%I%LTEMP_ARP, im%I%LGLACIER, gmeb, im%I%LFORC_MEASURE, im%I%LMEB_LITTER, &
           im%I%LMEB_GNDRES, ptstep, &
           cimplicit_wind, im%I%LAGRI_TO_GRASS, im%I%LSNOWDRIFT, im%I%LSNOWDRIFT_SUBLIM, &
           im%I%LSNOW_ABS_ZENITH, im%I%CSNOWMETAMO, im%I%CSNOWRAD, im%I%XCGMAX, zp_zref, &
           zp_uref, zp_slope_cos, zp_ta, zp_qa, zp_exna, zp_rhoa, zp_ps, zp_exns, zp_rain, &
           zp_snow, zp_zenith, zp_meb_sca_sw, zp_global_sw, zp_lw, zp_wind, zp_pew_a_coef, &
           zp_pew_b_coef, zp_pet_a_coef, zp_peq_a_coef,  zp_pet_b_coef, zp_peq_b_coef, &
           im%PKI%XP_RSMIN, im%PKI%XP_RGL, im%PKI%XP_GAMMA, im%PKI%XP_CV, im%PKI%XP_RUNOFFD, &
           im%PKI%XP_SOILWGHT, im%I%NLAYER_HORT, im%I%NLAYER_DUN, zp_albnir_tveg, zp_albvis_tveg,  &
           zp_albnir_tsoil, zp_albvis_tsoil, im%PKDI%XP_SNOWFREE_ALB, im%PKI%XP_WRMAX_CF, &
           im%PKI%XP_VEG, im%PKI%XP_LAI, im%PKI%XP_EMIS, im%PKDI%XP_Z0_WITH_SNOW, &
           im%PKDI%XP_Z0H_WITH_SNOW, im%PKI%XP_VEGTYPE_PATCH, im%PKDI%XP_Z0EFF,   &
           im%PKI%XP_RGLV, im%PKI%XP_GAMMAV, im%PKI%XP_RSMINV, &
           im%PKI%XP_ROOTFRACV, im%PKI%XP_WRMAX_CFV, im%PKI%XP_LAIV, im%PKI%XP_BSLAI, &
           im%PKI%XP_LAIMIN,im%PKI%XP_H_VEG,zpalphan, zz0g_without_snow, zz0_mebv,     &
           zz0h_mebv,zz0eff_mebv, zz0_mebn,zz0h_mebn,zz0eff_mebn, im%PKI%XP_GNDLITTER,  &
           im%PKI%XP_RUNOFFB, im%PKI%XP_CGSAT, im%PKI%XP_C1SAT, im%PKI%XP_C2REF, &
           im%PKI%XP_C3, im%PKI%XP_C4B, im%PKI%XP_C4REF, im%PKI%XP_ACOEF, im%PKI%XP_PCOEF, &
           im%PKI%XP_TAUICE, im%PKI%XP_WDRAIN, zp_tdeep_a, im%PKI%XP_TDEEP, im%PKI%XP_GAMMAT,  &
           im%PKI%XP_PSN, im%PKI%XP_PSNG, im%PKI%XP_PSNV, im%PKI%XP_PSNV_A, &
           im%PKDI%XP_SNOWFREE_ALB_VEG, im%PKDI%XP_SNOWFREE_ALB_SOIL, im%PKI%XP_IRRIG, &
           im%PKI%XP_WATSUP, im%PKI%XP_THRESHOLD, im%PKI%XP_LIRRIGATE, im%PKI%XP_LIRRIDAY, &
           im%PKI%LP_STRESS, im%PKI%XP_GC, im%PKI%XP_F2I, im%PKI%XP_DMAX, im%PKI%XP_AH, &
           im%PKI%XP_BH, zp_co2, im%PKI%XP_GMES, im%I%XPOI, im%PKI%XP_FZERO, im%PKI%XP_EPSO, &
           im%PKI%XP_GAMM, im%PKI%XP_QDGAMM, im%PKI%XP_QDGMES, im%PKI%XP_T1GMES, im%PKI%XP_T2GMES, &
           im%PKI%XP_AMAX, im%PKI%XP_QDAMAX,  im%PKI%XP_T1AMAX, im%PKI%XP_T2AMAX, im%I%XABC, &
           im%PKI%XP_DG, im%PKI%XP_DZG, im%PKI%XP_DZDIF, im%PKI%NK_WG_LAYER, im%PKI%XP_ROOTFRAC, &
           im%PKI%XP_WFC, im%PKI%XP_WWILT, im%PKI%XP_WSAT, im%PKI%XP_BCOEF, im%PKI%XP_CONDSAT, &
           im%PKI%XP_MPOTSAT, im%PKI%XP_HCAPSOIL, im%PKI%XP_CONDDRY, im%PKI%XP_CONDSLD, im%PKI%XP_D_ICE, &
           im%PKI%XP_KSAT_ICE, im%PKI%XP_MUF, im%PKI%XP_FF, im%PKI%XP_FFG, im%PKI%XP_FFV, zp_ffgnos,  &
           zp_ffvnos, im%PKI%XP_FFROZEN, im%PKI%XP_ALBF, im%PKI%XP_EMISF, im%PKI%XP_FFLOOD, im%PKI%XP_PIFLOOD, &
           im%PKDI%XP_IFLOOD, im%PKDI%XP_PFLOOD, im%PKDI%XP_LE_FLOOD, im%PKDI%XP_LEI_FLOOD, im%I%XSODELX, &
           im%PKI%XP_LAT, im%PKI%XP_LON, im%PKI%XP_TG, im%PKI%XP_WG, im%PKI%XP_WGI, im%PKI%XP_CPS, &
           im%PKI%XP_LVTT, im%PKI%XP_LSTT, im%PKI%XP_WR, im%PKI%XP_WRL, im%PKI%XP_WRLI, im%PKI%XP_WRVN, &
           im%PKI%XP_TV, im%PKI%XP_TL, &
           im%PKI%XP_RESA, im%PKI%XP_ANFM, im%PKI%XP_FSAT, im%PKI%XP_SNOWALB, im%PKI%XP_SNOWALBVIS, &
           im%PKI%XP_SNOWALBNIR, im%PKI%XP_SNOWALBFIR, im%PKI%XP_SNOWSWE, im%PKI%XP_SNOWHEAT, &
           im%PKI%XP_SNOWRHO, im%PKI%XP_SNOWGRAN1, im%PKI%XP_SNOWGRAN2, im%PKI%XP_SNOWHIST, im%PKI%XP_SNOWAGE, &
           im%PKDI%XP_GRNDFLUX, im%PKDI%XP_HPSNOW, im%PKDI%XP_SNOWHMASS, im%PKDI%XP_RNSNOW, im%PKDI%XP_HSNOW, &
           im%PKDI%XP_GFLUXSNOW, im%PKDI%XP_USTARSNOW, im%PKDI%XP_SRSFC, im%PKDI%XP_RRSFC, im%PKDI%XP_LESL,   &
           im%PKI%XP_SNOWEMIS, im%PKDI%XP_CDSNOW, im%PKDI%XP_CHSNOW, im%PKDI%XP_TSRAD, im%PKDI%XP_TS, &
           im%PKDI%XP_HV, im%PKDI%XP_QS, im%PKDI%XP_SNOWTEMP, im%PKDI%XP_SNOWLIQ, im%PKDI%XP_SNOWDZ, &
           im%PKDI%XP_CG, im%PKDI%XP_C1, im%PKDI%XP_C2, im%PKDI%XP_WGEQ, im%PKDI%XP_CT, im%PKDI%XP_CH, im%PKDI%XP_CD, &
           im%PKDI%XP_CDN, im%PKDI%XP_RI, im%PKDI%XP_HU, im%PKDI%XP_HUG, zp_emis, im%PKDI%XP_ALBT, im%PKDI%XP_RS, &
           im%PKI%XP_LE, im%PKDI%XP_RN, im%PKDI%XP_H, im%PKDI%XP_LEI, im%PKDI%XP_LEGI, im%PKDI%XP_LEG, im%PKDI%XP_LEV, &
           im%PKDI%XP_LES, im%PKDI%XP_LER, im%PKDI%XP_LETR, im%PKDI%XP_EVAP, im%PKDI%XP_GFLUX, im%PKDI%XP_RESTORE, &
           zp_ustar, im%PKDI%XP_DRAIN, im%PKDI%XP_RUNOFF, im%PKDI%XP_MELT, im%PKDI%XP_MELTADV, im%PKI%XP_TC, &
           im%PKI%XP_QC, im%PKDI%XP_RN_ISBA, im%PKDI%XP_H_ISBA, im%PKDI%XP_LEG_ISBA, im%PKDI%XP_LEGI_ISBA, &
           im%PKDI%XP_LEV_ISBA, im%PKDI%XP_LETR_ISBA, im%PKDI%XP_USTAR_ISBA, im%PKDI%XP_LER_ISBA, im%PKDI%XP_LE_ISBA, &
           im%PKDI%XP_LEI_ISBA, im%PKDI%XP_GFLUX_ISBA, im%PKDI%XP_HORT, im%PKDI%XP_DRIP, im%PKDI%XP_RRVEG, &
           zp_ac_agg, zp_hu_agg, im%PKI%XP_FAPARC, im%PKI%XP_FAPIRC, im%PKI%XP_MUS, im%PKI%XP_LAI_EFFC, im%PKI%XP_AN,   &
           im%PKI%XP_ANDAY, zp_resp_biomass_inst, im%PKDI%XP_IACAN, im%PKI%XP_ANF, im%PKDI%XP_GPP, im%PKDI%XP_FAPAR, &
           im%PKDI%XP_FAPIR, im%PKDI%XP_FAPAR_BS, im%PKDI%XP_FAPIR_BS, im%PKDI%XP_IRRIG_FLUX, zp_deep_flux,  &
           im%PKDI%XP_SWNET_V, im%PKDI%XP_SWNET_G, im%PKDI%XP_SWNET_N, im%PKDI%XP_SWNET_NS, im%PKDI%XP_LWNET_V, &
           im%PKDI%XP_LWNET_G, im%PKDI%XP_LWNET_N, im%PKDI%XP_LEVCV, im%PKDI%XP_LESC, im%PKDI%XP_H_V_C, &
           im%PKDI%XP_H_G_C, im%PKDI%XP_LETRGV, im%PKDI%XP_LETRCV, im%PKDI%XP_LERGV, im%PKDI%XP_LELITTER, &
           im%PKDI%XP_LELITTERI,im%PKDI%XP_DRIPLIT,im%PKDI%XP_RRLIT, im%PKDI%XP_LERCV, im%PKDI%XP_H_C_A, &
           im%PKDI%XP_H_N_C, im%PKDI%XP_LE_C_A, im%PKDI%XP_LE_V_C, im%PKDI%XP_LE_G_C,im%PKDI%XP_LE_N_C, &
           im%PKDI%XP_EVAP_N_C, im%PKDI%XP_EVAP_G_C, im%PKDI%XP_SR_GN, im%PKDI%XP_MELTCV, im%PKDI%XP_FRZCV,   &
           im%PKDI%XP_SWDOWN_GN, im%PKDI%XP_LWDOWN_GN, zirrig_gr, im%PKI%XP_TOPQS, im%PKDI%XP_QSB, im%PKDI%XP_SUBL, &
           im%PKI%XP_FWTD, im%PKI%XP_WTD, im%PKDI%XP_SNDRIFT               )
!
zp_trad=im%PKDI%XP_TSRAD
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Glacier : ice runoff flux (especally for Earth System Model)
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
IF(im%I%LGLACIER)THEN
!           
  CALL hydro_glacier(im%I, &
                     ptstep,zp_snow,im%PKI%XP_SNOWRHO,im%PKI%XP_SNOWSWE,im%PKI%XP_ICE_STO,im%PKDI%XP_ICEFLUX)
!     
ENDIF
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Calculation of ISBA water and energy budget (and time tendencies of each reservoir)
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
 CALL isba_budget(im%DGEI, &
                 im%I%CISBA,im%I%TSNOW%SCHEME,im%I%LGLACIER,ptstep,          &
                 im%PKI%XP_WG,im%PKI%XP_WGI,im%PKI%XP_WR,im%PKI%XP_SNOWSWE,  &
                 im%PKI%XP_DG,im%PKI%XP_DZG,zp_wg_ini,zp_wgi_ini,zp_wr_ini,  &
                 zp_swe_ini,zp_rain,zp_snow,im%PKDI%XP_EVAP,im%PKDI%XP_DRAIN,&
                 im%PKDI%XP_RUNOFF,im%PKDI%XP_IFLOOD,im%PKDI%XP_PFLOOD,      &
                 im%PKDI%XP_LE_FLOOD, im%PKDI%XP_LEI_FLOOD,                  &
                 im%PKDI%XP_ICEFLUX,im%PKDI%XP_IRRIG_FLUX,im%PKDI%XP_SNDRIFT,&
                 im%PKI%XP_LVTT, im%PKI%XP_LSTT,                             &
                 im%PKDI%XP_DWG,im%PKDI%XP_DWGI,im%PKDI%XP_DWR,              &
                 im%PKDI%XP_DSWE,im%PKDI%XP_WATBUD                           )
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Evolution of soil albedo, when depending on surface soil wetness:
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
IF (im%I%CALBEDO=='EVOL' .AND. im%I%LECOCLIMAP) THEN
  CALL soil_albedo(im%I%CALBEDO,                                    &
                   im%PKI%XP_WSAT(:,1),im%PKI%XP_WG(:,1),                    &
                   im%PKI%XP_ALBVIS_DRY,im%PKI%XP_ALBNIR_DRY,im%PKI%XP_ALBUV_DRY,   &
                   im%PKI%XP_ALBVIS_WET,im%PKI%XP_ALBNIR_WET,im%PKI%XP_ALBUV_WET,   &
                   im%PKI%XP_ALBVIS_SOIL,im%PKI%XP_ALBNIR_SOIL,im%PKI%XP_ALBUV_SOIL )  
  !
  CALL albedo(im%I%CALBEDO,                                          &
              im%PKI%XP_ALBVIS_VEG,im%PKI%XP_ALBNIR_VEG,im%PKI%XP_ALBUV_VEG,im%PKI%XP_VEG,  &
              im%PKI%XP_ALBVIS_SOIL,im%PKI%XP_ALBNIR_SOIL,im%PKI%XP_ALBUV_SOIL,      &
              im%PKI%XP_ALBVIS,im%PKI%XP_ALBNIR,im%PKI%XP_ALBUV                      )  
END IF
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Vegetation evolution for interactive LAI
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
IF (im%I%CPHOTO=='LAI' .OR. im%I%CPHOTO=='LST' .OR. im%I%CPHOTO=='NIT' .OR. im%I%CPHOTO=='NCB') THEN
  CALL vegetation_evol(im%I%CISBA, im%I%CPHOTO, im%I%CRESPSL, im%I%CALBEDO, lagrip, im%I%LTR_ML,           &
                       im%I%LNITRO_DILU, im%I%LAGRI_TO_GRASS, im%DTI%LIMP_VEG, im%DTI%LIMP_Z0, im%DTI%LIMP_EMIS, &
                       ptstep, kmonth, kday, im%I%NSPINW, ptime, im%PKI%XP_LAT, zp_rhoa,      &
                       im%PKI%XP_DG, im%PKI%XP_DZG, im%PKI%NK_WG_LAYER,                         &                       
                       im%PKI%XP_TG, im%PKI%XP_ALBNIR_VEG, im%PKI%XP_ALBVIS_VEG, im%PKI%XP_ALBUV_VEG,         &
                       im%PKI%XP_ALBNIR_SOIL, im%PKI%XP_ALBVIS_SOIL, im%PKI%XP_ALBUV_SOIL,             &
                       im%PKI%XP_VEGTYPE_PATCH, im%PKI%XP_SEFOLD, im%PKI%XP_ANMAX, im%PKI%XP_H_TREE, im%PKI%XP_BSLAI,&
                       im%PKI%XP_LAIMIN, zp_co2, im%PKI%XP_CE_NITRO, im%PKI%XP_CF_NITRO, im%PKI%XP_CNA_NITRO, &
                       im%PKI%XP_BSLAI_NITRO, im%PKI%XP_GMES, im%PKI%XP_TAU_WOOD, im%PKI%TP_SEED,             &
                       im%PKI%TP_REAP, im%PKI%XP_AOSIP, im%PKI%XP_AOSIM, im%PKI%XP_AOSJP, im%PKI%XP_AOSJM,           &
                       im%PKI%XP_HO2IP, im%PKI%XP_HO2IM, im%PKI%XP_HO2JP, im%PKI%XP_HO2JM, im%PKI%XP_Z0EFFIP,        &
                       im%PKI%XP_Z0EFFIM, im%PKI%XP_Z0EFFJP, im%PKI%XP_Z0EFFJM, im%PKI%XP_LAI, im%PKI%XP_VEG,        &
                       im%PKI%XP_Z0, im%PKI%XP_ALBNIR, im%PKI%XP_ALBVIS, im%PKI%XP_ALBUV, im%PKI%XP_EMIS,            &
                       im%PKI%XP_ANFM, im%PKI%XP_ANDAY, im%PKI%XP_BIOMASS, im%PKI%XP_RESP_BIOMASS,            &
                       zp_resp_biomass_inst, im%PKI%XP_INCREASE, im%PKI%XP_TURNOVER, &
                       ! add optional for accurate dependency to nitrogen
                       ! limitation
                        pswdir=zp_global_sw ) 
END IF
!
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Diagnostic of respiration carbon fluxes and soil carbon evolution
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
zp_sfco2(:)=0.
im%PKDI%XP_RESP_ECO (:)=0.
im%PKDI%XP_RESP_AUTO(:)=0.
!
IF ( im%I%CPHOTO/='NON' .AND. im%I%CRESPSL/='NON' .AND. any(im%PKI%XP_LAI(:)/=xundef) ) THEN
  CALL carbon_evol(im%I%CISBA, im%I%CRESPSL, im%I%CPHOTO, ptstep, im%I%NSPINS,                   &
                   zp_rhoa, im%PKI%XP_TG, im%PKI%XP_WG, im%PKI%XP_WFC, im%PKI%XP_WWILT, im%PKI%XP_WSAT, im%PKI%XP_SAND,&
                   im%PKI%XP_DG, im%PKI%XP_DZG, im%PKI%NK_WG_LAYER,                               &                   
                   im%PKI%XP_RE25, im%PKI%XP_LAI, zp_resp_biomass_inst, im%PKI%XP_TURNOVER,       &
                   im%PKI%XP_LITTER, im%PKI%XP_LIGNIN_STRUC , im%PKI%XP_SOILCARB,                 &
                   im%PKDI%XP_RESP_AUTO, im%PKDI%XP_RESP_ECO                                 )  
  ! calculation of vegetation CO2 flux
  ! Positive toward the atmosphere
  zp_sfco2(:) = im%PKDI%XP_RESP_ECO(:) - im%PKDI%XP_GPP(:)  
END IF
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Reset effecitve roughness lentgh to its nominal value when snow has just disappeared
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
 CALL subscale_z0eff(im%PKI%XP_AOSIP,im%PKI%XP_AOSIM,im%PKI%XP_AOSJP,im%PKI%XP_AOSJM,            &
                    im%PKI%XP_HO2IP,im%PKI%XP_HO2IM,im%PKI%XP_HO2JP,im%PKI%XP_HO2JM,im%PKI%XP_Z0,      &
                    im%PKI%XP_Z0EFFIP,im%PKI%XP_Z0EFFIM,im%PKI%XP_Z0EFFJP,im%PKI%XP_Z0EFFJM,    &
                    omask=(im%PKI%XP_SNOWSWE(:,1)==0. .AND. im%PKI%XP_PSN(:)>0.)  )   
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Turbulent fluxes
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
zp_sfth(:) = im%PKDI%XP_H(:)
zp_sftq(:) = im%PKDI%XP_EVAP(:)

zp_sfu(:) = 0.
zp_sfv(:) = 0.
WHERE (zp_wind>0.)
  zp_sfu(:) = - zp_u(:)/zp_wind(:) * zp_ustar(:)**2 * zp_rhoa(:)
  zp_sfv(:) = - zp_v(:)/zp_wind(:) * zp_ustar(:)**2 * zp_rhoa(:)
END WHERE
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Scalar fluxes
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
zp_sfts(:,:) = 0.
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
! --------------------------------------------------------------------------------------
! Chemical dry deposition :
! --------------------------------------------------------------------------------------
IF (im%CHI%SVI%NBEQ>0) THEN
  IF( im%CHI%CCH_DRY_DEP == "WES89") THEN

    CALL ch_dep_isba(zp_ustar, im%PKDI%XP_HU, im%PKI%XP_PSN,             &
                        im%PKI%XP_VEG, im%PKI%XP_LAI, im%PKI%XP_SAND, im%PKI%XP_CLAY, im%PKI%XP_RESA, &
                        im%PKDI%XP_RS(:),  im%PKI%XP_Z0(:),                       &
                        zp_ta, zp_pa, zp_trad(:),                  &
                        im%PKI%XP_VEGTYPE_PATCH(:,nvt_no),                &
                        im%PKI%XP_VEGTYPE_PATCH(:,nvt_rock),              &
                        im%CHI%SVI%CSV(im%CHI%SVI%NSV_CHSBEG:im%CHI%SVI%NSV_CHSEND),                &
                        im%PKCI%XP_SOILRC_SO2,  im%PKCI%XP_SOILRC_O3 ,             &
                        im%PKCI%XP_DEP(:,1:im%CHI%SVI%NBEQ)                           )  
 
    zp_sfts(:,im%CHI%SVI%NSV_CHSBEG:im%CHI%SVI%NSV_CHSEND) = - zp_sv(:,im%CHI%SVI%NSV_CHSBEG:im%CHI%SVI%NSV_CHSEND)  &
                                                    * im%PKCI%XP_DEP(:,1:im%CHI%SVI%NBEQ)  
    IF (im%CHI%SVI%NAEREQ > 0 ) THEN
      CALL ch_aer_dep(zp_sv(:,im%CHI%SVI%NSV_AERBEG:im%CHI%SVI%NSV_AEREND),&
                           zp_sfts(:,im%CHI%SVI%NSV_AERBEG:im%CHI%SVI%NSV_AEREND),&
                           zp_ustar, im%PKI%XP_RESA,zp_ta,zp_rhoa)     
    END IF
  ELSE
    zp_sfts(:,im%CHI%SVI%NSV_CHSBEG:im%CHI%SVI%NSV_CHSEND) = 0.
    zp_sfts(:,im%CHI%SVI%NSV_AERBEG:im%CHI%SVI%NSV_AEREND) = 0.
  ENDIF
ENDIF
!
! --------------------------------------------------------------------------------------
! Dust deposition and emission:
! --------------------------------------------------------------------------------------
!
IF(im%CHI%SVI%NDSTEQ>0)THEN
  idst = im%CHI%SVI%NSV_DSTEND - im%CHI%SVI%NSV_DSTBEG + 1

  CALL coupling_dst_n(dst, im%PKI, &
            hprogram,                    &!I [char] Name of program
            ksize,      &!I [nbr] number of points in patch
            idst,                        &!I [nbr] number of dust emissions variables
            jpatch,                      &!I [idx] patch in question
            im%PKI%XP_CLAY(:,1),                &!I [frc] mass fraction clay in first soil layer
            zp_ps,                       &!I [Pa] surface pressure
            im%PKDI%XP_TS,                       &!I [K] surface temperature
            zp_qa,                       &!I [kg/kg] specific humidity
            im%PKI%XP_RESA,                     &!I [s/m] atmospheric resistance
            zp_rhoa,                     &!I [kg/m3] atmospheric density
            im%PKI%XP_SAND(:,1),                &!I [frc] mass fraction of sand in first soil layer
            zp_pa,                       &!I [K] Atmospheric pressure
            zp_ta,                       &!I [K] Atmospheric temperature
            im%PKI%XP_TG(:,1),                  &!I [K] Ground temperature
            zp_u,                        &!I [m/s] zonal wind at atmospheric height 
            zp_uref,                     &!I [m] reference height of wind
            zp_v,                        &!I [m/s] meridional wind at atmospheric height
            im%PKI%XP_WG(:,1),                  &!I [m3/m3] ground volumetric water content
            im%PKI%XP_WSAT(:,1),                &!I [m3/m3] saturation volumetric water content
            zp_zref,                     &!I [m] reference height of wind
            im%PKDI%XP_CD,                       &!I [] Drag Coefficient for momentum
            im%PKDI%XP_CDN,                      &!I [] Drag neutral Coefficient for momentum
            im%PKDI%XP_CH,                       &!I [] drag coefficient for heat
            im%PKDI%XP_RI,                       &!I [] Richardson number
            im%PKDI%XP_Z0H_WITH_SNOW,            &!I [frc] Z0 (heat) with snow
            zp_sfts(:,im%CHI%SVI%NSV_DSTBEG:im%CHI%SVI%NSV_DSTEND)  &!O [kg/m2/sec] flux of dust            
            )  
!
   IF (im%CHI%SVI%NSV_AEREND > 0)  THEN ! case of dust/ anthropogenic aerosols coupling
     DO jmode=1,ndstmde
       !
       !Make index which is 0 for first mode, 3 for second, 6 for third etc
       IF (lvarsig_dst) THEN
         jsv_idx = (jmode-1)*3
       ELSE IF (lrgfix_dst) THEN
         jsv_idx = jmode-2
       ELSE
         jsv_idx = (jmode-1)*2
       END IF
       !
       DO jsv=1, size(hsv)
         IF ((trim(hsv(jsv)) == "@DSTI").AND.(jmode==3)) THEN 
           ! add dust flux and conversion kg/m2/s into molec.m2/s
           zp_sfts(:,jsv) = zp_sfts(:,jsv) + zp_sfts(:,im%CHI%SVI%NSV_DSTBEG-1+jsv_idx+2)*xavogadro/xmolarweight_dst
         END IF
         IF ( (trim(hsv(jsv)) == "@DSTJ").AND.(jmode==2)) THEN 
           ! add dust flux and conversion kg/m2/sec into molec.m2/s
           zp_sfts(:,jsv) = zp_sfts(:,jsv) + zp_sfts(:,im%CHI%SVI%NSV_DSTBEG-1+jsv_idx+2)*xavogadro/xmolarweight_dst
         END IF
       END DO
       !
     END DO
    END IF
!    
!Modify fluxes due to dry deposition, we introduce a negative flux where dust is lost
  CALL dslt_dep(zp_sv(:,im%CHI%SVI%NSV_DSTBEG:im%CHI%SVI%NSV_DSTEND), &
                zp_sfts(:,im%CHI%SVI%NSV_DSTBEG:im%CHI%SVI%NSV_DSTEND), &
                zp_ustar, im%PKI%XP_RESA, zp_ta, zp_rhoa, dst%XEMISSIG_DST, dst%XEMISRADIUS_DST, &
                jpmode_dst, xdensity_dst, xmolarweight_dst, zconvertfacm0_dst,    &
                zconvertfacm6_dst, zconvertfacm3_dst, lvarsig_dst, lrgfix_dst,    &
                cvermod  )
!
!Transfer these fluxes to fluxes understandable by all moments
  CALL massflux2momentflux(           &
    zp_sfts(:,im%CHI%SVI%NSV_DSTBEG:im%CHI%SVI%NSV_DSTEND), & !I/O ![kg/m2/sec] In: flux of only mass, out: flux of moments
    zp_rhoa,                          & !I [kg/m3] air density
    dst%XEMISRADIUS_DST,                  &!I [um] emitted radius for the modes (max 3)
    dst%XEMISSIG_DST,                     &!I [-] emitted sigma for the different modes (max 3)
    ndstmde,                          &
    zconvertfacm0_dst,                &
    zconvertfacm6_dst,                &
    zconvertfacm3_dst,                &
    lvarsig_dst, lrgfix_dst           )   
!
ENDIF !Check on CDSTYN
!
! --------------------------------------------------------------------------------------
! Sea Salt deposition
! --------------------------------------------------------------------------------------
!
IF (im%CHI%SVI%NSLTEQ>0) THEN
  CALL dslt_dep(zp_sv(:,im%CHI%SVI%NSV_SLTBEG:im%CHI%SVI%NSV_SLTEND), &
                zp_sfts(:,im%CHI%SVI%NSV_SLTBEG:im%CHI%SVI%NSV_SLTEND), &
                zp_ustar, im%PKI%XP_RESA, zp_ta, zp_rhoa, slt%XEMISSIG_SLT, slt%XEMISRADIUS_SLT, &
                jpmode_slt, xdensity_slt, xmolarweight_slt, zconvertfacm0_slt,    &
                zconvertfacm6_slt, zconvertfacm3_slt, lvarsig_slt, lrgfix_slt,    &
                cvermod  )  

  CALL massflux2momentflux(           &
    zp_sfts(:,im%CHI%SVI%NSV_SLTBEG:im%CHI%SVI%NSV_SLTEND), & !I/O ![kg/m2/sec] In: flux of only mass, out: flux of moments
    zp_rhoa,                          & !I [kg/m3] air density
    slt%XEMISRADIUS_SLT,                  &!I [um] emitted radius for the modes (max 3)
    slt%XEMISSIG_SLT,                     &!I [-] emitted sigma for the different modes (max 3)
    nsltmde,                          &
    zconvertfacm0_slt,                &
    zconvertfacm6_slt,                &
    zconvertfacm3_slt,                &
    lvarsig_slt, lrgfix_slt         ) 
ENDIF !Check on CSLTYN
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Inline diagnostics
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
 CALL diag_inline_isba_n(im%DGEI, im%DGI, im%I, im%PKDI, &
                         zp_ta, im%PKDI%XP_TS, zp_qa, zp_pa, zp_ps, zp_rhoa, zp_u, zp_v,       &
                          zp_zref, zp_uref,                                            &
                          im%PKDI%XP_CD, im%PKDI%XP_CDN, im%PKDI%XP_CH, im%PKDI%XP_RI, &
                          im%PKDI%XP_HU, im%PKDI%XP_Z0_WITH_SNOW,         &
                          im%PKDI%XP_Z0H_WITH_SNOW, im%PKDI%XP_Z0EFF,                                  &
                          zp_sfth, zp_sftq, zp_sfu, zp_sfv, im%PKDI%XP_QS,                     &
                          im%PKI%XP_DIR_ALB_WITH_SNOW, im%PKI%XP_SCA_ALB_WITH_SNOW,                  &
                          zp_dir_sw, zp_sca_sw, zp_lw, im%PKDI%XP_RN                           )  
!
!
!-------------------------------------------------------------------------------
!Physical properties see by the atmosphere in order to close the energy budget 
!between surfex and the atmosphere. All variables should be at t+1 but very 
!difficult to do. Maybe it will be done later. However, Ts can be at time t+1
!-------------------------------------------------------------------------------
!
zp_tsurf(:) = im%PKDI%XP_TS (:)
zp_z0(:) = im%PKDI%XP_Z0_WITH_SNOW (:)
zp_z0h(:) = im%PKDI%XP_Z0H_WITH_SNOW(:)
zp_qsurf(:) = im%PKDI%XP_QS (:)
!
!-------------------------------------------------------------------------------
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Isba offline diagnostics for each patch
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
 CALL diag_evap_isba_n(im%DGEI, im%DGI, im%I, im%PKDI, im%PKI, &
                       im%I%CPHOTO,ptstep,kmask,ksize,jpatch,zp_rhoa)
!
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! Isba offline diagnostics for miscellaneous terms over each patch
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
 CALL diag_misc_isba_n(im%DGMI, im%PKDI, &
                       ptstep, im%I%CISBA, im%I%CPHOTO, im%I%TSNOW%SCHEME, lagrip, im%I%LTR_ML,    &
                      ptime, ksize, jpatch, kmask, im%PKI%XP_THRESHOLD,              &
                      im%PKI%XP_PSN, im%PKI%XP_PSNG, im%PKI%XP_PSNV, im%PKI%XP_FF, im%PKI%XP_FFG, im%PKI%XP_FFV,        &
                      im%PKI%XP_WG, im%PKI%XP_WGI, im%PKI%XP_WFC, im%PKI%XP_WWILT, im%PKI%XP_SNOWSWE, im%PKI%XP_SNOWRHO,&
                      im%PKI%XP_FAPARC, im%PKI%XP_FAPIRC, im%PKI%XP_LAI_EFFC, im%PKI%XP_MUS, im%PKI%XP_FSAT,     &
                      im%PKI%XP_DG, im%PKI%XP_TG       )                  
!
! Unpack ISBA diagnostics (modd_diag_isban) for each patch:ISIZE_MAX = MAXVAL(NSIZE_NATURE_P)

!  (MUST be done BEFORE UNPACK_ISBA_PATCH, because of XP_LE)
!
 CALL unpack_diag_patch_n(im%DGI, im%GB, im%I, im%PKDI, im%PKI, &
                          kmask,ksize,im%I%NPATCH,jpatch, &
                           zcpl_drain,zcpl_runoff,zcpl_eflood,zcpl_pflood,           &
                           zcpl_iflood, zcpl_iceflux)  
!
! for chemical deposition
!
IF (im%CHI%SVI%NBEQ>0) THEN
  IF( im%CHI%CCH_DRY_DEP == "WES89") THEN
    CALL unpack_ch_isba_patch_n(im%CHI, im%PKCI, &
                                kmask,ksize,im%I%NPATCH,jpatch)     
  END IF
END IF
!
! Unpack ISBA variables (modd_isban) for each patch:
!
 CALL unpack_isba_patch_n(im%AG, im%I, im%PKI, &
                          kmask,ksize,jpatch)
!
!----------------------------------------------------------------------
!
! for further chemical biogenic emissions
!
IF (im%CHI%SVI%NBEQ>0 .AND. im%CHI%LCH_BIO_FLUX) THEN
  !
  DO jj=1,ksize
    zsw_forbio(kmask(jj),jpatch) = 0.
  ENDDO
  !
  DO jswb=1,iswb
!cdir nodep
!cdir unroll=8
    DO jj=1,ksize
      zsw_forbio(kmask(jj),jpatch) = zsw_forbio(kmask(jj),jpatch)              &
                                     + zp_dir_sw(jj,jswb) + zp_sca_sw(jj,jswb)  
    ENDDO
  ENDDO
  !
ENDIF
!----------------------------------------------------------------------
!
! Unpack output dummy arguments for each patch:
!
IF (im%I%NPATCH==1) THEN
   zsftq_tile(:,jpatch)  = zp_sftq(:)
   zsfth_tile(:,jpatch)  = zp_sfth(:)
   zsfts_tile(:,:,jpatch)= zp_sfts(:,:)
   zsfco2_tile(:,jpatch)  = zp_sfco2(:)
   zsfu_tile(:,jpatch)  = zp_sfu(:)
   zsfv_tile(:,jpatch)  = zp_sfv(:)
   ztrad_tile(:,jpatch)  = zp_trad(:)
   ztsurf_tile(:,jpatch)  = zp_tsurf(:)
   zz0_tile(:,jpatch)  = zp_z0(:)
   zz0h_tile(:,jpatch)  = zp_z0h(:)
   zqsurf_tile(:,jpatch)  = zp_qsurf(:)   
ELSE
!cdir nodep
!cdir unroll=8
 DO jj=1,ksize
   ji = kmask(jj)
   zsftq_tile(ji,jpatch)  = zp_sftq(jj)
   zsfth_tile(ji,jpatch)  = zp_sfth(jj)
   zsfco2_tile(ji,jpatch)  = zp_sfco2(jj)
   zsfu_tile(ji,jpatch)  = zp_sfu(jj)
   zsfv_tile(ji,jpatch)  = zp_sfv(jj)
   ztrad_tile(ji,jpatch)  = zp_trad(jj)
   ztsurf_tile(ji,jpatch)  = zp_tsurf(jj)
   zz0_tile(ji,jpatch)  = zp_z0(jj)
   zz0h_tile(ji,jpatch)  = zp_z0h(jj)
   zqsurf_tile(ji,jpatch)  = zp_qsurf(jj)   
 ENDDO
!
!cdir nodep
!cdir unroll=8
  DO jk=1,SIZE(zp_sfts,2)
    DO jj=1,ksize
      ji=kmask(jj)    
      zsfts_tile(ji,jk,jpatch)= zp_sfts(jj,jk)
    ENDDO
  ENDDO
ENDIF
!
!----------------------------------------------------------------------
!
! Get output dust flux if we are calculating dust
IF (ndstmde .GE. 1) imoment = int(idst / ndstmde)
IF (im%CHI%SVI%NDSTEQ>0) THEN
  DO jsv = 1,ndstmde
    IF (imoment == 1) THEN
      dst%XSFDST(:,jsv,jpatch)=zsfts_tile(:,ndst_mdebeg+jsv-1,jpatch)
    ELSE
      dst%XSFDST(:,jsv,jpatch)=zsfts_tile(:,ndst_mdebeg+(jsv-1)*imoment+1,jpatch)
    END IF

    dst%XSFDSTM(:,jsv,jpatch)=dst%XSFDSTM(:,jsv,jpatch) + dst%XSFDST(:,jsv,jpatch) * ptstep
  ENDDO
ENDIF
!
IF (lhook) CALL dr_hook('COUPLING_ISBA_n:TREAT_PATCH',1,zhook_handle)
!
END SUBROUTINE treat_patch
!==========================================================================================
END SUBROUTINE coupling_isba_n