coef_ver_interp_lin_surf.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE coef_ver_interp_lin_surf(PZ1,PZ2,KKLIN,PCOEFLIN)
!     ###############################################################
!
!!****  *VER_INTERP_LIN* - vertical linear interpolation
!!
!!    PURPOSE
!!    -------
!     This function computes the interpolation coefficient XCOEFLIN
!     of the level XKLIN of grid PZ1 which is just under the points of
!     grid PZ2 (respectively called hereafter 'initial' and 'target'), 
!     in order to perform linear interpolations between these 2 grids.
!
!     CAUTION:
!     * The interpolation occurs on the WHOLE grid. Therefore, one must
!     only give as argument to this function the inner points of the domain,
!     particularly for the vertical grid, where there is no physical information
!     under the ground or at and over H.
!     * The level numbers must increase from bottom to top.
!!
!!**  METHOD
!!    ------
!!    two extrapolations are possible: with the two or four nearest points.
!!
!!   Interpolation with 2 points:
!!
!!    If there is less than two points on one side, the interpolation is linear.
!!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      
!     V.Masson  Meteo-France
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    18/07/97
!!                  20/01/98  use explicit arguments
!!      P Jabouille 20/12/02  no extrapolation under the ground
!!      S. Malardel 11/2003   bug of no extrapolation under the ground
!!      V. Masson   10/2003   no extrapolation above top
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declaration of arguments
!              ------------------------
REAL,   DIMENSION(:,:), INTENT(IN)   :: pz1   ! altitudes of the points of the
!                                             ! initial grid 
REAL,   DIMENSION(:,:), INTENT(IN)   :: pz2   ! altitudes of the points of the
!                                             ! target grid 
INTEGER, DIMENSION(:,:), INTENT(OUT) :: kklin ! number of the level
                                              ! of the data to be interpolated
!
REAL,    DIMENSION(:,:), INTENT(OUT):: pcoeflin ! interpolation
                                              ! coefficient
!
!
!*       0.2   Declaration of local variables
!              ------------------------------
!
LOGICAL,DIMENSION(SIZE(PZ1,1),SIZE(PZ1,2))            :: glevel
INTEGER                                               :: jk2,ji
INTEGER,DIMENSION(SIZE(PZ1,1))                        :: ilevel
INTEGER,DIMENSION(SIZE(PZ1,1))                        :: iunder
REAL                                                  :: zeps ! a small number
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('COEF_VER_INTERP_LIN_SURF',0,zhook_handle)
zeps=1.e-12
!
!-------------------------------------------------------------------------------
!
!*       2.    LOOP ON THE TARGET VERTICAL GRID
!              --------------------------------
!
DO jk2=1,SIZE(pz2,2)
!
!-------------------------------------------------------------------------------
!
!*       3.    Determination of the initial level under the target level JK2
!              -------------------------------------------------------------
!
  glevel(:,:)=pz1(:,:)<=spread(pz2(:,jk2),2,SIZE(pz1,2)) *(1.-zeps)
  ilevel(:)  =count(glevel(:,:),2)
!
!* linear extrapolation under the ground
  iunder=ilevel
  ilevel(:)=max(ilevel(:),1)
!
!* linear extrapolation above the uppest level
  ilevel(:)=min(ilevel(:),SIZE(pz1,2)-1)
!
  kklin(:,jk2)=ilevel(:)

!-------------------------------------------------------------------------------
!
!*       4.    Linear interpolation coefficients
!              ---------------------------------
!
  DO ji=1,SIZE(pz1,1)
    IF (pz1(ji,ilevel(ji))==pz1(ji,ilevel(ji)+1)) THEN
      pcoeflin(ji,jk2)= 0.
    ELSE
      pcoeflin(ji,jk2)=(pz2(ji,jk2)-pz1(ji,ilevel(ji)+1))              &
                        /(pz1(ji,ilevel(ji))-pz1(ji,ilevel(ji)+1))   
    END IF
    IF (iunder(ji) < 1 )           pcoeflin(ji,jk2)=1.                       ! no extrapolation
    IF (ilevel(ji)==SIZE(pz1,2)-1) pcoeflin(ji,jk2)=max(pcoeflin(ji,jk2),0.) ! no extrapolation
  ENDDO
!
!-------------------------------------------------------------------------------
!
END DO
IF (lhook) CALL dr_hook('COEF_VER_INTERP_LIN_SURF',1,zhook_handle)
!
!-------------------------------------------------------------------------------
!
END SUBROUTINE coef_ver_interp_lin_surf