prep_teb.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_teb (DTCO, UG, U, USS, IG, I, TM, GDM, GRM, &
                     hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!     #################################################################################
!
!!****  *PREP_TEB* - prepares TEB fields
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      S. Riette   06/2009 PREP_TEB_CANOPY has no more argument
!!------------------------------------------------------------------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_isba_grid_n, ONLY : isba_grid_t
USE modd_isba_n, ONLY : isba_t
USE modd_surfex_n, ONLY : teb_model_t
USE modd_surfex_n, ONLY : teb_garden_model_t
USE modd_surfex_n, ONLY : teb_greenroof_model_t
!
USE modi_prep_hor_teb_field
USE modi_prep_ver_teb
USE modi_prep_output_grid
USE modi_get_luout
USE modi_prep_teb_canopy
USE modi_prep_teb_garden
USE modi_prep_teb_greenroof
USE modi_goto_wrapper_teb_patch
!
USE modn_prep_teb
!
USE modd_read_namelist, ONLY : lnam_read
!
USE modd_prep,       ONLY : xzs_ls
!
USE modd_prep_teb_garden, ONLY : xwsnow_gd, xrsnow_gd, xtsnow_gd, xlwcsnow_gd, &
                                 xagesnow_gd
!
USE modd_prep_teb_greenroof, ONLY : xwsnow_gr, xrsnow_gr, xtsnow_gr, xlwcsnow_gr, &
                                    xagesnow_gr
!
USE modd_surf_atm,   ONLY : lvertshift
!
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_clean_prep_output_grid
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(isba_grid_t), INTENT(INOUT) :: ig
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(teb_model_t), INTENT(INOUT) :: tm
TYPE(teb_garden_model_t), INTENT(INOUT) :: gdm
TYPE(teb_greenroof_model_t), INTENT(INOUT) :: grm
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
!
!*      0.2    declarations of local variables
!
INTEGER :: iluout
INTEGER :: jpatch         ! TEB patch number
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!*      1.     Default of configuration
!
!
IF (lhook) CALL dr_hook('PREP_TEB',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL prep_output_grid(ug, u, &
                       iluout,tm%TG%CGRID,tm%TG%XGRID_PAR,tm%TG%XLAT,tm%TG%XLON)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations
!
!
!*      2.0    Large scale orography
!
 CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'ZS     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,1)
!
!* option for roads
!
tm%TOP%CROAD_DIR = croad_dir
tm%TOP%CWALL_OPT = cwall_opt
!
DO jpatch=1,tm%TOP%NTEB_PATCH
  !
  CALL goto_wrapper_teb_patch(tm%B, tm%DGCT, tm%DGMT, tm%T, &
                              gdm%TGD, gdm%TGDPE, grm%TGR, grm%TGRPE, jpatch)
  !*      2.1    Water reservoirs
  !
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'WS_ROOF',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'WS_ROAD',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  !
  !*      2.2    Building temperature
  !
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'TI_BLD ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  !
  !*      2.3    Road deep temperature
  !
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'TI_ROAD',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  !
  !*      2.4    Temperature profiles
  !
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_ROAD ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_WALLA',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_WALLB',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_ROOF ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  !
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_WIN1 ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  IF (tm%TOP%CBEM == 'BEM') THEN
    CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'QI_BLD ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
    CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_WIN2 ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
    CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_FLOOR',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
    CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_MASS ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  ENDIF  
  !*      2.5    Snow variables
  !
  tm%T%CUR%TSNOW_ROOF%SCHEME='1-L'
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'SN_ROOF',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  tm%T%CUR%TSNOW_ROAD%SCHEME='1-L'
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'SN_ROAD',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  !
  !*      2.6    Canyon air variables
  !
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'T_CAN  ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  CALL prep_hor_teb_field(tm%B, tm%BOP, dtco, ig, u, tm%TG, tm%T, tm%TOP, &
                         hprogram,'Q_CAN  ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  !
  !-------------------------------------------------------------------------------------
  !
  !*      3.     Vertical interpolations of all variables
  !
  IF(lvertshift)THEN
    CALL prep_ver_teb(tm%B, tm%T, tm%TOP)
  ENDIF
  !
  !-------------------------------------------------------------------------------------
  !
  !*      4.     Urban green areas
  !
  
  IF (tm%TOP%LGARDEN)    CALL prep_teb_garden(dtco, ug, u, uss, ig, i, &
                                              tm%TG, tm%TOP, gdm,  &
                                              hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  IF (tm%TOP%LGREENROOF) CALL prep_teb_greenroof(dtco, ug, u, uss, ig, i, &
                                                 tm%TG, tm%T, tm%TOP, gdm%TVG, grm, &
                                              hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype, jpatch)
  !  
ENDDO
!
DEALLOCATE(xwsnow_gd,xrsnow_gd,xtsnow_gd,xlwcsnow_gd,xagesnow_gd)
DEALLOCATE(xwsnow_gr,xrsnow_gr,xtsnow_gr,xlwcsnow_gr,xagesnow_gr)
!
!-------------------------------------------------------------------------------------
!
!*      5.     Preparation of canopy air variables
!
tm%TOP%LCANOPY = lteb_canopy
IF (tm%TOP%LCANOPY) CALL prep_teb_canopy(tm%TCP, tm%TG)
!
DEALLOCATE(xzs_ls)
!
!-------------------------------------------------------------------------------------
 CALL clean_prep_output_grid
IF (lhook) CALL dr_hook('PREP_TEB',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_teb