read_grid.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_grid (&
                            hprogram,hgrid,pgrid_par,plat,plon,pmesh_size,kresp,pdir)
!     #########################################
!
!!****  *READ_GRID* - routine to initialise the horizontal grid of a scheme
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2003 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modi_get_luout
USE modi_read_surf
USE modi_latlon_grid
USE modi_read_gridtype
!
USE modd_assim, ONLY : lread_all, lassim
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram   ! calling program
 CHARACTER(LEN=10),  INTENT(OUT) :: hgrid      ! type of horizontal grid
REAL, DIMENSION(:), POINTER     :: pgrid_par  ! parameters defining this grid
REAL, DIMENSION(:), INTENT(OUT) :: plat       ! latitude  (degrees)
REAL, DIMENSION(:), INTENT(OUT) :: plon       ! longitude (degrees)
REAL, DIMENSION(:), INTENT(OUT) :: pmesh_size ! horizontal mesh size (m2)
INTEGER,            INTENT(OUT) :: kresp      ! error return code
REAL, DIMENSION(:), INTENT(OUT), OPTIONAL :: pdir ! heading of main axis of grid compared to North (degrees)
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
LOGICAL :: gread_all
INTEGER :: igrid_par
INTEGER :: iluout
REAL(KIND=JPRB) :: zhook_handle
!---------------------------------------------------------------------------
!
!*       1.    Reading of type of grid
!              -----------------------
!
IF (lhook) CALL dr_hook('READ_GRID',0,zhook_handle)
!
IF (lassim) THEN
  gread_all = lread_all
  lread_all = .true.
ENDIF
!
 CALL read_surf(&
                hprogram,'GRID_TYPE',hgrid,kresp)
!
!---------------------------------------------------------------------------
!
!*       2.    Reading parameters of the grid
!              ------------------------------
!
 CALL read_gridtype(&
                    hprogram,hgrid,igrid_par,SIZE(plat),.false.)
!
ALLOCATE(pgrid_par(igrid_par))
 CALL read_gridtype(&
                    hprogram,hgrid,igrid_par,SIZE(plat),.true.,pgrid_par,kresp)
!
!---------------------------------------------------------------------------
!
!*       3.    Latitude, longitude, mesh size
!              ------------------------------
!
 CALL get_luout(hprogram,iluout)
!
SELECT CASE (hgrid)
  CASE("NONE      ")
    IF (present(pdir)) pdir(:) = 0.
    !
    CALL read_surf(&
                hprogram,'LON',      plon,kresp)
    IF (kresp/=0 .AND. lhook) CALL dr_hook('READ_GRID',1,zhook_handle)
    IF (kresp/=0) RETURN
    CALL read_surf(&
                hprogram,'LAT',      plat,kresp)
    IF (kresp/=0 .AND. lhook) CALL dr_hook('READ_GRID',1,zhook_handle)
    IF (kresp/=0) RETURN
    CALL read_surf(&
                hprogram,'MESH_SIZE',pmesh_size,kresp)
    IF (kresp/=0 .AND. lhook) CALL dr_hook('READ_GRID',1,zhook_handle)
    IF (kresp/=0) RETURN

  CASE default
    IF (present(pdir)) THEN
      CALL latlon_grid(hgrid,SIZE(pgrid_par),SIZE(plat),iluout,pgrid_par,plat,plon,pmesh_size,pdir)
    ELSE
      CALL latlon_grid(hgrid,SIZE(pgrid_par),SIZE(plat),iluout,pgrid_par,plat,plon,pmesh_size)
    END IF

END SELECT
!
IF (lassim) lread_all = gread_all
!
IF (lhook) CALL dr_hook('READ_GRID',1,zhook_handle)
!
!---------------------------------------------------------------------------
!
END SUBROUTINE read_grid