get_type_dimn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #####################################
      SUBROUTINE get_type_dim_n (DTCO, U, &
                                 htype,kdim)
!     #####################################
!
!!****  *GET_TYPE_DIM_n* - routine to get the number of point for any surface type
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    -------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson    *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modi_convert_cover_frac
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),  INTENT(IN)      :: htype    ! Type of surface
INTEGER,           INTENT(INOUT)   :: kdim     ! size of the mask
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(:),   ALLOCATABLE :: zsea   ! sea cover
REAL, DIMENSION(:),   ALLOCATABLE :: znature! nature cover
REAL, DIMENSION(:),   ALLOCATABLE :: ztown  ! town cover
REAL, DIMENSION(:),   ALLOCATABLE :: zwater ! water cover
REAL, DIMENSION(:),   ALLOCATABLE :: zland  ! land cover
REAL, DIMENSION(:),   ALLOCATABLE :: zfull  ! total cover
!
INTEGER           :: ilu    ! total horizontal size
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('GET_TYPE_DIM_N',0,zhook_handle)
IF (.NOT. ASSOCIATED(u%XCOVER) .AND. lhook) CALL dr_hook('GET_TYPE_DIM_N',1,zhook_handle)
IF (.NOT. ASSOCIATED(u%XCOVER)) RETURN
!
!*        1.    Fractions
!              ---------
!
ilu = SIZE(u%XCOVER,1)
!
ALLOCATE(zsea(ilu))
ALLOCATE(znature(ilu))
ALLOCATE(ztown(ilu))
ALLOCATE(zwater(ilu))
ALLOCATE(zland(ilu))
IF (.NOT. ASSOCIATED(u%XSEA)) THEN
  CALL convert_cover_frac(dtco, &
                          u%XCOVER,u%LCOVER,zsea,znature,ztown,zwater)
ELSE
  zsea    = u%XSEA
  znature = u%XNATURE
  zwater  = u%XWATER
  ztown   = u%XTOWN
END IF
zland = ztown + znature
!
ALLOCATE(zfull(ilu))
zfull=1.
!
SELECT CASE (htype)
  CASE ('FULL  ')
   kdim = ilu
   !
  CASE ('EXTZON')
   kdim = ilu
   !
  CASE ('NATURE')
   kdim = count(znature(:) > 0.)
   !
  CASE ('SEA   ')
   kdim = count(zsea(:) > 0.)
   !
  CASE ('TOWN  ')
   kdim = count(ztown(:) > 0.)
   !
  CASE ('WATER ')
   kdim = count(zwater(:) > 0.)
   !
  CASE ('LAND  ')
   kdim = count(zland(:) > 0.)
   !
END SELECT
!-------------------------------------------------------------------------------
DEALLOCATE(zsea   )
DEALLOCATE(znature)
DEALLOCATE(ztown  )
DEALLOCATE(zwater )
DEALLOCATE(zfull  )
DEALLOCATE(zland  )
IF (lhook) CALL dr_hook('GET_TYPE_DIM_N',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_type_dim_n