prep_teb_greenroof.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_teb_greenroof (DTCO, UG, U, USS, IG, I, TG, T, TOP, TVG, GRM, &
                               hprogram,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!     #################################################################################
!
!!****  *PREP_TEB_GREENROOF* - Prepares ISBA fields for greenroofs
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!    Based on "prep_teb_garden"
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!      A. Lemonsu & C. de Munck 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    07/2011
!!------------------------------------------------------------------
!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
USE modd_isba_grid_n, ONLY : isba_grid_t
USE modd_isba_n, ONLY : isba_t
USE modd_teb_grid_n, ONLY : teb_grid_t
USE modd_teb_n, ONLY : teb_t
USE modd_teb_option_n, ONLY : teb_options_t
USE modd_teb_veg_n, ONLY : teb_veg_options_t
USE modd_surfex_n, ONLY : teb_greenroof_model_t
!
USE modi_prep_hor_teb_greenroof_field
USE modi_prep_ver_teb_greenroof
!
                                ! A FAIRE :
                                ! IL FAUT RAJOUTER TSNOW
                                ! ----------------------
USE modd_surf_atm,       ONLY : lvertshift
USE modd_csts,           ONLY : xtt
USE modd_snow_par,       ONLY : xz0sn
USE modd_isba_par,       ONLY : xwgmin
USE modd_co2v_par,       ONLY : xcc_nit, xca_nit, xanfminit
USE modd_surf_par,       ONLY : xundef
!
USE modn_prep_isba
USE mode_pos_surf
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
TYPE(isba_grid_t), INTENT(INOUT) :: ig
TYPE(isba_t), INTENT(INOUT) :: i
TYPE(teb_grid_t), INTENT(INOUT) :: tg
TYPE(teb_t), INTENT(INOUT) :: t
TYPE(teb_options_t), INTENT(INOUT) :: top
TYPE(teb_veg_options_t), INTENT(INOUT) :: tvg
TYPE(teb_greenroof_model_t), INTENT(INOUT) :: grm
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram    ! program calling surf. schemes
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
!
INTEGER,            INTENT(IN)  :: kpatch
!
!*      0.2    declarations of local variables
!
INTEGER :: jp
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.     Default of configuration
!
!*      1.1    Default
!
!
!-------------------------------------------------------------------------------------
!
!*      2.     Reading and horizontal interpolations
!
!
!*      2.1    Soil Water reservoirs
!
IF (lhook) CALL dr_hook('PREP_TEB_GREENROOF',0,zhook_handle)
!
 CALL prep_hor_teb_greenroof_field(dtco, ig, i, ug, u, uss, grm%TGR, grm%TGRO, grm%TGRPE, grm%TGRP, &
                                         tg, top, &
                                   hprogram,'WG     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!*      2.2    Soil ice reservoirs
!
 CALL prep_hor_teb_greenroof_field(dtco, ig, i, ug, u, uss, grm%TGR, grm%TGRO, grm%TGRPE, grm%TGRP, &
                                         tg, top, &
                                   hprogram,'WGI    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!*      2.3    Leaves interception water reservoir
!
 CALL prep_hor_teb_greenroof_field(dtco, ig, i, ug, u, uss, grm%TGR, grm%TGRO, grm%TGRPE, grm%TGRP, &
                                         tg, top, &
                                   hprogram,'WR     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!*      2.4    Temperature profile
!
 CALL prep_hor_teb_greenroof_field(dtco, ig, i, ug, u, uss, grm%TGR, grm%TGRO, grm%TGRPE, grm%TGRP, &
                                         tg, top, &
                                   hprogram,'TG     ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
! Initializing deep GR temp. with that of the outer layer of the structural roof 
!
grm%TGRP%XTDEEP(:) = t%CUR%XT_ROOF(:,1)
!
!*      2.5    Snow variables
!
 CALL prep_hor_teb_greenroof_field(dtco, ig, i, ug, u, uss, grm%TGR, grm%TGRO, grm%TGRPE, grm%TGRP, &
                                         tg, top, &
                                   hprogram,'SN_VEG ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!*      2.6    LAI
!
 CALL prep_hor_teb_greenroof_field(dtco, ig, i, ug, u, uss, grm%TGR, grm%TGRO, grm%TGRPE, grm%TGRP, &
                                         tg, top, &
                                   hprogram,'LAI    ',hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,kpatch)
!
!-------------------------------------------------------------------------------------
!
!*      3.    Physical limitations: 
!
! 3.1  If whole ice reservoir is empty (grib from ecmwf case) and surface temperature is
!      lower than -10C, then ice content is maximum and water content minimum
!
IF (all(grm%TGR%CUR%XWGI(:,:)==0.)) THEN
   WHERE(grm%TGR%CUR%XTG(:,1:SIZE(grm%TGR%CUR%XWG,2)) < xtt-10.)
      grm%TGR%CUR%XWGI(:,:) = grm%TGRP%XWSAT(:,:)-xwgmin
      grm%TGR%CUR%XWG (:,:) = xwgmin
   END WHERE
ENDIF
!
!
! 3.2.  Total water content should not exceed saturation:
WHERE(grm%TGR%CUR%XWG(:,:) /= xundef .AND. (grm%TGR%CUR%XWG(:,:) + grm%TGR%CUR%XWGI(:,:)) > grm%TGRP%XWSAT(:,:) )
   grm%TGR%CUR%XWGI(:,:) = grm%TGRP%XWSAT(:,:) - grm%TGR%CUR%XWG(:,:)
END WHERE
!
!-------------------------------------------------------------------------------------
!
!*      4.     Vertical interpolations of all variables
!
IF(lvertshift)THEN
  CALL prep_ver_teb_greenroof(grm%TGR, grm%TGRO, grm%TGRP, top)
ENDIF
!
!
!-------------------------------------------------------------------------------------
!
!*      5.     Half prognostic fields
!
ALLOCATE(grm%TGR%CUR%XRESA(SIZE(grm%TGRPE%CUR%XLAI)))
grm%TGR%CUR%XRESA(:) = 100.
!
!-------------------------------------------------------------------------------------
!
!*      6.     Isba-Ags prognostic fields
!
IF (tvg%CPHOTO /= 'NON') THEN
!
   ALLOCATE(grm%TGR%CUR%XAN(SIZE(grm%TGRPE%CUR%XLAI)))
   grm%TGR%CUR%XAN = 0.
!
   ALLOCATE(grm%TGR%CUR%XANDAY(SIZE(grm%TGRPE%CUR%XLAI)))
   grm%TGR%CUR%XANDAY = 0.
!
   ALLOCATE(grm%TGR%CUR%XANFM(SIZE(grm%TGRPE%CUR%XLAI)))
   grm%TGR%CUR%XANFM = xanfminit
!
   ALLOCATE(grm%TGR%CUR%XLE(SIZE(grm%TGRPE%CUR%XLAI)))
   grm%TGR%CUR%XLE = 0.
!
ENDIF
!
IF (tvg%CPHOTO == 'AGS' .OR. tvg%CPHOTO == 'AST') THEN
!
   ALLOCATE(grm%TGR%CUR%XBIOMASS(SIZE(grm%TGRPE%CUR%XLAI),tvg%NNBIOMASS))
   grm%TGR%CUR%XBIOMASS(:,1) = 0.
!
   ALLOCATE(grm%TGR%CUR%XRESP_BIOMASS(SIZE(grm%TGRPE%CUR%XLAI),tvg%NNBIOMASS))
   grm%TGR%CUR%XRESP_BIOMASS(:,:) = 0.
!
ELSEIF (tvg%CPHOTO == 'LAI' .OR. tvg%CPHOTO == 'LST') THEN
!
   ALLOCATE(grm%TGR%CUR%XBIOMASS(SIZE(grm%TGRPE%CUR%XLAI),tvg%NNBIOMASS))
   grm%TGR%CUR%XBIOMASS(:,1) = grm%TGRPE%CUR%XLAI(:) * grm%TGRP%XBSLAI(:)
!
   ALLOCATE(grm%TGR%CUR%XRESP_BIOMASS(SIZE(grm%TGRPE%CUR%XLAI),tvg%NNBIOMASS))
   grm%TGR%CUR%XRESP_BIOMASS(:,:) = 0.
!
ELSEIF (tvg%CPHOTO == 'NIT' .OR. tvg%CPHOTO == 'NCB') THEN
!
   ALLOCATE(grm%TGR%CUR%XBIOMASS(SIZE(grm%TGRPE%CUR%XLAI),tvg%NNBIOMASS))
   grm%TGR%CUR%XBIOMASS(:,1) = grm%TGRPE%CUR%XLAI(:) * grm%TGRP%XBSLAI_NITRO(:)
   grm%TGR%CUR%XBIOMASS(:,2) = max( 0., (grm%TGR%CUR%XBIOMASS(:,1)/ (xcc_nit/10.**xca_nit))  &
                              **(1.0/(1.0-xca_nit)) - grm%TGR%CUR%XBIOMASS(:,1) )  
   grm%TGR%CUR%XBIOMASS(:,3:tvg%NNBIOMASS) = 0.
!
   ALLOCATE(grm%TGR%CUR%XRESP_BIOMASS(SIZE(grm%TGRPE%CUR%XLAI),tvg%NNBIOMASS))
   grm%TGR%CUR%XRESP_BIOMASS(:,:) = 0.
!
ENDIF
!
!-------------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('PREP_TEB_GREENROOF',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_teb_greenroof