trip_prep.F90

Go to the documentation of this file.

!######
PROGRAM trip_prep
!###########
!
!!****  *TRIP_PREP* - driver for TRIP fields preparation
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     B. Decharme 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    06/2008
!!      S.Sénési    08/11/16 : interface to XIOS
!!------------------------------------------------------------------
!
USE modd_surfex_trip_n
USE modd_off_trip_n
!
USE modd_trip_listing
!
USE modi_init_trip_par
USE modi_prep_trip_run
!
USE modi_open_trip_namelist
USE modi_close_trip_namelist
USE modi_abort_trip
USE modi_trip_posnam
USE modi_read_nam_trip
USE modi_read_nam_trip_grid
USE modi_read_nam_trip_prep
!
USE modi_trip_oasis_end
!
USE modi_trip_oasis_init
USE modi_trip_oasis_read_nam
USE modi_trip_oasis_prep
USE modi_trip_oasis_end
!
#ifdef SFX_MPI
#ifdef SFX_MPL
USE mpl_data_module, ONLY : lmplusercomm, mplusercomm
#endif
#endif
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
#ifdef CPLOASIS
include 'mpif.h'
#endif
!
INTEGER  :: ILON
INTEGER  :: ILAT
!
INTEGER  :: NYEAR           ! current year  (UTC)
INTEGER  :: NMONTH          ! current month (UTC)
INTEGER  :: NDAY            ! current day   (UTC)
REAL     :: XTIME           ! current time    (s)
!
INTEGER  :: ILUNAM          ! namelist unit number
LOGICAL  :: GFOUND          ! return logical when reading namelist
INTEGER  :: ILOCAL_COMM     ! Local communicator
LOGICAL  :: GOASIS          ! OASIS used(default=.false.)
LOGICAL  :: GXIOS           ! XIOS used(default=.false.)
!
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
NAMELIST/nam_start_date/nyear,nmonth,nday,xtime
!
! --------------------------------------------------------------------------------------
! * 0. MPI and OASIS must be initialized before any DR_HOOK call
! --------------------------------------------------------------------------------------
!
 CALL trip_oasis_init(goasis,gxios,ilocal_comm,lprep=.true.)
#ifdef SFX_MPI
#ifdef SFX_MPL
IF (ilocal_comm/=0) THEN
  lmplusercomm = .true.
  mplusercomm = ilocal_comm
ENDIF
#endif
#endif
!
IF (lhook) CALL dr_hook('TRIP_PREP',0,zhook_handle)
!
!-------------------------------------------------------------------------------
 CALL trip_alloc_list(1)
 ytrip_cur => ytrip_list(1)
!-------------------------------------------------------------------------------
!
 clisting = clisting_prep
!
OPEN (unit=nlisting,file=clisting_prep,form='FORMATTED',action='WRITE')
!
! --------------------------------------------------------------------------------------
!* 1. Time configuration: start date of the run
! --------------------------------------------------------------------------------------
!
 CALL open_trip_namelist(ilunam)
 CALL trip_posnam(ilunam,'NAM_START_DATE',gfound,nlisting)
IF (gfound) THEN
   READ (unit=ilunam,nml=nam_start_date)
ELSE
  WRITE(nlisting,*)'NAM_START_DATE not found in namelist'
  WRITE(nlisting,*)'NYEAR, NMONTH, NDAY and XTIME must be initialized'
  WRITE(nlisting,*)'as the date of the beginning of the run'
  CALL abort_trip('NAM_START_DATE not found in namelist')        
ENDIF
 CALL close_trip_namelist(ilunam)
!
! --------------------------------------------------------------------------------------
!* 2. Initializations
! --------------------------------------------------------------------------------------
!
 CALL init_trip_par
!
! --------------------------------------------------------------------------------------
!* 3. Read grid and physical option namelists
! --------------------------------------------------------------------------------------
!
 CALL read_nam_trip(nlisting)
!
 CALL read_nam_trip_prep(nlisting)
!
 CALL read_nam_trip_grid(ytrip_cur%TPG, &
                        nlisting)
!
IF(goasis)THEN
  CALL trip_oasis_read_nam(nlisting)
ENDIF
!
! --------------------------------------------------------------------------------------
!* 4. TRIP parameters preparation
! --------------------------------------------------------------------------------------
!
 CALL prep_trip_run(ytrip_cur%TP, ytrip_cur%TPG, &
                   nyear,nmonth,nday,xtime,ilon,ilat)
!
IF(goasis)THEN
  CALL trip_oasis_prep(ytrip_cur%TPG, &
                       nlisting,ilon,ilat)
ENDIF
!
! --------------------------------------------------------------------------------------
!
WRITE(nlisting,*) ' '
WRITE(nlisting,*) '    ----------------------------'
WRITE(nlisting,*) '    | TRIP PREP ENDS CORRECTLY |'
WRITE(nlisting,*) '    ----------------------------'
!
WRITE(*,*) ' '
WRITE(*,*) '    ----------------------------'
WRITE(*,*) '    | TRIP PREP ENDS CORRECTLY |'
WRITE(*,*) '    ----------------------------'
!
 CLOSE(nlisting)
!
!-------------------------------------------------------------------------------
 CALL trip_deallo_list
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('TRIP_PREP',1,zhook_handle)
!
! --------------------------------------------------------------------------------------
! * 3. MPI and OASIS must be finalized after the last DR_HOOK call
! --------------------------------------------------------------------------------------
!
 CALL trip_oasis_end(goasis,gxios)
!
!-------------------------------------------------------------------------------------
!
END PROGRAM trip_prep