isba_budget_init.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE isba_budget_init (DGEI, &
                             hisba, hsnow_isba,                   &
                            pwg, pwgi, pwr, psnowswe, pdg, pdzg, &
                            pwg_ini, pwgi_ini, pwr_ini, pswe_ini )
!     ###############################################################################
!
!!****  *ISBA_BUDGET_INIT * - initialize water and energy budget for ISBA
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    10/2012
!!
!!------------------------------------------------------------------
!
!
USE modd_diag_evap_isba_n, ONLY : diag_evap_isba_t
!
USE modd_surf_par,   ONLY : xundef
USE modd_csts,       ONLY : xrholw
!    
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_evap_isba_t), INTENT(INOUT) :: dgei
!
 CHARACTER(LEN=*),     INTENT(IN)  :: hisba      ! type of ISBA version:
!                                               ! '2-L' (default)
!                                               ! '3-L'
!                                               ! 'DIF'
 CHARACTER(LEN=*),     INTENT(IN)  :: hsnow_isba ! 'DEF' = Default F-R snow scheme
!                                               !         (Douville et al. 1995)
!                                               ! '3-L' = 3-L snow scheme (option)
!                                               !         (Boone and Etchevers 2000)
!                                               ! 'CRO' = Crocus snow scheme
!
REAL, DIMENSION(:,:),  INTENT(IN) :: pwg        ! liquid water content by layer  (m3/m3)
REAL, DIMENSION(:,:),  INTENT(IN) :: pwgi       ! ice content by layer           (m3/m3)
REAL, DIMENSION(:),    INTENT(IN) :: pwr        ! liquid water on veg canopy     (kg m-2)
REAL, DIMENSION(:,:),  INTENT(IN) :: psnowswe   ! snow water equivalent by layer (kg m-2)
REAL, DIMENSION(:,:),  INTENT(IN) :: pdg        ! soil layer depth               (m)
REAL, DIMENSION(:,:),  INTENT(IN) :: pdzg       ! soil layer thickness           (m)
!
REAL, DIMENSION(:), INTENT(OUT)   :: pwg_ini    ! total wg at t-1                (kg m-2)
REAL, DIMENSION(:), INTENT(OUT)   :: pwgi_ini   ! total wgi at t-1               (kg m-2)
REAL, DIMENSION(:), INTENT(OUT)   :: pwr_ini    ! total wr at t-1                (kg m-2)
REAL, DIMENSION(:), INTENT(OUT)   :: pswe_ini   ! total swe at t-1               (kg m-2)
!
!*      0.2    declarations of local variables
!
INTEGER :: ini, inl, inls
INTEGER :: ji, jl
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('ISBA_BUDGET_INIT',0,zhook_handle)
!
ini =SIZE(pwg,1)
inl =SIZE(pwg,2)
inls=SIZE(psnowswe,2)
!
pwg_ini(:) = xundef
pwgi_ini(:) = xundef
pswe_ini(:) = xundef
pwr_ini(:) = xundef
!
!
! * Water budget
!   ------------
!
IF(dgei%LWATER_BUDGET)THEN
!
! total wr at t-1
  pwr_ini(:)=pwr(:)
!
! total swe at t-1
  pswe_ini(:)=0.0
  DO jl=1,inls
     DO ji=1,ini
        pswe_ini(ji)=pswe_ini(ji)+psnowswe(ji,jl)
     ENDDO
  ENDDO
!
! total wg and wgi at t-1
  pwg_ini(:)= 0.0
  pwgi_ini(:)= 0.0
  IF(hisba=='DIF')THEN
    DO jl=1,inl
       DO ji=1,ini
          IF(pwg(ji,jl)/=xundef)THEN
             pwg_ini(ji)=pwg_ini(ji)+pwg(ji,jl)*pdzg(ji,jl)*xrholw
             pwgi_ini(ji)=pwgi_ini(ji)+pwgi(ji,jl)*pdzg(ji,jl)*xrholw
          ENDIF
       ENDDO
    ENDDO
  ELSE
    pwg_ini(:)=pwg(:,2)*pdg(:,2)*xrholw
    pwgi_ini(:)=pwgi(:,2)*pdg(:,2)*xrholw
    IF(hisba=='3-L')THEN
      pwg_ini(:)=pwg_ini(:)+pwg(:,3)*(pdg(:,3)-pdg(:,2))*xrholw
    ENDIF
  ENDIF
!
ENDIF
!
! * Energy budget
!   -------------
!
! not yet implemented
!
!
IF (lhook) CALL dr_hook('ISBA_BUDGET_INIT',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE isba_budget_init