prep_hor_teb_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_hor_teb_field (B, BOP, DTCO, IG, U, TG, T, TOP, &
                               hprogram,hsurf,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!     #################################################################################
!
!
!!****  *PREP_HOR_TEB_FIELD* - reads, interpolates and prepares a TEB field
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      P. Le Moigne 10/2005, Phasage Arome
!!------------------------------------------------------------------
!
!
!
!
!
USE modd_bem_n, ONLY : bem_t
USE modd_bem_option_n, ONLY : bem_options_t
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_isba_grid_n, ONLY : isba_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_teb_grid_n, ONLY : teb_grid_t
USE modd_teb_n, ONLY : teb_t
USE modd_teb_option_n, ONLY : teb_options_t
!
USE modd_prep,     ONLY : cingrid_type, cinterp_type, xzs_ls, xlat_out, xlon_out, &
                          xx_out, xy_out, cmask
USE modd_prep_teb, ONLY : xgrid_roof, xgrid_road, xgrid_wall, xgrid_floor, lsnow_ideal_teb, &
                          xwsnow_roof, xrsnow_roof, xtsnow_roof, xlwcsnow_roof, xasnow_roof, &
                          xwsnow_road, xrsnow_road, xtsnow_road, xlwcsnow_road, xasnow_road, &
                          xhui_bld, xhui_bld_def
!
USE modd_csts, ONLY: xg, xp00
USE modd_surf_par, ONLY: xundef
!
USE mode_thermos
!
USE modi_read_prep_teb_conf
USE modi_read_prep_teb_snow
USE modi_prep_teb_grib
USE modi_prep_teb_unif
USE modi_prep_teb_buffer
USE modi_hor_interpol
USE modi_prep_hor_snow_fields
USE modi_get_luout
USE modi_prep_teb_extern
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(bem_t), INTENT(INOUT) :: b
TYPE(bem_options_t), INTENT(INOUT) :: bop
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(isba_grid_t), INTENT(INOUT) :: ig
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(teb_grid_t), INTENT(INOUT) :: tg
TYPE(teb_t), INTENT(INOUT) :: t
TYPE(teb_options_t), INTENT(INOUT) :: top
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
!
INTEGER,            INTENT(IN)  :: kpatch
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=6)              :: yfiletype ! type of input file
 CHARACTER(LEN=28)             :: yfile     ! name of file
 CHARACTER(LEN=6)              :: yfilepgdtype ! type of input file
 CHARACTER(LEN=28)             :: yfilepgd     ! name of file
REAL, DIMENSION(:), ALLOCATABLE :: zsg1snow, zsg2snow, zhistsnow, zagesnow
REAL, POINTER, DIMENSION(:,:) :: zfieldin  ! field to interpolate horizontally
REAL, ALLOCATABLE, DIMENSION(:,:) :: zfieldout ! field interpolated   horizontally
REAL, ALLOCATABLE, DIMENSION(:) :: zps !surface pressure
REAL, PARAMETER               :: zrhoa=1.19 ! volumic mass of air at 20C and 1000hPa
INTEGER                       :: iluout    ! output listing logical unit
!
LOGICAL                       :: gunif     ! flag for prescribed uniform field
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!
!*      1.     Reading of input file name and type
!
IF (lhook) CALL dr_hook('PREP_HOR_TEB_FIELD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL read_prep_teb_conf(hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,&
                        hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,iluout,gunif)
!
 cmask = 'TOWN'
!
!-------------------------------------------------------------------------------------
!
!*      2.     Snow variables case?
!
IF (hsurf=='SN_ROOF') THEN
  CALL read_prep_teb_snow(hprogram,t%CUR%TSNOW_ROOF%SCHEME,t%CUR%TSNOW_ROOF%NLAYER,&
                                   t%CUR%TSNOW_ROAD%SCHEME,t%CUR%TSNOW_ROAD%NLAYER,&
                                   yfile,yfiletype,yfilepgd,yfilepgdtype)
  IF (len_trim(yfile)>0 .AND. len_trim(yfiletype)>0) gunif = .false.                                   
  ALLOCATE(zsg1snow(SIZE(xwsnow_roof)))
  ALLOCATE(zsg2snow(SIZE(xwsnow_roof)))
  ALLOCATE(zhistsnow(SIZE(xwsnow_roof)))
  ALLOCATE(zagesnow(SIZE(xwsnow_roof)))                                 
  CALL prep_hor_snow_fields(dtco, &
                            ig, u, &
                            hprogram,hsurf,              &
                            yfile,yfiletype,             &
                            yfilepgd, yfilepgdtype,      &
                            iluout,gunif,1,kpatch,       &
                            SIZE(tg%XLAT),t%CUR%TSNOW_ROOF, top%TTIME,&
                            xwsnow_roof, xrsnow_roof,    &
                            xtsnow_roof, xlwcsnow_roof,  &
                            xasnow_roof,                 &
                            lsnow_ideal_teb, zsg1snow,   &
                            zsg2snow, zhistsnow, zagesnow)
  DEALLOCATE(zsg1snow)
  DEALLOCATE(zsg2snow)
  DEALLOCATE(zhistsnow)
  DEALLOCATE(zagesnow)                            
  IF (lhook) CALL dr_hook('PREP_HOR_TEB_FIELD',1,zhook_handle)
  RETURN
ELSE IF (hsurf=='SN_ROAD') THEN
  CALL read_prep_teb_snow(hprogram,t%CUR%TSNOW_ROOF%SCHEME,t%CUR%TSNOW_ROOF%NLAYER,&
                                   t%CUR%TSNOW_ROAD%SCHEME,t%CUR%TSNOW_ROAD%NLAYER,&
                                   yfile,yfiletype,yfilepgd,yfilepgdtype)
  IF (len_trim(yfile)>0 .AND. len_trim(yfiletype)>0) gunif = .false.                                   
  ALLOCATE(zsg1snow(SIZE(xwsnow_road)))
  ALLOCATE(zsg2snow(SIZE(xwsnow_road)))
  ALLOCATE(zhistsnow(SIZE(xwsnow_road)))
  ALLOCATE(zagesnow(SIZE(xwsnow_road)))                                   
  CALL prep_hor_snow_fields(dtco, &
                            ig, u, &
                            hprogram,hsurf,              &
                            yfile,yfiletype,             &
                            yfilepgd, yfilepgdtype,      &                            
                            iluout,gunif,1,kpatch,       &
                            SIZE(tg%XLAT),t%CUR%TSNOW_ROAD, top%TTIME,&
                            xwsnow_road, xrsnow_road,    &
                            xtsnow_road, xlwcsnow_road,  &
                            xasnow_road,                 &
                            lsnow_ideal_teb, zsg1snow,   &
                            zsg2snow, zhistsnow, zagesnow)
  DEALLOCATE(zsg1snow)
  DEALLOCATE(zsg2snow)
  DEALLOCATE(zhistsnow)
  DEALLOCATE(zagesnow)                               
  IF (lhook) CALL dr_hook('PREP_HOR_TEB_FIELD',1,zhook_handle)
  RETURN
END IF
!
!
!*      4.     Reading of input  configuration (Grid and interpolation type)
!
IF (gunif) THEN
  CALL prep_teb_unif(iluout,hsurf,zfieldin)
ELSE IF (yfiletype=='GRIB  ') THEN
  CALL prep_teb_grib(hprogram,hsurf,yfile,iluout,zfieldin)
 ELSE IF (yfiletype=='MESONH' .OR. yfiletype=='ASCII ' .OR. yfiletype=='LFI   '.OR. yfiletype=='FA    ') THEN
  CALL prep_teb_extern(dtco, &
                       hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,iluout,kpatch,zfieldin)
 ELSE IF (yfiletype=='BUFFER') THEN
  CALL prep_teb_buffer(hprogram,hsurf,iluout,zfieldin)
 ELSE
  CALL abor1_sfx('PREP_HOR_TEB_FIELD: data file type not supported : '//yfiletype)
END IF
!
!*      5.     Horizontal interpolation
!
ALLOCATE(zfieldout(SIZE(tg%XLAT),SIZE(zfieldin,2)))
!
 CALL hor_interpol(dtco, u, &
                   iluout,zfieldin,zfieldout)
!
!*      6.     Return to historical variable
!
SELECT CASE (hsurf)
 CASE('ZS     ') 
  ALLOCATE(xzs_ls(SIZE(zfieldout,1)))
  xzs_ls(:) = zfieldout(:,1)
 CASE('WS_ROOF') 
  ALLOCATE(t%CUR%XWS_ROOF(SIZE(zfieldout,1)))
  t%CUR%XWS_ROOF(:) = zfieldout(:,1)
 CASE('WS_ROAD')
  ALLOCATE(t%CUR%XWS_ROAD(SIZE(zfieldout,1)))
  t%CUR%XWS_ROAD(:) = zfieldout(:,1)
 CASE('TI_ROAD') 
  ALLOCATE(t%CUR%XTI_ROAD(SIZE(zfieldout,1)))
  t%CUR%XTI_ROAD(:) = zfieldout(:,1)
 CASE('TI_BLD ') 
  ALLOCATE(b%CUR%XTI_BLD (SIZE(zfieldout,1)))
  b%CUR%XTI_BLD (:) = zfieldout(:,1)
 CASE('QI_BLD ') 
  ALLOCATE(b%CUR%XQI_BLD (SIZE(zfieldout,1)))
  IF (all(zfieldout .GE. xundef-1.e+5 .AND. zfieldout .LE. xundef+1.e+5)) THEN
     ALLOCATE(zps(SIZE(zfieldout,1)))
     zps = xp00 - zrhoa * xg * xzs_ls
     IF (xhui_bld==xundef) THEN
        zfieldout(:,1) = xhui_bld_def * qsat(b%CUR%XTI_BLD, zps)
     ELSE
        zfieldout(:,1) = xhui_bld * qsat(b%CUR%XTI_BLD, zps)
     ENDIF
     DEALLOCATE(zps)
  ENDIF
  b%CUR%XQI_BLD (:) = zfieldout(:,1)
 CASE('T_WIN1 ') 
  ALLOCATE(b%CUR%XT_WIN1 (SIZE(zfieldout,1)))
  b%CUR%XT_WIN1 (:) = zfieldout(:,1)
 CASE('T_WIN2 ') 
  ALLOCATE(b%CUR%XT_WIN2 (SIZE(zfieldout,1)))
  b%CUR%XT_WIN2 (:) = zfieldout(:,1)
 CASE('T_FLOOR')
  ALLOCATE(b%CUR%XT_FLOOR(SIZE(zfieldout,1),bop%NFLOOR_LAYER))
  CALL init_from_ref_grid(xgrid_floor,zfieldout,b%CUR%XD_FLOOR,b%CUR%XT_FLOOR)
 CASE('T_MASS')
  ALLOCATE(b%CUR%XT_MASS(SIZE(zfieldout,1),bop%NFLOOR_LAYER))
  CALL init_from_ref_grid(xgrid_floor,zfieldout,b%CUR%XD_FLOOR,b%CUR%XT_MASS)    
 CASE('T_ROAD ') 
  ALLOCATE(t%CUR%XT_ROAD(SIZE(zfieldout,1),top%NROAD_LAYER))
  CALL init_from_ref_grid(xgrid_road,zfieldout,t%CUR%XD_ROAD,t%CUR%XT_ROAD)
 CASE('T_WALLA')
  ALLOCATE(t%CUR%XT_WALL_A(SIZE(zfieldout,1),top%NWALL_LAYER))
  CALL init_from_ref_grid(xgrid_wall,zfieldout,t%CUR%XD_WALL,t%CUR%XT_WALL_A)
 CASE('T_WALLB')
  ALLOCATE(t%CUR%XT_WALL_B(SIZE(zfieldout,1),top%NWALL_LAYER))
  IF (top%CWALL_OPT=='UNIF') THEN
    t%CUR%XT_WALL_B = t%CUR%XT_WALL_A
  ELSE
    CALL init_from_ref_grid(xgrid_wall,zfieldout,t%CUR%XD_WALL,t%CUR%XT_WALL_B)
  END IF  
 CASE('T_ROOF ') 
  ALLOCATE(t%CUR%XT_ROOF(SIZE(zfieldout,1),top%NROOF_LAYER))
  CALL init_from_ref_grid(xgrid_roof,zfieldout,t%CUR%XD_ROOF,t%CUR%XT_ROOF)
 CASE('T_CAN  ') 
  ALLOCATE(t%CUR%XT_CANYON(SIZE(zfieldout,1)))
  t%CUR%XT_CANYON (:) = zfieldout(:,1)
 CASE('Q_CAN  ') 
  ALLOCATE(t%CUR%XQ_CANYON(SIZE(zfieldout,1)))
  t%CUR%XQ_CANYON (:) = zfieldout(:,1)
END SELECT
!
!-------------------------------------------------------------------------------------
!
!*      7.     Deallocations
!
DEALLOCATE(zfieldin )
DEALLOCATE(zfieldout)
IF (lhook) CALL dr_hook('PREP_HOR_TEB_FIELD',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!-------------------------------------------------------------------------------------
!
 CONTAINS
!
!-------------------------------------------------------------------------------------
!-------------------------------------------------------------------------------------
SUBROUTINE init_from_ref_grid(PGRID1,PT1,PD2,PT2)
!
USE modi_interp_grid
!
REAL, DIMENSION(:,:), INTENT(IN)  :: pt1    ! temperature profile
REAL, DIMENSION(:),   INTENT(IN)  :: pgrid1 ! normalized grid
REAL, DIMENSION(:,:), INTENT(IN)  :: pd2    ! output layer thickness
REAL, DIMENSION(:,:), INTENT(OUT) :: pt2    ! temperature profile
!
INTEGER                                  :: jl  ! loop counter
REAL, DIMENSION(SIZE(PT1,1),SIZE(PT1,2)) :: zd1 ! input grid
REAL, DIMENSION(SIZE(PD2,1),SIZE(PD2,2)) :: zd2 ! output grid
REAL, DIMENSION(SIZE(PD2,1))             :: zd  ! output total thickness
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('INIT_FROM_REF_GRID',0,zhook_handle)
zd2(:,:) = 0.
zd(:)   = 0.
!
DO jl=1,SIZE(zd2,2)
  zd2(:,jl) = zd(:) + pd2(:,jl)/2.
  zd(:)    = zd(:) + pd2(:,jl)
END DO
!
DO jl=1,SIZE(pt1,2)
  zd1(:,jl) = pgrid1(jl) * zd(:)
END DO
!
 CALL interp_grid(zd1,pt1,zd2,pt2)
IF (lhook) CALL dr_hook('INIT_FROM_REF_GRID',1,zhook_handle)
!
END SUBROUTINE init_from_ref_grid
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_hor_teb_field