interp_grid.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!######################
MODULE modi_interp_grid
!######################

INTERFACE interp_grid

SUBROUTINE interp_grid_1d(PZ1,PT1,PZ2,PT2)
!
REAL, DIMENSION(:,:), INTENT(IN)  :: pz1  ! input vertical grid
REAL, DIMENSION(:,:), INTENT(IN)  :: pt1  ! input temperatures
REAL, DIMENSION(:),   INTENT(IN)  :: pz2  ! output vertical grid
REAL, DIMENSION(:,:), INTENT(OUT)  :: pt2  ! output temperatures
!
END SUBROUTINE interp_grid_1d
!
SUBROUTINE interp_grid_2d(PZ1,PT1,PZ2,PT2)
!
REAL, DIMENSION(:,:), INTENT(IN) :: pz1  ! input vertical grid
REAL, DIMENSION(:,:), INTENT(IN) :: pt1  ! input temperatures
REAL, DIMENSION(:,:), INTENT(IN) :: pz2  ! output vertical grid
REAL, DIMENSION(:,:), INTENT(OUT) :: pt2  ! output temperatures
!
END SUBROUTINE interp_grid_2d
!
END INTERFACE

END MODULE modi_interp_grid

!     ##########################################
      SUBROUTINE interp_grid_1d(PZ1,PT1,PZ2,PT2)
!     ##########################################
!!
!!****  *INTERP_GRID* - interpolation on the vertical
!!
!!    PURPOSE
!!    -------
!!
!! input  grid/data is (x,z1)
!! output grid/data is (x,z2)
!!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!------------------------------------------------------------------
!
USE modd_surf_par,   ONLY : xundef
USE modi_coef_ver_interp_lin_surf
USE modi_ver_interp_lin_surf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!* 0.1 Declaration of dummy arguments
!
REAL, DIMENSION(:,:), INTENT(IN)   :: pz1  ! input vertical grid
REAL, DIMENSION(:,:), INTENT(IN)   :: pt1  ! input temperatures
REAL, DIMENSION(:),   INTENT(IN)   :: pz2  ! output vertical grid
REAL, DIMENSION(:,:), INTENT(OUT)  :: pt2  ! output temperatures
!
!* 0.2 Declaration of local variables
!
INTEGER :: jl, ji ! loop counter
REAL,    DIMENSION(SIZE(PZ1,1),SIZE(PZ2)) :: zz2      ! output grid
REAL,    DIMENSION(SIZE(PZ1,1),SIZE(PZ2)) :: zcoeflin ! interpolation coefficients
INTEGER, DIMENSION(SIZE(PZ1,1),SIZE(PZ2)) :: iklin    ! lower interpolating level of
!                                                     ! grid 1 for each level of grid 2 
REAL(KIND=JPRB) :: zhook_handle
!-----------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MODI_INTERP_GRID:INTERP_GRID_1D',0,zhook_handle)
DO jl=1,SIZE(pz2)
  zz2(:,jl) = pz2(jl)
END DO
!
 CALL coef_ver_interp_lin_surf(pz1,zz2,kklin=iklin,pcoeflin=zcoeflin)
!
!
pt2= ver_interp_lin_surf(pt1,iklin,zcoeflin)
!
!  On reporte le mask sur tous les niveaux
!
DO jl=1,SIZE(pt1,2)
  DO ji=1,SIZE(pt1,1)
    IF (pt1(ji,jl)==xundef) THEN
      pt2(ji,:)=xundef
    ENDIF
  END DO
END DO
IF (lhook) CALL dr_hook('MODI_INTERP_GRID:INTERP_GRID_1D',1,zhook_handle)
!-----------------------------------------------------------------------------
END SUBROUTINE interp_grid_1d
!
!     ##########################################
      SUBROUTINE interp_grid_2d(PZ1,PT1,PZ2,PT2)
!     ##########################################
!
USE modd_surf_par,   ONLY : xundef
USE modi_coef_ver_interp_lin_surf
USE modi_ver_interp_lin_surf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!* 0.1 Declaration of dummy arguments
!
REAL, DIMENSION(:,:), INTENT(IN)  :: pz1  ! input vertical grid
REAL, DIMENSION(:,:), INTENT(IN)  :: pt1  ! input temperatures
REAL, DIMENSION(:,:), INTENT(IN)  :: pz2  ! output vertical grid
REAL, DIMENSION(:,:), INTENT(OUT) :: pt2  ! output temperatures
!
!* 0.2 Declaration of local variables
!
INTEGER :: jl, ji ! loop counter
REAL,    DIMENSION(SIZE(PZ1,1),SIZE(PZ2,2)) :: zcoeflin ! interpolation coefficients
INTEGER, DIMENSION(SIZE(PZ1,1),SIZE(PZ2,2)) :: iklin    ! lower interpolating level of
                                                        ! grid 1 for each level of grid 2
REAL(KIND=JPRB) :: zhook_handle
!-----------------------------------------------------------------------------
IF (lhook) CALL dr_hook('MODI_INTERP_GRID:INTERP_GRID_2D',0,zhook_handle)
 CALL coef_ver_interp_lin_surf(pz1,pz2,iklin,zcoeflin)
!
pt2= ver_interp_lin_surf(pt1,iklin,zcoeflin)
!
!  On reporte le mask sur tous les niveaux
!
DO jl=1,SIZE(pt1,2)
  DO ji=1,SIZE(pt1,1)
    IF (pt1(ji,jl)==xundef) THEN
      pt2(ji,:)=xundef
    ENDIF
  END DO
END DO
IF (lhook) CALL dr_hook('MODI_INTERP_GRID:INTERP_GRID_2D',1,zhook_handle)
!-----------------------------------------------------------------------------
END SUBROUTINE interp_grid_2d