prep_teb_garden.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_teb_garden (DTCO, UG, U, USS, IG, I, TG, TOP, GDM, &
                            hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!     #################################################################################
!
!!****  *PREP_TEB_GARDEN* - Prepares ISBA fields
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      Modified by P. Le Moigne (11/2004): AGS fields
!!      Modified by B. Decharme   (2008)  : Floodplains
!!      Modified by B. Decharme  (01/2009): Consistency with Arpege deep soil
!!                                          temperature
!!      Modified by B. Decharme  (03/2009): Consistency with Arpege permanent
!!                                          snow/ice treatment
!!------------------------------------------------------------------
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_isba_grid_n, ONLY : isba_grid_t
USE modd_isba_n, ONLY : isba_t
USE modd_teb_grid_n, ONLY : teb_grid_t
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_surfex_n, ONLY : teb_garden_model_t
!
USE modi_prep_hor_teb_garden_field
USE modi_prep_ver_teb_garden
!
USE modd_surf_atm,       ONLY : lvertshift
!
                                ! A FAIRE :
                                ! IL FAUT RAJOUTER TSNOW
                                ! ----------------------
USE modd_csts,        ONLY : xtt
USE modd_snow_par,    ONLY : xz0sn
USE modd_isba_par,    ONLY : xwgmin
USE modd_co2v_par,    ONLY : xanfminit, xca_nit, xcc_nit
USE modd_surf_par,    ONLY : xundef
!
USE modn_prep_isba
USE mode_pos_surf
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(isba_grid_t), INTENT(INOUT) :: ig
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(teb_grid_t), INTENT(INOUT) :: tg
TYPE(teb_options_t), INTENT(INOUT) :: top
TYPE(teb_garden_model_t), INTENT(INOUT) :: gdm
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
!
INTEGER,            INTENT(IN)  :: kpatch
!
!*      0.2    declarations of local variables
!
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.     Default of configuration
!
!*      1.1    Default
!
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations
!
!
!*      2.1    Soil Water reservoirs
!
IF (lhook) CALL dr_hook('PREP_TEB_GARDEN',0,zhook_handle)
 CALL prep_hor_teb_garden_field(dtco, ig, i, ug, u, uss, &
                                gdm%TGD, gdm%TGDO, gdm%TGDPE, gdm%TGDP, tg, top, gdm%TVG, &
                                hprogram,'WG     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!*      2.2    Soil ice reservoirs
!
 CALL prep_hor_teb_garden_field(dtco, ig, i, ug, u, uss, &
                                gdm%TGD, gdm%TGDO, gdm%TGDPE, gdm%TGDP, tg, top, gdm%TVG, &
                                hprogram,'WGI    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!*      2.3    Leaves interception water reservoir
!
 CALL prep_hor_teb_garden_field(dtco, ig, i, ug, u, uss, &
                                gdm%TGD, gdm%TGDO, gdm%TGDPE, gdm%TGDP, tg, top, gdm%TVG, &
                                hprogram,'WR     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!*      2.4    Temperature profile
!
 CALL prep_hor_teb_garden_field(dtco, ig, i, ug, u, uss, &
                                gdm%TGD, gdm%TGDO, gdm%TGDPE, gdm%TGDP, tg, top, gdm%TVG, &
                                hprogram,'TG     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!*      2.5    Snow variables
!
 CALL prep_hor_teb_garden_field(dtco, ig, i, ug, u, uss, &
                                gdm%TGD, gdm%TGDO, gdm%TGDPE, gdm%TGDP, tg, top, gdm%TVG, &
                                hprogram,'SN_VEG ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)

!
!*      2.6    LAI
!
IF (gdm%TVG%CPHOTO/='NON' .AND. gdm%TVG%CPHOTO/='AGS' .AND. gdm%TVG%CPHOTO/='LST')  &
 CALL prep_hor_teb_garden_field(dtco, ig, i, ug, u, uss, &
                                gdm%TGD, gdm%TGDO, gdm%TGDPE, gdm%TGDP, tg, top, gdm%TVG, &
                                hprogram,'LAI    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!-------------------------------------------------------------------------------------
!
!*      3.    Physical limitation: 
!
! If whole ice reservoir is empty (grib from ecmwf case) and surface temperature is
! lower than -10C, then ice content is maximum and water content minimum
!
IF (all(gdm%TGD%CUR%XWGI(:,:)==0.)) THEN
   WHERE(gdm%TGD%CUR%XTG(:,1:SIZE(gdm%TGD%CUR%XWG,2)) < xtt-10.)
       gdm%TGD%CUR%XWGI(:,:) = gdm%TGDP%XWSAT(:,:)-xwgmin
       gdm%TGD%CUR%XWG (:,:) = xwgmin
   END WHERE
ENDIF
!
! No ice for force restore third layer:
IF (gdm%TVG%CISBA == '3-L') THEN
      WHERE(gdm%TGD%CUR%XWG(:,3)/=xundef.AND.gdm%TGD%CUR%XWGI(:,3)/=xundef)
        gdm%TGD%CUR%XWG(:,3)  = min(gdm%TGD%CUR%XWG(:,3)+gdm%TGD%CUR%XWGI(:,3),gdm%TGDP%XWSAT(:,3))
        gdm%TGD%CUR%XWGI(:,3) = 0.
      END WHERE
ENDIF
!
! Total water content should not exceed saturation:
WHERE(gdm%TGD%CUR%XWG(:,:) /= xundef .AND. &
                  (gdm%TGD%CUR%XWG(:,:) + gdm%TGD%CUR%XWGI(:,:)) > gdm%TGDP%XWSAT(:,:) )
     gdm%TGD%CUR%XWGI(:,:) = gdm%TGDP%XWSAT(:,:) - gdm%TGD%CUR%XWG(:,:)
END WHERE
!
!-------------------------------------------------------------------------------------
!
!*      3.     Vertical interpolations of all variables
!
IF(lvertshift)THEN
  CALL prep_ver_teb_garden(gdm%TGD, gdm%TGDO, gdm%TGDP, top, gdm%TVG)
ENDIF
!
!
!-------------------------------------------------------------------------------------
!
!*      5.     Half prognostic fields
!
ALLOCATE(gdm%TGD%CUR%XRESA(SIZE(gdm%TGDPE%CUR%XLAI,1)))
gdm%TGD%CUR%XRESA = 100.
!
!-------------------------------------------------------------------------------------
!
!*      6.     Isba-Ags prognostic fields
!
IF (gdm%TVG%CPHOTO /= 'NON') THEN
!
   ALLOCATE(gdm%TGD%CUR%XAN(SIZE(gdm%TGDPE%CUR%XLAI,1)))
   gdm%TGD%CUR%XAN = 0.
!
   ALLOCATE(gdm%TGD%CUR%XANDAY(SIZE(gdm%TGDPE%CUR%XLAI,1)))
   gdm%TGD%CUR%XANDAY = 0.
!
   ALLOCATE(gdm%TGD%CUR%XANFM(SIZE(gdm%TGDPE%CUR%XLAI,1)))
   gdm%TGD%CUR%XANFM = xanfminit
!
   ALLOCATE(gdm%TGD%CUR%XLE(SIZE(gdm%TGDPE%CUR%XLAI,1)))
   gdm%TGD%CUR%XLE = 0.
!
ENDIF
!
IF (gdm%TVG%CPHOTO == 'AGS' .OR. gdm%TVG%CPHOTO == 'AST') THEN
!
   ALLOCATE(gdm%TGD%CUR%XBIOMASS(SIZE(gdm%TGDPE%CUR%XLAI,1),gdm%TVG%NNBIOMASS))
   gdm%TGD%CUR%XBIOMASS(:,1) = 0.
!
   ALLOCATE(gdm%TGD%CUR%XRESP_BIOMASS(SIZE(gdm%TGDPE%CUR%XLAI,1),gdm%TVG%NNBIOMASS))
   gdm%TGD%CUR%XRESP_BIOMASS(:,:) = 0.
!
ELSEIF (gdm%TVG%CPHOTO == 'LAI' .OR. gdm%TVG%CPHOTO == 'LST') THEN
!
   ALLOCATE(gdm%TGD%CUR%XBIOMASS(SIZE(gdm%TGDPE%CUR%XLAI,1),gdm%TVG%NNBIOMASS))
   gdm%TGD%CUR%XBIOMASS(:,1) = gdm%TGDPE%CUR%XLAI(:) * gdm%TGDP%XBSLAI(:)
!
   ALLOCATE(gdm%TGD%CUR%XRESP_BIOMASS(SIZE(gdm%TGDPE%CUR%XLAI,1),gdm%TVG%NNBIOMASS))
   gdm%TGD%CUR%XRESP_BIOMASS(:,:) = 0.
!
ELSEIF (gdm%TVG%CPHOTO == 'NIT' .OR. gdm%TVG%CPHOTO == 'NCB') THEN
!
   ALLOCATE(gdm%TGD%CUR%XBIOMASS(SIZE(gdm%TGDPE%CUR%XLAI,1),gdm%TVG%NNBIOMASS))
   gdm%TGD%CUR%XBIOMASS(:,1) = gdm%TGDPE%CUR%XLAI(:) * gdm%TGDP%XBSLAI_NITRO(:)
   gdm%TGD%CUR%XBIOMASS(:,2) = max( 0., (gdm%TGD%CUR%XBIOMASS(:,1)/ (xcc_nit/10.**xca_nit))  &
                              **(1.0/(1.0-xca_nit)) - gdm%TGD%CUR%XBIOMASS(:,1) )  
   gdm%TGD%CUR%XBIOMASS(:,3:gdm%TVG%NNBIOMASS) = 0.
!
   ALLOCATE(gdm%TGD%CUR%XRESP_BIOMASS(SIZE(gdm%TGDPE%CUR%XLAI,1),gdm%TVG%NNBIOMASS))
   gdm%TGD%CUR%XRESP_BIOMASS(:,:) = 0.
!
ENDIF
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PREP_TEB_GARDEN',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_teb_garden