prep_ver_teb_greenroof.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_ver_teb_greenroof (TGR, TGRO, TGRP, TOP)
!     #################################################################################
!
!!****  *PREP_VER_TEB_GREENROOF* - change in ISBA fields due to altitude change
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     V. Masson  + A.Lemonsu & C.deMunck
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      Modified by B. Decharme  (01/2009), Optional Arpege deep soil temperature initialization
!!------------------------------------------------------------------
!

!
!
USE modd_teb_greenroof_n, ONLY : teb_greenroof_t
USE modd_teb_greenroof_option_n, ONLY : teb_greenroof_options_t
USE modd_teb_greenroof_pgd_n, ONLY : teb_greenroof_pgd_t
USE modd_teb_option_n, ONLY : teb_options_t
!
USE modd_isba_par,          ONLY : xwgmin
USE modd_surf_par,          ONLY : xundef
USE modd_prep,              ONLY : xzs_ls, xt_clim_grad
USE modd_csts,              ONLY : xtt, xday, xlmtt, xrholw
!
USE mode_thermos
USE modi_prep_ver_snow
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!*      0.2    declarations of local variables
!
!
TYPE(teb_greenroof_t), INTENT(INOUT) :: tgr
TYPE(teb_greenroof_options_t), INTENT(INOUT) :: tgro
TYPE(teb_greenroof_pgd_t), INTENT(INOUT) :: tgrp
TYPE(teb_options_t), INTENT(INOUT) :: top
!
INTEGER                         :: jl        ! loop counter on layers
INTEGER                         :: iwork     ! Work integer
!
REAL, DIMENSION(:), ALLOCATABLE :: zwgtot    ! total water content
REAL, DIMENSION(:), ALLOCATABLE :: zdw       ! variation of water in soil
REAL, DIMENSION(:), ALLOCATABLE :: zzsfreeze ! altitude where soil temperature equals XTT
INTEGER                         :: ideep_soil! layer corresponding to deep soil temperature
!
REAL, DIMENSION(:,:), ALLOCATABLE :: zwgi_clim_grad ! ice content vertical gradient
!
REAL, DIMENSION(:,:), ALLOCATABLE :: ztg_ls! temperature on initial orography
!
REAL                            :: zgradx = 5.e-4 ! slope of ice content gradient
REAL                            :: zh0    = 5.e-1 ! constant used to define ice content gradient
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!*      1.0    Ice content climatologic gradient
!
IF (lhook) CALL dr_hook('PREP_VER_TEB_GREENROOF',0,zhook_handle)
ALLOCATE(zwgi_clim_grad(SIZE(tgr%CUR%XWG,1),SIZE(tgr%CUR%XWG,2)))
!
zwgi_clim_grad(:,:) = zgradx * exp( - tgrp%XDG(:,:) / zh0 )
!-------------------------------------------------------------------------------------
!
!*      1.1    Temperature profile
!
ALLOCATE(ztg_ls(SIZE(tgr%CUR%XTG,1),SIZE(tgr%CUR%XTG,2)))
ztg_ls(:,:) = tgr%CUR%XTG(:,:)
!
  DO jl=1,SIZE(tgr%CUR%XTG,2)
    WHERE(tgr%CUR%XTG(:,jl)/=xundef) &
      tgr%CUR%XTG(:,jl) = tgr%CUR%XTG(:,jl) + xt_clim_grad  * (top%XZS - xzs_ls)  
  END DO
!
!-------------------------------------------------------------------------------------
!
!*      1.2    Water and ice in the soil
!
ALLOCATE(zzsfreeze(SIZE(tgr%CUR%XWG,1)))
ALLOCATE(zwgtot(SIZE(tgr%CUR%XWG,1)))
ALLOCATE(zdw(SIZE(tgr%CUR%XWG,1)))
!
!* general case
!
iwork=SIZE(tgr%CUR%XTG,2)
!
  !
  DO jl=1,iwork
    !
    zdw(:) = 0.
    ! altitude where deep soil freezes (diurnal surface response is not treated)
    zzsfreeze(:) = top%XZS + (xtt - tgr%CUR%XTG(:,jl)) / xt_clim_grad
    !
    WHERE(tgr%CUR%XTG(:,jl)/=xundef) 
      !
      WHERE (ztg_ls(:,jl) < xtt)
        !
        WHERE (top%XZS <= xzs_ls)
          !
          WHERE (top%XZS > zzsfreeze) 
            zdw(:) = zwgi_clim_grad(:,jl) * (top%XZS - xzs_ls)
          ELSEWHERE
            zdw(:) = zwgi_clim_grad(:,jl) * (zzsfreeze - xzs_ls) + zgradx * (top%XZS - zzsfreeze)
          ENDWHERE
          !
        ELSEWHERE
          !
          zdw(:) = zwgi_clim_grad(:,jl) * (top%XZS - xzs_ls)
          !
        ENDWHERE
        !
      ELSEWHERE
        !
        WHERE (top%XZS <= xzs_ls)
          !
          zdw(:) = zgradx * (top%XZS - xzs_ls)
          !
        ELSEWHERE
          !
          zdw(:) = zwgi_clim_grad(:,jl) * (top%XZS - zzsfreeze)
          !
        END WHERE
        !
      END WHERE
      !
      zwgtot(:) = xundef
      !
      WHERE(tgr%CUR%XWG(:,jl)/=xundef)         
        zwgtot(:) = tgr%CUR%XWG(:,jl) + tgr%CUR%XWGI(:,jl)
      ENDWHERE 
      !
      WHERE(tgr%CUR%XWG(:,jl)/=xundef)      
        tgr%CUR%XWGI(:,jl) = tgr%CUR%XWGI(:,jl) + zdw(:)
        tgr%CUR%XWG (:,jl) = tgr%CUR%XWG (:,jl) - zdw(:)
      ENDWHERE      
      !
      WHERE (tgr%CUR%XWGI(:,jl) < 0..AND.tgr%CUR%XWGI(:,jl)/=xundef) 
        tgr%CUR%XWGI(:,jl) = 0.
        tgr%CUR%XWG (:,jl) = zwgtot(:)
      END WHERE
      !
      WHERE (tgr%CUR%XWG(:,jl) < xwgmin.AND.tgr%CUR%XWG(:,jl)/=xundef)
        tgr%CUR%XWG (:,jl) = xwgmin
        tgr%CUR%XWGI(:,jl) = zwgtot(:) - xwgmin
      END WHERE
      !
      WHERE(tgr%CUR%XWGI(:,jl) > 0..AND.tgr%CUR%XWGI(:,jl)/=xundef)
        tgr%CUR%XTG(:,jl) = min(xtt,tgr%CUR%XTG(:,jl))
      ELSEWHERE
        tgr%CUR%XTG(:,jl) = max(xtt,tgr%CUR%XTG(:,jl))
      ENDWHERE
      !
    ENDWHERE
    !
  END DO
  !
!
!
DEALLOCATE(zzsfreeze     )
DEALLOCATE(zwgi_clim_grad)
DEALLOCATE(zwgtot        )
DEALLOCATE(zdw           )
!
!* masks where fields are not defined
WHERE (tgr%CUR%XTG(:,1:SIZE(tgr%CUR%XWG,2)) == xundef)
  tgr%CUR%XWG (:,:) = xundef
  tgr%CUR%XWGI(:,:) = xundef
END WHERE
!
!-------------------------------------------------------------------------------------
!
ideep_soil = tgro%NLAYER_GR
 CALL prep_ver_snow(tgr%CUR%TSNOW,xzs_ls,top%XZS,spread(ztg_ls,3,1),spread(tgr%CUR%XTG,3,1),ideep_soil)
!
!-------------------------------------------------------------------------------------
!
!*      2.     Deallocation of large-scale orography
!
DEALLOCATE(ztg_ls)
IF (lhook) CALL dr_hook('PREP_VER_TEB_GREENROOF',1,zhook_handle)
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_ver_teb_greenroof