prep_hor_teb_garden_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_hor_teb_garden_field (DTCO, IG, I, UG, U, USS, &
                                       tgd, tgdo, tgdpe, tgdp, tg, top, tvg, &
                                      hprogram,hsurf,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!     #################################################################################
!
!!****  *PREP_HOR_TEB_GARDEN_FIELD* - reads, interpolates and prepares an ISBA field
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      P. Le Moigne 10/2005, Phasage Arome
!!      P. Le Moigne 03/2007, Ajout initialisation par ascllv
!!      B. Decharme  01/2009, Optional Arpege deep soil temperature initialization
!!      B. Decharme  03/2014, external init with FA files
!!                            new vertical interpol
!!------------------------------------------------------------------
!
!
!
!
!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_isba_grid_n, ONLY : isba_grid_t
USE modd_isba_n, ONLY : isba_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_teb_garden_n, ONLY : teb_garden_t
USE modd_teb_garden_option_n, ONLY : teb_garden_options_t
USE modd_teb_garden_pgd_evol_n, ONLY : teb_garden_pgd_evol_t
USE modd_teb_garden_pgd_n, ONLY : teb_garden_pgd_t
USE modd_teb_grid_n, ONLY : teb_grid_t
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_teb_veg_n, ONLY : teb_veg_options_t
!
USE modd_prep,            ONLY : cingrid_type, cinterp_type, xzs_ls,       &
                                 xlat_out, xlon_out, xx_out, xy_out,       &
                                 linterp, cmask

USE modd_prep_teb_garden, ONLY : xgrid_soil, ngrid_level,                  &
                                 xwsnow_gd, xrsnow_gd, xtsnow_gd, xlwcsnow_gd, &
                                 xagesnow_gd, xasnow_gd, lsnow_ideal_gd

USE modd_isba_par,        ONLY : xwgmin
USE modd_data_cover_par,  ONLY : nvegtype
USE modd_surf_par,        ONLY : xundef
!
USE modi_read_prep_teb_garden_conf
USE modi_read_prep_garden_snow
USE modi_prep_teb_garden_ascllv
USE modi_prep_teb_garden_grib
USE modi_prep_teb_garden_unif
USE modi_prep_teb_garden_buffer
USE modi_hor_interpol
USE modi_put_on_all_vegtypes
USE modi_vegtype_grid_to_patch_grid
USE modi_prep_hor_snow_fields
USE modi_get_luout
USE modi_prep_teb_garden_extern
USE modi_abor1_sfx
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(isba_grid_t), INTENT(INOUT) :: ig
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
TYPE(teb_garden_t), INTENT(INOUT) :: tgd
TYPE(teb_garden_options_t), INTENT(INOUT) :: tgdo
TYPE(teb_garden_pgd_evol_t), INTENT(INOUT) :: tgdpe
TYPE(teb_garden_pgd_t), INTENT(INOUT) :: tgdp
TYPE(teb_grid_t), INTENT(INOUT) :: tg
TYPE(teb_options_t), INTENT(INOUT) :: top
TYPE(teb_veg_options_t), INTENT(INOUT) :: tvg
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
!
INTEGER,            INTENT(IN)  :: kpatch
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=6)              :: yfiletype ! type of input file
 CHARACTER(LEN=28)             :: yfile     ! name of file
 CHARACTER(LEN=6)              :: yfilepgdtype ! type of input file
 CHARACTER(LEN=28)             :: yfilepgd     ! name of file
 CHARACTER(LEN=6)              :: yfiletype_snow ! type of input file
 CHARACTER(LEN=28)             :: yfile_snow     ! name of file
 CHARACTER(LEN=6)              :: yfilepgdtype_snow ! type of input file
 CHARACTER(LEN=28)             :: yfilepgd_snow     ! name of file 
REAL, POINTER,     DIMENSION(:,:,:) :: zfieldin  ! field to interpolate horizontally
REAL, POINTER,     DIMENSION(:,:)   :: zfield ! field to interpolate horizontally
REAL, ALLOCATABLE, DIMENSION(:,:,:) :: zfieldoutp ! field interpolated   horizontally
REAL, ALLOCATABLE, DIMENSION(:,:,:) :: zfieldoutv !
REAL, ALLOCATABLE, DIMENSION(:,:,:) :: zvegtype_patch ! vegtype for each patch
REAL, ALLOCATABLE, DIMENSION(:,:)   :: zw        ! work array (x, fine   soil grid)
REAL, ALLOCATABLE, DIMENSION(:)     :: zsum
REAL, ALLOCATABLE, DIMENSION(:,:)   :: zf        ! work array (x, output soil grid)
REAL, ALLOCATABLE, DIMENSION(:,:)   :: zdg       ! out T grid (x, output soil grid)
REAL, ALLOCATABLE, DIMENSION(:,:)   :: zpatch    ! work array for patches
REAL, ALLOCATABLE, DIMENSION(:)     :: zsg1snow, zsg2snow, zhistsnow
INTEGER                             :: iluout    ! output listing logical unit
!
LOGICAL                             :: gunif     ! flag for prescribed uniform field
LOGICAL                             :: gunif_snow! flag for prescribed uniform field
INTEGER                             :: jvegtype, jpatch  ! loop on vegtypes
INTEGER                             :: jlayer    ! loop on layers
INTEGER                             :: ji, inp, inl, ini
INTEGER                             :: iwork     ! Work integer
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!
!*      1.     Reading of input file name and type
!
IF (lhook) CALL dr_hook('PREP_HOR_TEB_GARDEN_FIELD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL read_prep_teb_garden_conf(hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,&
                               hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,iluout,gunif)
!
 cmask = 'TOWN  '
!
ini=SIZE(tg%XLAT)
!-------------------------------------------------------------------------------------
!
!*      2.     Snow variables case?
!
IF (hsurf=='SN_VEG ') THEN
  CALL read_prep_garden_snow(hprogram,tgd%CUR%TSNOW%SCHEME,tgd%CUR%TSNOW%NLAYER,yfile_snow,&
        yfiletype_snow,yfilepgd_snow,yfilepgdtype_snow,gunif_snow)
  IF(.NOT.gunif_snow.AND.len_trim(yfile_snow)==0.AND.len_trim(yfiletype_snow)==0)THEN
    !IF(LEN_TRIM(YFILE)/=0.AND.LEN_TRIM(YFILETYPE)/=0)THEN
    IF (yfiletype=='GRIB') THEN
      yfile_snow    =yfile
      yfiletype_snow=yfiletype
      yfilepgd_snow    =yfilepgd
      yfilepgdtype_snow=yfilepgdtype       
    ELSE          
      gunif_snow=.true.
      IF(all(xwsnow_gd==xundef))xwsnow_gd=0.0 
    ENDIF 
  ENDIF    
  ALLOCATE(zsg1snow(SIZE(xwsnow_gd)))
  ALLOCATE(zsg2snow(SIZE(xwsnow_gd)))
  ALLOCATE(zhistsnow(SIZE(xwsnow_gd)))
  ALLOCATE(zpatch(SIZE(tgdp%XVEGTYPE,1),1))
  ALLOCATE(zvegtype_patch(SIZE(tgdp%XVEGTYPE,1),SIZE(tgdp%XVEGTYPE,2),1))
  !
  zpatch=1.
  zvegtype_patch(:,:,1) = tgdp%XVEGTYPE(:,:)
  CALL prep_hor_snow_fields(dtco, &
                            ig, u, &
                            hprogram,hsurf,                 &
                            yfile,yfiletype,                &
                            yfilepgd, yfilepgdtype,         &
                            iluout,gunif_snow,1,kpatch,     &
                            ini,tgd%CUR%TSNOW, top%TTIME,   &
                            xwsnow_gd, xrsnow_gd, xtsnow_gd,&
                            xlwcsnow_gd, xasnow_gd,         &
                            lsnow_ideal_gd, zsg1snow,       &
                            zsg2snow, zhistsnow, xagesnow_gd,  &
                            tgdp%XVEGTYPE,zvegtype_patch, zpatch )
  DEALLOCATE(zsg1snow)
  DEALLOCATE(zsg2snow)
  DEALLOCATE(zhistsnow)  
  DEALLOCATE(zpatch)
  DEALLOCATE(zvegtype_patch)
  IF (lhook) CALL dr_hook('PREP_HOR_TEB_GARDEN_FIELD',1,zhook_handle)
  RETURN
END IF
!
!-------------------------------------------------------------------------------------
!
!*      3.     Reading of input  configuration (Grid and interpolation type)
!
IF (gunif) THEN
  CALL prep_teb_garden_unif(iluout,hsurf,zfieldin)
ELSE IF (yfiletype=='ASCLLV') THEN
  CALL prep_teb_garden_ascllv(dtco, ug, u, uss, &
                              hprogram,hsurf,iluout,zfieldin)
ELSE IF (yfiletype=='GRIB  ') THEN
  CALL prep_teb_garden_grib(hprogram,hsurf,yfile,iluout,zfieldin)
ELSE IF (yfiletype=='MESONH' .OR. yfiletype=='ASCII ' .OR. yfiletype=='LFI   '.OR.yfiletype=='FA    ') THEN
   CALL prep_teb_garden_extern(dtco, i, u, &
                               hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,iluout,kpatch,zfieldin)
ELSE IF (yfiletype=='BUFFER') THEN
   CALL prep_teb_garden_buffer(hprogram,hsurf,iluout,zfieldin)
ELSE
   CALL abor1_sfx('PREP_HOR_TEB_GARDEN_FIELD: data file type not supported : '//yfiletype)
END IF
!
!-------------------------------------------------------------------------------------
!
!*      5.     Horizontal interpolation
!
inl = SIZE(zfieldin,2)
inp = SIZE(zfieldin,3)
!
ALLOCATE(zfieldoutp(ini,inl,inp))
ALLOCATE(zfield(SIZE(zfieldin,1),inl))
!
DO jpatch = 1, SIZE(zfieldin,3)
  zfield=zfieldin(:,:,jpatch)
  IF (inp==nvegtype) linterp = (tgdp%XVEGTYPE(:,jpatch) > 0.)
  CALL hor_interpol(dtco, u, &
                    iluout,zfield,zfieldoutp(:,:,jpatch))
  linterp = .true.
END DO
!
DEALLOCATE(zfield)
!
ALLOCATE(zfieldoutv(ini,inl,nvegtype))
!
 CALL put_on_all_vegtypes(ini,inl,inp,nvegtype,zfieldoutp,zfieldoutv)
!
DEALLOCATE(zfieldoutp)
!
!-------------------------------------------------------------------------------------
!
!*      6.     Transformation from vegtype grid to averaged grid
!
ALLOCATE(zw(ini,SIZE(zfieldoutv,2)))
ALLOCATE(zsum(SIZE(zfieldoutv,1)))
zw = 0.
!
DO jlayer=1,SIZE(zw,2)
  zsum(:) = sum(tgdp%XVEGTYPE(:,:),2,zfieldoutv(:,jlayer,:)/=xundef)
  DO jvegtype=1,nvegtype
    WHERE (zfieldoutv(:,jlayer,jvegtype)/=xundef) 
      zw(:,jlayer) = zw(:,jlayer) + tgdp%XVEGTYPE(:,jvegtype) * zfieldoutv(:,jlayer,jvegtype) / zsum(:)
    END WHERE
  END DO
  DO ji=1,SIZE(zw,1)
    IF (all(zfieldoutv(ji,jlayer,:)==xundef)) zw(ji,jlayer) = xundef
  ENDDO
END DO
!
!-------------------------------------------------------------------------------------
!
!*      7.     Return to historical variable
!
!
SELECT CASE (hsurf)
  !
  !- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  !
 CASE('WG     ') 
  ALLOCATE(zf(SIZE(zfieldoutv,1),tgdo%NGROUND_LAYER))
  !
  !* interpolates on output levels
  CALL init_from_ref_grid(xgrid_soil,zw,tgdp%XDG,zf)
  !
  !* retrieves soil water content from soil relative humidity
  ALLOCATE(tgd%CUR%XWG(SIZE(zfieldoutv,1),tgdo%NGROUND_LAYER))
  tgd%CUR%XWG(:,:) = tgdp%XWWILT + zf(:,:) * (tgdp%XWFC-tgdp%XWWILT)
  tgd%CUR%XWG(:,:) = max(min(tgd%CUR%XWG(:,:),tgdp%XWSAT),xwgmin)
  !
  WHERE(zf(:,:)==xundef)tgd%CUR%XWG(:,:)=xundef
  !
  DEALLOCATE(zf)
  !
  !- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  !
 CASE('WGI    ')
  ALLOCATE(zf(SIZE(zfieldoutv,1),tgdo%NGROUND_LAYER))
  !
  !* interpolates on output levels
  CALL init_from_ref_grid(xgrid_soil,zw,tgdp%XDG,zf)
  !
  !* retrieves soil ice content from soil relative humidity
  ALLOCATE(tgd%CUR%XWGI(SIZE(zfieldoutv,1),tgdo%NGROUND_LAYER))
  tgd%CUR%XWGI(:,:) = zf(:,:) * tgdp%XWSAT
  tgd%CUR%XWGI(:,:) = max(min(tgd%CUR%XWGI(:,:),tgdp%XWSAT),0.)
  !
  WHERE(zf(:,:)==xundef)tgd%CUR%XWGI(:,:)=xundef
  !
  DEALLOCATE(zf)
  !
  !- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  !
 CASE('TG     ') 
  iwork=tgdo%NGROUND_LAYER
  ALLOCATE(tgd%CUR%XTG(SIZE(zfieldoutv,1),iwork))
  ALLOCATE(zdg(SIZE(tgdp%XDG,1),iwork))
  IF (tvg%CISBA=='2-L'.OR.tvg%CISBA=='3-L') THEN
    zdg(:,1) = 0.01
    zdg(:,2) = 0.40   ! deep temperature for force-restore taken at 20cm
    IF(tvg%CISBA=='3-L') zdg(:,3) = 5.00   ! climatological temperature, usually not used
  ELSE
    !* diffusion method, the soil grid is the same as for humidity
    zdg(:,:) = tgdp%XDG(:,:)
  END IF
  CALL init_from_ref_grid(xgrid_soil,zw,zdg,tgd%CUR%XTG)
  DEALLOCATE(zdg)
  !
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  !
 CASE('WR     ') 
  ALLOCATE(tgd%CUR%XWR(SIZE(zfieldoutv,1)))
  tgd%CUR%XWR(:) = zw(:,1)
  !
  !- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  !
 CASE('LAI    ') 
  !* LAI is updated only if present and pertinent (evolutive LAI) in input file

   WHERE (zw(:,1)/=xundef) tgdpe%CUR%XLAI(:) = zw(:,1)
  !
END SELECT
!
DEALLOCATE(zw)
!-------------------------------------------------------------------------------------
!
!*      8.     Deallocations
!
DEALLOCATE(zfieldin )
DEALLOCATE(zfieldoutv)
!
IF (lhook) CALL dr_hook('PREP_HOR_TEB_GARDEN_FIELD',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!-------------------------------------------------------------------------------------
!
 CONTAINS
!
!-------------------------------------------------------------------------------------
!-------------------------------------------------------------------------------------
!
SUBROUTINE init_from_ref_grid(PGRID1,PT1,PD2,PT2)
!
USE modi_interp_grid_nat
!
REAL, DIMENSION(:,:), INTENT(IN)  :: pt1    ! variable profile
REAL, DIMENSION(:),   INTENT(IN)  :: pgrid1 ! normalized grid
REAL, DIMENSION(:,:), INTENT(IN)  :: pd2    ! output layer thickness
REAL, DIMENSION(:,:), INTENT(OUT) :: pt2    ! variable profile
!
INTEGER                                  :: ji, jl  ! loop counter
REAL, DIMENSION(SIZE(PT1,1),SIZE(PT1,2)) :: zd1 ! input grid
!
INTEGER :: ilayer1, ilayer2
REAL(KIND=JPRB) :: zhook_handle
!
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
IF (lhook) CALL dr_hook('INIT_FROM_REF_GRID',0,zhook_handle)
!
IF (SIZE(pt1,2)==3) THEN
!
!* 1. case with only 3 input levels (typically coming from 'UNIF')
!     -----------------------------
!
  IF (tvg%CISBA=='2-L' .OR. tvg%CISBA=='3-L') THEN
    !* Possible LTEMP_ARP case
    IF(SIZE(pt2,2)>3)THEN
       ilayer1=3
       ilayer2=SIZE(pt2,2)
    ELSE
       ilayer1=SIZE(pt2,2)
       ilayer2=0
    ENDIF
    !* historical 2L or 3L ISBA version
    pt2(:,1:ilayer1) = pt1(:,1:ilayer1) 
    !* Possible LTEMP_ARP case
    IF(ilayer2>0)THEN
       DO jl=ilayer1+1,ilayer2
         pt2(:,jl) = pt2(:,ilayer1)
       ENDDO
    ENDIF
!    
  ELSEIF(tvg%CISBA=='DIF')THEN
       !surface layer (generally 0.01m imposed)
       pt2(:,1) = pt1(:,1) 
       !deep layers
       DO jl=2,tgdo%NGROUND_LAYER
          pt2(:,jl) = pt1(:,3)
       END DO
       !if root layers
       DO ji=1,SIZE(pt1,1)
          DO jl=2,tgdo%NGROUND_LAYER
             IF(tgdp%XROOTFRAC(ji,jl)<=1.0)THEN 
                pt2(ji,jl) = pt1(ji,2)
                EXIT
             ENDIF
          END DO
       END DO 
  END IF    
!
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
ELSE
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
!* 2. case with fine grid as input (general case)
!     ----------------------------
!
  DO jl=1,SIZE(pt1,2)
    zd1(:,jl) = pgrid1(jl)
  END DO
!
  CALL interp_grid_nat(zd1,pt1(:,:),pd2,pt2(:,:))
!
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
ENDIF
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!
IF (lhook) CALL dr_hook('INIT_FROM_REF_GRID',1,zhook_handle)
!
!- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
END SUBROUTINE init_from_ref_grid
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_hor_teb_garden_field