read_pgd_seafluxn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_pgd_seaflux_n (DTCO, DTS, SG, S, U, &
                                     hprogram)
!     #########################################
!
!!****  *READ_PGD_SEAFLUX_n* - routine to read SEAFLUX physiographic fields
!!
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_seaflux_n, ONLY : data_seaflux_t
USE modd_seaflux_grid_n, ONLY : seaflux_grid_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_type_date_surf
!
USE modd_data_cover_par, ONLY : jpcover
!
USE mode_read_surf_cov, ONLY : read_surf_cov
!
USE modi_read_surf
USE modi_read_grid
USE modi_read_lcover
USE modi_read_pgd_seaflux_par_n
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(data_seaflux_t), INTENT(INOUT) :: dts
TYPE(seaflux_grid_t), INTENT(INOUT) :: sg
TYPE(seaflux_t), INTENT(INOUT) :: s
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),  INTENT(IN)  :: hprogram ! calling program
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER           :: iresp          ! Error code after redding
!
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
!
INTEGER           :: iversion   ! surface version
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------
!
!* 1D physical dimension
!
IF (lhook) CALL dr_hook('READ_PGD_SEAFLUX_N',0,zhook_handle)
yrecfm='SIZE_SEA'
 CALL get_type_dim_n(dtco, u, &
                     'SEA   ',sg%NDIM)
!
!
!*       2.     Physiographic data fields:
!               -------------------------
!
!* cover classes
!
ALLOCATE(s%LCOVER(jpcover))
 CALL read_lcover(&
                  hprogram,s%LCOVER)
!
ALLOCATE(s%XCOVER(sg%NDIM,jpcover))
 CALL read_surf_cov(&
                    hprogram,'COVER',s%XCOVER(:,:),s%LCOVER,iresp)
!
!* orography
!
ALLOCATE(s%XZS(sg%NDIM))
s%XZS(:) = 0.
!
yrecfm='VERSION'
 CALL read_surf(&
                hprogram,yrecfm,iversion,iresp)
!
!* bathymetry
!
ALLOCATE(s%XSEABATHY(sg%NDIM))
IF (iversion<=3) THEN
  s%XSEABATHY(:) = -300.
ELSE
  yrecfm='BATHY'
  CALL read_surf(&
                hprogram,yrecfm,s%XSEABATHY(:),iresp)
END IF
!
!* latitude, longitude 
!
ALLOCATE(sg%XLAT      (sg%NDIM))
ALLOCATE(sg%XLON      (sg%NDIM))
ALLOCATE(sg%XMESH_SIZE(sg%NDIM))
 CALL read_grid(&
                hprogram,sg%CGRID,sg%XGRID_PAR,sg%XLAT,sg%XLON,sg%XMESH_SIZE,iresp)
!
!
!* sst
!
!
IF (iversion<3) THEN
  dts%LSST_DATA = .false.
ELSE
  yrecfm='SST_DATA'
  CALL read_surf(&
                hprogram,yrecfm,dts%LSST_DATA,iresp)
END IF
!
IF (dts%LSST_DATA) CALL read_pgd_seaflux_par_n(dtco, u, dts, sg, &
                                               hprogram,sg%NDIM)
IF (lhook) CALL dr_hook('READ_PGD_SEAFLUX_N',1,zhook_handle)
!
!------------------------------------------------------------------------------!
END SUBROUTINE read_pgd_seaflux_n