mode_read_surf_cov.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.

MODULE mode_read_surf_cov

!RJ: split cover from read_surf.F90 to avoid compiler bugs
!RJ: all safety compatibility checks should be done here
PUBLIC :: read_surf_cov

 CONTAINS

!     #############################################################
      SUBROUTINE read_surf_cov (&
                                hprogram,hrec,pfield,oflag,kresp,hcomment,hdir)
!     #############################################################
!
!
!
!
USE modd_surf_par,  ONLY : xundef
!
USE modi_read_surf
#ifdef SFX_MNH
USE modi_read_surfx2cov_mnh
#endif
!
USE yomhook ,ONLY : lhook, dr_hook
USE parkind1 ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1   Declarations of arguments
!
!
!
 CHARACTER(LEN=6), INTENT(IN) :: hprogram    ! calling program
 CHARACTER(LEN=*), INTENT(IN) :: hrec        ! name of the article to be read
REAL, DIMENSION(:,:), INTENT(OUT) :: pfield ! array containing the data field
LOGICAL,DIMENSION(:), INTENT(IN) :: oflag   ! mask for array filling
INTEGER, INTENT(OUT) :: kresp               ! KRESP  : return-code if a problem appears
 CHARACTER(LEN=*), OPTIONAL, INTENT(OUT) :: hcomment ! name of the article to be read
 CHARACTER(LEN=1), OPTIONAL, INTENT(IN)  :: hdir     ! type of field :
!                                                   ! 'H' : field with
!                                                   !       horizontal spatial dim.
!                                                   ! '-' : no horizontal dim.
!*      0.2   Declarations of local variables
!
 CHARACTER(LEN=100) :: ycomment
 CHARACTER(LEN=16)  :: yrec
 CHARACTER(LEN=1)   :: ydir
INTEGER            :: jj
INTEGER            :: jcover
INTEGER            :: il1, il2
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('READ_SURF_COV',0,zhook_handle)
!
yrec = hrec
ycomment="empty"
ydir = 'H'
IF (present(hdir)) ydir = hdir
!
il1 = SIZE(pfield,1)
il2 = SIZE(pfield,2)
!
pfield(:,:)=xundef
!
IF (hprogram=='MESONH') THEN
#ifdef SFX_MNH
    CALL read_surfx2cov_mnh(yrec,il1,il2,pfield,oflag,kresp,ycomment,ydir)
#endif
ELSE
  !
  jcover = 0
  DO jj=1,SIZE(oflag)
    !
    IF (.NOT. oflag(jj)) cycle
    !
    jcover = jcover + 1
    !
    WRITE(yrec,'(A5,I3.3)') 'COVER',jj
    ycomment='X_Y_'//yrec
!RJ: xundef is done for whole array above, to ensure status INTENT(OUT)
!RJ     PFIELD(:,JCOVER)=0.
    !
    CALL read_surf(hprogram,yrec,pfield(:,jcover),kresp,ycomment,ydir)
    !
  END DO
  !
ENDIF
!
!RJ: what is a point of comment here? last field comment? Should be 'COVER_PACKED' status?
IF (present(hcomment)) hcomment = ycomment
!
IF (lhook) CALL dr_hook('READ_SURF_COV',1,zhook_handle)
!
END SUBROUTINE read_surf_cov

END MODULE mode_read_surf_cov