isba_budget.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE isba_budget (DGEI, &
                        hisba, hsnow_isba, oglacier, ptstep,    &
                        pwg, pwgi, pwr, psnowswe, pdg, pdzg,    &
                        pwg_ini, pwgi_ini, pwr_ini, pswe_ini,   & 
                        prain, psnow, pevap, pdrain, prunoff,   &
                        piflood, ppflood, ple_flood, plei_flood,&
                        piceflux, pirrig_flux, psndrift,        &
                        plvtt, plstt,                           &
                        pdwg, pdwgi, pdwr, pdswe, pwatbud       )
!     ###############################################################################
!
!!****  *ISBA_BUDGET * - water and energy budget for ISBA
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2012
!!
!!      B. Decharme    01/16 : Bug with flood budget
!!------------------------------------------------------------------
!
!
USE modd_diag_evap_isba_n, ONLY : diag_evap_isba_t
!
USE modd_surf_par,   ONLY : xundef
USE modd_csts,       ONLY : xrholw
!     
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_evap_isba_t), INTENT(INOUT) :: dgei
!
 CHARACTER(LEN=*),      INTENT(IN) :: hisba      ! type of ISBA version:
!                                               ! '2-L' (default)
!                                               ! '3-L'
!                                               ! 'DIF'
 CHARACTER(LEN=*),     INTENT(IN)  :: hsnow_isba ! 'DEF' = Default F-R snow scheme
!                                               !         (Douville et al. 1995)
!                                               ! '3-L' = 3-L snow scheme (option)
!                                               !         (Boone and Etchevers 2000)
!                                               ! 'CRO' = Crocus snow scheme
LOGICAL,               INTENT(IN) :: oglacier   ! True = glacier over permanent snow and ice
                                                ! False = No specific treatment
REAL,                  INTENT(IN) :: ptstep     ! timestep of the integration    (s)
!
REAL, DIMENSION(:,:),  INTENT(IN) :: pwg        ! liquid water content by layer  (m3/m3)
REAL, DIMENSION(:,:),  INTENT(IN) :: pwgi       ! ice content by layer           (m3/m3)
REAL, DIMENSION(:),    INTENT(IN) :: pwr        ! liquid water on veg canopy     (kg m-2)
REAL, DIMENSION(:,:),  INTENT(IN) :: psnowswe   ! snow water equivalent by layer (kg m-2)
REAL, DIMENSION(:,:),  INTENT(IN) :: pdg        ! soil layer depth               (m)
REAL, DIMENSION(:,:),  INTENT(IN) :: pdzg       ! soil layer thickness           (m)
!
REAL, DIMENSION(:),    INTENT(IN) :: pwg_ini    ! total wg at t-1                (kg m-2)
REAL, DIMENSION(:),    INTENT(IN) :: pwgi_ini   ! total wgi at t-1               (kg m-2)
REAL, DIMENSION(:),    INTENT(IN) :: pwr_ini    ! total wr at t-1                (kg m-2)
REAL, DIMENSION(:),    INTENT(IN) :: pswe_ini   ! total swe at t-1               (kg m-2)
!
REAL, DIMENSION(:),    INTENT(IN)  :: prain     ! Rain rate                      (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: psnow     ! Snow rate                      (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: pevap     ! total evaporative flux         (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: pdrain    ! drainage                       (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: prunoff   ! surface runoff                 (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: piflood   ! Floodplain infiltration        (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: ppflood   ! Floodplain direct precip runoff(kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: ple_flood ! Floodplain latent heat         (W/m2)
REAL, DIMENSION(:),    INTENT(IN)  :: plei_flood! Floodplain sublimation heat    (W/m2)
REAL, DIMENSION(:),    INTENT(IN)  :: piceflux  ! Ice flux from Snow reservoir   (kg/m2/s)
REAL ,DIMENSION(:),    INTENT(IN)  :: pirrig_flux! additional water flux from irrigation (kg/m2/s)
REAL ,DIMENSION(:),    INTENT(IN)  :: psndrift   ! blowing snow sublimation (kg/m2/s)
REAL, DIMENSION(:),    INTENT(IN)  :: plvtt, plstt    
! 
REAL, DIMENSION(:),    INTENT(OUT) :: pdwg
REAL, DIMENSION(:),    INTENT(OUT) :: pdwgi
REAL, DIMENSION(:),    INTENT(OUT) :: pdwr
REAL, DIMENSION(:),    INTENT(OUT) :: pdswe
REAL, DIMENSION(:),    INTENT(OUT) :: pwatbud   ! ISBA water budget              (kg/m2/s)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PWR)) :: zinput
REAL, DIMENSION(SIZE(PWR)) :: zoutput
REAL, DIMENSION(SIZE(PWR)) :: ztendency
REAL, DIMENSION(SIZE(PWR)) :: ziceflux
REAL, DIMENSION(SIZE(PWR)) :: zswe_t
REAL, DIMENSION(SIZE(PWR)) :: zwg_t
REAL, DIMENSION(SIZE(PWR)) :: zwgi_t
REAL, DIMENSION(SIZE(PWR)) :: zsndrift
REAL, DIMENSION(SIZE(PWR)) :: zeflood
!
INTEGER :: ini, inl, inls
INTEGER :: ji, jl
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('ISBA_BUDGET',0,zhook_handle)
!
!*      1.0    Init
!       -----------
!
ini =SIZE(pwg,1)
inl =SIZE(pwg,2)
inls=SIZE(psnowswe,2)
!
pdwg(:) = xundef
pdwgi(:) = xundef
pdwr(:) = xundef
pdswe(:) = xundef
!
IF (hsnow_isba=='3-L'.OR.hsnow_isba=='CRO') THEN
   zsndrift(:)=psndrift(:)
ELSE
   zsndrift(:)=0.0
ENDIF
!
!*      2.0    Comptut isba water budget in kg/m2/s
!       -------------------------------------------
!
IF(dgei%LWATER_BUDGET)THEN
!
! total swe at t in kg/m2
  zswe_t(:)=0.0
  DO jl=1,inls
     DO ji=1,ini
        zswe_t(ji)=zswe_t(ji)+psnowswe(ji,jl)
     ENDDO
  ENDDO
!
! total wg and wgi at t in kg/m2
  zwg_t(:)= 0.0
  zwgi_t(:)= 0.0
  IF(hisba=='DIF')THEN
    DO jl=1,inl
       DO ji=1,ini
          IF(pwg(ji,jl)/=xundef)THEN
             zwg_t(ji)=zwg_t(ji)+pwg(ji,jl)*pdzg(ji,jl)*xrholw
             zwgi_t(ji)=zwgi_t(ji)+pwgi(ji,jl)*pdzg(ji,jl)*xrholw
          ENDIF
       ENDDO
    ENDDO
  ELSE
    zwg_t(:)=pwg(:,2)*pdg(:,2)*xrholw
    zwgi_t(:)=pwgi(:,2)*pdg(:,2)*xrholw
    IF(hisba=='3-L')THEN
      zwg_t(:)=zwg_t(:)+pwg(:,3)*(pdg(:,3)-pdg(:,2))*xrholw
    ENDIF
  ENDIF
!
! Comptut reservoir time tendencies in kg/m2/s
  pdwg(:) = (zwg_t(:)-pwg_ini(:))/ptstep
  pdwgi(:) = (zwgi_t(:)-pwgi_ini(:))/ptstep
  pdwr(:) = (pwr(:)-pwr_ini(:))/ptstep
  pdswe(:) = (zswe_t(:)-pswe_ini(:))/ptstep
!
! ice calving flux if used
  IF(oglacier)THEN
    ziceflux(:)=piceflux(:)
  ELSE
    ziceflux(:)=0.0
  ENDIF
!
! Floodplains evaporation (kg/m2/s)
  zeflood(:)=ple_flood(:)/plvtt(:)+plei_flood(:)/plstt(:)
!
! total input water in the system at t
  zinput(:)=prain(:)+psnow(:)+piflood(:)+pirrig_flux(:)
!
! total output water in the system at t
  zoutput(:) = pevap(:)+pdrain(:)+prunoff(:) &
             + ppflood(:)+ziceflux(:)+zsndrift(:) &
             - zeflood(:)
!
! total reservoir time tendencies at "t - (t-1)"
  ztendency(:) = pdwg(:)+pdwgi(:)+pdwr(:)+pdswe(:)
!
! isba water budget (dw/dt=in-out) in kg/m2/s
  pwatbud(:)=ztendency(:)-(zinput(:)-zoutput(:))
!
ENDIF
!
!*      3.0    Comptut isba energy budget in W/m2
!       -----------------------------------------
!
! not yet implemented
!
IF (lhook) CALL dr_hook('ISBA_BUDGET',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE isba_budget