prep_teb_garden_extern.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_teb_garden_extern (DTCO, I, U, &
                                   hprogram,hsurf,hfile,hfiletype,hfilepgd,hfilepgdtype,kluout,kpatch,pfield)
!     #################################################################################
!
!!****  *PREP_TEB_GARDEN_EXTERN* - initializes ISBA fields from operational GRIB
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!------------------------------------------------------------------
!

!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_isba_n, ONLY : isba_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE mode_read_extern
!
USE modd_type_date_surf
!
USE modi_prep_grid_extern
USE modi_read_surf
USE modi_interp_grid_nat
USE modi_open_aux_io_surf
USE modi_close_aux_io_surf
USE modi_read_teb_patch
USE modi_town_presence
!
USE modd_prep,           ONLY : cingrid_type, cinterp_type
USE modd_prep_teb_garden,ONLY : xgrid_soil, xwr_def
USE modd_data_cover_par, ONLY : nvegtype
USE modd_surf_par,       ONLY : xundef
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_put_on_all_vegtypes
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: hfile     ! name of file
 CHARACTER(LEN=6),   INTENT(IN)  :: hfiletype ! type of input file
 CHARACTER(LEN=28),  INTENT(IN)  :: hfilepgd     ! name of file
 CHARACTER(LEN=6),   INTENT(IN)  :: hfilepgdtype ! type of input file
INTEGER,            INTENT(IN)  :: kluout    ! logical unit of output listing
INTEGER,            INTENT(IN)  :: kpatch
REAL,DIMENSION(:,:,:), POINTER  :: pfield    ! field to interpolate horizontally (on final soil grid)
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=12) :: yrecfm         ! Name of the article to be read
INTEGER           :: iresp          ! reading return code
INTEGER           :: ini            ! total 1D dimension
INTEGER           :: ipatch         ! number of patch
!
REAL, DIMENSION(:,:,:), POINTER     :: zfield         ! field read on initial MNH vertical soil grid, all patches
REAL, DIMENSION(:,:),   POINTER     :: zfield1        ! field read on initial MNH vertical soil grid, one patch
REAL, DIMENSION(:,:,:), POINTER     :: zd             ! depth of field in the soil
REAL, DIMENSION(:,:), POINTER       :: zd1            ! depth of field in the soil, one patch
REAL, DIMENSION(:,:), ALLOCATABLE   :: zout           !
INTEGER                             :: jpatch         ! loop counter for patch
INTEGER                             :: iteb_patch     ! number of TEB patches in file
INTEGER                             :: iversion       ! SURFEX version
INTEGER                             :: ibugfix        ! SURFEX bug version
LOGICAL                             :: gold_name      ! old name flag for temperatures
 CHARACTER(LEN=12)                   :: ysurf     ! type of field
 CHARACTER(LEN=3)                    :: ypatch    ! indentificator for TEB patch
LOGICAL                         :: gteb      ! flag if TEB fields are present
LOGICAL                         :: ggarden   ! T if gardens are present in the file
REAL(KIND=JPRB) :: zhook_handle
!
!------------------------------------------------------------------------------
!
!*      1.     Preparation of IO for reading in the file
!              -----------------------------------------
!
!* Note that all points are read, even those without physical meaning.
!  These points will not be used during the horizontal interpolation step.
!  Their value must be defined as XUNDEF.
!
IF (lhook) CALL dr_hook('PREP_TEB_GARDEN_EXTERN',0,zhook_handle)
!
!------------------------------------------------------------------------------
!
!*      2.     Reading of grid
!              ---------------
!
 CALL open_aux_io_surf(&
                      hfilepgd,hfilepgdtype,'FULL  ')
!
!* reading of version of the file being read
 CALL read_surf(&
               hfilepgdtype,'VERSION',iversion,iresp)
 CALL read_surf(&
               hfilepgdtype,'BUG',ibugfix,iresp)
gold_name=(iversion<7 .OR. (iversion==7 .AND. ibugfix<3))
!
 CALL prep_grid_extern(&
                      hfilepgdtype,kluout,cingrid_type,cinterp_type,ini)
!
!* reads if TEB fields exist in the input file
 CALL town_presence(&
                   hfilepgdtype,gteb)
!
IF (gteb) THEN
  CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
  CALL read_teb_patch(&
                      hfilepgd,hfilepgdtype,iteb_patch)
  CALL open_aux_io_surf(&
                      hfilepgd,hfilepgdtype,'FULL  ')  
  ypatch='   '
  IF (iteb_patch>1) THEN
    WRITE(ypatch,fmt='(A,I1,A)') 'T',min(kpatch,iteb_patch),'_'
  END IF
END IF
!
!---------------------------------------------------------------------------------------
!
!*      3.     Transformation into physical quantity to be interpolated
!              --------------------------------------------------------
!
SELECT CASE(hsurf)
!
!*     3.      Orography
!              ---------
!
  CASE('ZS     ')
    ALLOCATE(pfield(ini,1,1))
    yrecfm='ZS'
    CALL read_surf(&
               hfilepgdtype,yrecfm,pfield(:,1,1),iresp,hdir='A')
    CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
!
!--------------------------------------------------------------------------
!
!
!*      3.1    Profile of temperature, water or ice in the soil
!
  CASE('TG    ','WG    ','WGI   ')
!* choice if one reads garden fields (if present) or ISBA fields
    ggarden = .false.
    IF (gteb) CALL read_surf(&
               hfilepgdtype,'GARDEN',ggarden,iresp)
    CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
    IF (ggarden) THEN
      ysurf = 'GD_'//hsurf(1:3)
      IF (gold_name) ysurf = 'TWN_'//hsurf(1:3)
      ysurf = ypatch//ysurf
    ELSE
      ysurf = hsurf
    END IF
    ysurf=adjustl(ysurf)  
!* reading of the profile and its depth definition
     CALL read_extern_isba(u, &
                           dtco, i, &
                           hfile,hfiletype,hfilepgd,hfilepgdtype,kluout,ini,&
                hsurf,ysurf,zfield,zd)
! 
     ALLOCATE(zfield1(SIZE(zfield,1),SIZE(zfield,2)))
     ALLOCATE(zd1(SIZE(zfield,1),SIZE(zfield,2)))
     ALLOCATE(zout(SIZE(zfield,1),SIZE(xgrid_soil)))
     ALLOCATE(pfield(SIZE(zfield,1),SIZE(xgrid_soil),SIZE(zfield,3)))
!
     DO jpatch=1,SIZE(zfield,3)
        zfield1(:,:)=zfield(:,:,jpatch)
        zd1(:,:)=zd(:,:,jpatch)
        CALL interp_grid_nat(zd1,zfield1,xgrid_soil,zout)
        pfield(:,:,jpatch)=zout(:,:)
     END DO
!
     DEALLOCATE(zfield)
     DEALLOCATE(zout)
     DEALLOCATE(zfield1)
     DEALLOCATE(zd)
!
!--------------------------------------------------------------------------
!
!*      3.4    Water content intercepted on leaves, LAI
!
  CASE('WR     ')
     ALLOCATE(pfield(ini,1,nvegtype))
     !* choice if one reads garden fields (if present) or ISBA fields    
     ggarden = .false.
     IF (gteb) CALL read_surf(&
               hfilepgdtype,'GARDEN',ggarden,iresp)
     CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
     IF (ggarden) THEN
       ipatch = 1    
       yrecfm = 'GD_WR'
       IF (gold_name) yrecfm = 'TWN_WR'
       yrecfm = ypatch//yrecfm
       CALL open_aux_io_surf(&
                      hfile,hfiletype,'TOWN  ')
     ELSE            
       yrecfm = 'PATCH_NUMBER'
       CALL open_aux_io_surf(&
                      hfilepgd,hfilepgdtype,'NATURE')
       CALL read_surf(&
               hfilepgdtype,yrecfm,ipatch,iresp)
       CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
       CALL open_aux_io_surf(&
                      hfile,hfiletype,'NATURE')
       yrecfm = 'WR'
     END IF
     yrecfm=adjustl(yrecfm)
     
     ALLOCATE(zfield(ini,1,ipatch))
     CALL read_surf(&
               hfiletype,yrecfm,zfield(:,1,:),iresp,hdir='A')
     CALL close_aux_io_surf(hfile,hfiletype)
     CALL put_on_all_vegtypes(ini,1,1,nvegtype,zfield,pfield)
     DEALLOCATE(zfield)
!
  CASE('LAI    ')
     CALL close_aux_io_surf(hfilepgd,hfilepgdtype)
     ALLOCATE(pfield(ini,1,nvegtype))
     pfield(:,:,:) = xundef
!
END SELECT
!
!
!---------------------------------------------------------------------------
!
!*      6.     End of IO
!              ---------
!
IF (lhook) CALL dr_hook('PREP_TEB_GARDEN_EXTERN',1,zhook_handle)
!
!---------------------------------------------------------------------------
!---------------------------------------------------------------------------
END SUBROUTINE prep_teb_garden_extern