diag_inline_isban.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
 SUBROUTINE diag_inline_isba_n (DGEI, DGI, I, PKDI, &
                                 pta, pts, pqa, ppa, pps, prhoa, pzona, pmera,  &
                                  pht, phw, pcd, pcdn, pch, pri, phu, pz0, pz0h, &
                                  pz0eff, psfth, psftq, psfzon, psfmer, pqs,     &
                                  pdir_alb, psca_alb, pdir_sw, psca_sw, plw, prn )  
!     ###############################################################################
!
!!****  *DIAG_INLINE_ISBA_n * - computes diagnostics during ISBA time-step
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      B. Decharme 08/2009 caculate cumulated diag LSURF_BUDGETC
!!      S. Riette   06/2009 CLS_2M becomes CLS_TQ, CLS_TQ and CLS_WIND have one
!!                          more argument (height of diagnostic)
!!------------------------------------------------------------------
!

!
!
!
USE modd_diag_evap_isba_n, ONLY : diag_evap_isba_t
USE modd_diag_isba_n, ONLY : diag_isba_t
USE modd_isba_n, ONLY : isba_t
USE modd_pack_diag_isba, ONLY : pack_diag_isba_t
!
USE modd_surf_par,         ONLY : xundef
!
USE modi_param_cls
USE modi_cls_tq
USE modi_cls_wind
USE modi_diag_surf_budget_isba
! 
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(diag_evap_isba_t), INTENT(INOUT) :: dgei
TYPE(diag_isba_t), INTENT(INOUT) :: dgi
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(pack_diag_isba_t), INTENT(INOUT) :: pkdi
!
REAL, DIMENSION(:), INTENT(IN)       :: pta      ! atmospheric temperature
REAL, DIMENSION(:), INTENT(IN)       :: pts      ! surface temperature
REAL, DIMENSION(:), INTENT(IN)       :: pqa      ! atmospheric specific humidity
REAL, DIMENSION(:), INTENT(IN)       :: ppa      ! atmospheric level pressure
REAL, DIMENSION(:), INTENT(IN)       :: pps      ! surface pressure
REAL, DIMENSION(:), INTENT(IN)       :: prhoa    ! air density
REAL, DIMENSION(:), INTENT(IN)       :: pzona    ! zonal wind
REAL, DIMENSION(:), INTENT(IN)       :: pmera    ! meridian wind
REAL, DIMENSION(:), INTENT(IN)       :: pht      ! atmospheric level height
REAL, DIMENSION(:), INTENT(IN)       :: phw      ! atmospheric level height for wind
REAL, DIMENSION(:), INTENT(IN)       :: pcd      ! drag coefficient for momentum
REAL, DIMENSION(:), INTENT(IN)       :: pcdn     ! neutral drag coefficient
REAL, DIMENSION(:), INTENT(IN)       :: pch      ! drag coefficient for heat
REAL, DIMENSION(:), INTENT(IN)       :: pri      ! Richardson number
REAL, DIMENSION(:), INTENT(IN)       :: phu      ! near-surface humidity
REAL, DIMENSION(:), INTENT(IN)       :: pz0      ! roughness length for momentum
REAL, DIMENSION(:), INTENT(IN)       :: pz0h     ! roughness length for heat
REAL, DIMENSION(:), INTENT(IN)       :: pz0eff   ! effective roughness length (z0+z0rel)
REAL, DIMENSION(:), INTENT(IN)       :: pqs      ! humidity at surface 
REAL, DIMENSION(:,:), INTENT(IN)     :: pdir_alb ! direct albedo for each spectral band
REAL, DIMENSION(:,:), INTENT(IN)     :: psca_alb ! diffuse albedo for each spectral band (-)
REAL, DIMENSION(:,:), INTENT(IN)     :: pdir_sw  ! direct  solar radiation (on horizontal surf.)
REAL, DIMENSION(:,:), INTENT(IN)     :: psca_sw  ! diffuse solar radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN)       :: plw      ! longwave radiation (on horizontal surf.)
REAL, DIMENSION(:), INTENT(IN)       :: prn      ! Surface net radiation
!
REAL, DIMENSION(:), INTENT(IN)       :: psfzon   ! zonal friction
REAL, DIMENSION(:), INTENT(IN)       :: psfmer   ! meridian friction
REAL, DIMENSION(:), INTENT(IN)       :: psfth    ! heat flux (W/m2)
REAL, DIMENSION(:), INTENT(IN)       :: psftq    ! water flux (kg/m2/s)
!
!*      0.2    declarations of local variables
!
REAL, DIMENSION(SIZE(PTA)) :: zh
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('DIAG_INLINE_ISBA_N',0,zhook_handle)
!
! * Richardson number
!
IF (dgi%N2M>=1) THEN
    pkdi%XP_RI     = pri        
ENDIF
!
! * Near surface atmospheric variables
!
IF (.NOT. i%LCANOPY) THEN
!        
  IF (dgi%N2M==1) THEN
    CALL param_cls(pta, pts, pqa, ppa, prhoa, pzona, pmera, pht, phw,  &
                     psfth, psftq, psfzon, psfmer,                     &
                     pkdi%XP_T2M, pkdi%XP_Q2M, pkdi%XP_HU2M, pkdi%XP_ZON10M, pkdi%XP_MER10M     )  
  ELSE IF (dgi%N2M==2) THEN
    zh(:)=2.          
    CALL cls_tq(pta, pqa, ppa, pps, pht,           &
                  pcd, pch, pri,                   &
                  pts, phu, pz0h, zh,              &
                  pkdi%XP_T2M, pkdi%XP_Q2M, pkdi%XP_HU2M          )  
    zh(:)=10.                
    CALL cls_wind(pzona, pmera, phw,               &
                    pcd, pcdn, pri, zh,            &
                    pkdi%XP_ZON10M, pkdi%XP_MER10M           )  
  END IF
!
ELSE
  !        
  IF (dgi%N2M>=1) THEN
    pkdi%XP_T2M    = xundef
    pkdi%XP_Q2M    = xundef
    pkdi%XP_HU2M   = xundef
    pkdi%XP_ZON10M = xundef
    pkdi%XP_MER10M = xundef
  ENDIF
  !        
ENDIF
!
! * Surface energy budget
!
IF (dgi%LSURF_BUDGET.OR.dgei%LSURF_BUDGETC) THEN
   !
   CALL diag_surf_budget_isba(pdir_sw, psca_sw, pdir_alb, psca_alb,  &
                                plw, prn,                              &
                                pkdi%XP_SWD, pkdi%XP_SWU, pkdi%XP_SWBD, pkdi%XP_SWBU,      &
                                pkdi%XP_LWD, pkdi%XP_LWU   )          
   !
   pkdi%XP_FMU = psfzon
   pkdi%XP_FMV = psfmer
   !
END IF
!
IF (dgi%LCOEF) THEN
  !
  !* Transfer coefficient
  !
  pkdi%XP_CD = pcd
  pkdi%XP_CH = pch
  pkdi%XP_CE = pch
  !
  !* Roughness lengths
  !
  pkdi%XP_Z0_WITH_SNOW  = pz0
  pkdi%XP_Z0H_WITH_SNOW = pz0h
  pkdi%XP_Z0EFF         = pz0eff
  !
ENDIF
!
IF (dgi%LSURF_VARS) THEN
  !
  !* Humidity at surface
  !
  pkdi%XP_QS = pqs
  !
ENDIF
IF (lhook) CALL dr_hook('DIAG_INLINE_ISBA_N',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE diag_inline_isba_n