average_phy.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE average_phy(PFRAC_TILE,             &
                   ptsurf_tile, pz0_tile,               &
                   pz0h_tile, pqsurf_tile,              &   
                   puref, pzref,                        &
                   ptsurf, pz0, pz0h, pqsurf            )  
!     ######################################################################
!
!
!!****  *AVERAGE_PHY*  
!!
!!    PURPOSE
!!    -------
!      Average the physical properties from the land and water surfaces depending on the
!      fraction of each surface cover type in the mesh area.
!     
!!**  METHOD
!!    ------
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------ 
!!
!!      
!!    REFERENCE
!!    ---------
!!      
!!    AUTHOR
!!    ------
!!      B. Decharme          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    23/04/2013 
!
!      B. Decharme 07/2015 - Modification to deal with E-zone points in Arome/Aladin
!-----------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE modd_surf_par,   ONLY : xundef
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!*      0.1    declarations of arguments
!
REAL, DIMENSION(:,:), INTENT(IN) :: pfrac_tile ! Fraction in a mesh-area of 
!
REAL, DIMENSION(:,:), INTENT(IN) :: ptsurf_tile ! surface effective temperature (K)
REAL, DIMENSION(:,:), INTENT(IN) :: pz0_tile    ! roughness length for momentum (m)
REAL, DIMENSION(:,:), INTENT(IN) :: pz0h_tile   ! roughness length for heat     (m)
REAL, DIMENSION(:,:), INTENT(IN) :: pqsurf_tile ! specific humidity at surface  (kg/kg)
!
REAL, DIMENSION(:),   INTENT(IN) :: puref     ! height of wind forcing                (m)
REAL, DIMENSION(:),   INTENT(IN) :: pzref     ! height of T,q forcing                 (m)
REAL, DIMENSION(:),   INTENT(OUT):: ptsurf    ! surface effective temperature   (K)
REAL, DIMENSION(:),   INTENT(OUT):: pz0       ! roughness length for momentum   (m)
REAL, DIMENSION(:),   INTENT(OUT):: pz0h      ! roughness length for heat       (m)
REAL, DIMENSION(:),   INTENT(OUT):: pqsurf    ! specific humidity at surface    (kg/kg)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PUREF)) :: zwork_z0       ! work array for roughness length for momentum 
REAL, DIMENSION(SIZE(PUREF)) :: zwork_z0h      ! work array for roughness length for heat     
!
INTEGER :: ini, inp  ! dimenssion
INTEGER ::  ji, jp    ! loop counter
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!       0.     Initialization
!              --------------
!
IF (lhook) CALL dr_hook('AVERAGE_PHY',0,zhook_handle)
!
ini  = SIZE(pfrac_tile,1)
inp  = SIZE(pfrac_tile,2)
!
ptsurf(:)   = 0.
pz0(:)   = 0.
pz0h(:)   = 0.
pqsurf(:)   = 0.
!
zwork_z0(:)   = 0.
zwork_z0h(:)   = 0.
!
!       1.     Grid-Box average 
!              ----------------
DO jp = 1, inp
!
  DO ji = 1, ini
!  
!    surface effective temperature
!
     ptsurf(ji) = ptsurf(ji) + pfrac_tile(ji,jp) * ptsurf_tile(ji,jp)
!
!    specific humidity at surface
!
     pqsurf(ji) = pqsurf(ji) + pfrac_tile(ji,jp) * pqsurf_tile(ji,jp)
!
!    roughness length for momentum and heat
!
     zwork_z0(ji) = zwork_z0(ji) + pfrac_tile(ji,jp) * 1.0/(log(puref(ji)/pz0_tile(ji,jp)))**2
     zwork_z0h(ji) = zwork_z0h(ji) + pfrac_tile(ji,jp) * 1.0/(log(pzref(ji)/pz0h_tile(ji,jp)))**2
!
  ENDDO
!
ENDDO
!

DO ji = 1, ini
 IF(zwork_z0(ji) /= 0 ) then
   pz0(ji) = puref(ji) * exp( - sqrt(1./zwork_z0(ji)) )
   pz0h(ji) = pzref(ji) * exp( - sqrt(1./zwork_z0h(ji)) )
 ELSE
   pz0(ji) = xundef
   pz0h(ji) = xundef
 ENDIF
ENDDO
!
IF (lhook) CALL dr_hook('AVERAGE_PHY',1,zhook_handle)

!-------------------------------------------------------------------------------
!
END SUBROUTINE average_phy