prep_hor_seaflux_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_hor_seaflux_field (DTCO, UG, U, &
                                    dts, o, or, sg, s, &
                                   hprogram,hsurf,hatmfile,hatmfiletype,hpgdfile,hpgdfiletype)
!     #################################################################################
!
!!****  *PREP_HOR_SEAFLUX_FIELD* - reads, interpolates and prepares a sea field
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!      P. Le Moigne 10/2005, Phasage Arome
!!      P. Le Moigne 09/2007, sst from clim
!!      S. Senesi    09/2013, extends to fields of SSS and SIC
!!------------------------------------------------------------------
!

!
!
!
!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_data_seaflux_n, ONLY : data_seaflux_t
USE modd_ocean_n, ONLY : ocean_t
USE modd_ocean_rel_n, ONLY : ocean_rel_t
USE modd_seaflux_grid_n, ONLY : seaflux_grid_t
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_prep,           ONLY : cingrid_type, cinterp_type, xzs_ls, xlat_out, xlon_out, &
                                xx_out, xy_out, cmask
!
USE modi_read_prep_seaflux_conf
USE modi_prep_seaflux_grib
USE modi_prep_seaflux_unif
USE modi_prep_seaflux_buffer
USE modi_prep_seaflux_netcdf
USE modi_hor_interpol
USE modi_get_luout
USE modi_prep_seaflux_extern
USE modi_prep_sst_init
!
USE modi_prep_hor_ocean_fields
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
TYPE(data_seaflux_t), INTENT(INOUT) :: dts
TYPE(ocean_t), INTENT(INOUT) :: o
TYPE(ocean_rel_t), INTENT(INOUT) :: or
TYPE(seaflux_grid_t), INTENT(INOUT) :: sg
TYPE(seaflux_t), INTENT(INOUT) :: s
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: hatmfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hatmfiletype! type of the Atmospheric file
 CHARACTER(LEN=28),  INTENT(IN)  :: hpgdfile    ! name of the Atmospheric file
 CHARACTER(LEN=6),   INTENT(IN)  :: hpgdfiletype! type of the Atmospheric file
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=6)              :: yfiletype ! type of input file
 CHARACTER(LEN=28)             :: yfile     ! name of file
 CHARACTER(LEN=6)              :: yfilepgdtype ! type of input file
 CHARACTER(LEN=28)             :: yfilepgd     ! name of file
REAL, POINTER, DIMENSION(:,:) :: zfieldin  ! field to interpolate horizontally
REAL, ALLOCATABLE, DIMENSION(:,:) :: zfieldout ! field interpolated   horizontally
INTEGER                       :: iluout    ! output listing logical unit
!
LOGICAL                       :: gunif     ! flag for prescribed uniform field
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------------
!
!
!*      1.     Reading of input file name and type
!
IF (lhook) CALL dr_hook('PREP_HOR_SEAFLUX_FIELD',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
 CALL read_prep_seaflux_conf(o, &
                             hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,&
                            hatmfile,hatmfiletype,hpgdfile,hpgdfiletype,iluout,gunif)
!
 cmask = 'SEA'
!--------------------------------------------------------------------- ----------------
!
!*      2.     Reading of input  configuration (Grid and interpolation type)
!
IF (gunif) THEN
  CALL prep_seaflux_unif(iluout,hsurf,zfieldin)
ELSE IF (yfiletype=='GRIB  ') THEN
  CALL prep_seaflux_grib(hprogram,hsurf,yfile,iluout,zfieldin)
ELSE IF (yfiletype=='MESONH' .OR. yfiletype=='ASCII ' .OR. yfiletype=='LFI   '.OR. yfiletype=='FA    ') THEN        
   CALL prep_seaflux_extern(&
                            hprogram,hsurf,yfile,yfiletype,yfilepgd,yfilepgdtype,iluout,zfieldin)
ELSE IF (yfiletype=='BUFFER') THEN
   CALL prep_seaflux_buffer(hprogram,hsurf,iluout,zfieldin)
ELSE IF (yfiletype=='NETCDF') THEN
  CALL prep_seaflux_netcdf(hprogram,hsurf,yfile,iluout,zfieldin)
ELSE
  CALL abor1_sfx('PREP_HOR_SEAFLUX_FIELD: data file type not supported : '//yfiletype)
END IF
!
!
!*      4.     Horizontal interpolation
!
ALLOCATE(zfieldout(SIZE(sg%XLAT),SIZE(zfieldin,2)))
!
 CALL hor_interpol(dtco, u, &
                  iluout,zfieldin,zfieldout)
!
!*      5.     Return to historical variable
!
SELECT CASE (hsurf)
 CASE('ZS     ') 
  ALLOCATE(xzs_ls(SIZE(zfieldout,1)))
  xzs_ls(:) = zfieldout(:,1)
 CASE('SST    ')
  ALLOCATE(s%XSST(SIZE(zfieldout,1)))
  s%XSST(:) = zfieldout(:,1)
  IF (dts%LSST_DATA) THEN
     ! XSST is derived from array XDATA_SST from MODD_DATA_SEAFLUX, with time interpolation
     CALL prep_sst_init(dts, s, &
                        s%XSST)
  END IF
  IF (o%LMERCATOR) THEN
    ! Preparing input for ocean 1D model
    CALL prep_hor_ocean_fields(dtco, ug, u, &
                               o, or, sg, s, &
                               hprogram,hsurf,yfile,yfiletype,iluout,gunif)
  ENDIF
 CASE('SSS    ')
  ALLOCATE(s%XSSS(SIZE(zfieldout,1)))
  s%XSSS(:) = zfieldout(:,1)
 CASE('SIC    ')
  ALLOCATE(s%XSIC(SIZE(zfieldout,1)))
  s%XSIC(:) = zfieldout(:,1)
END SELECT
!
!-------------------------------------------------------------------------------------
!
!*      6.     Deallocations
!
DEALLOCATE(zfieldin )
DEALLOCATE(zfieldout)
IF (lhook) CALL dr_hook('PREP_HOR_SEAFLUX_FIELD',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
!
END SUBROUTINE prep_hor_seaflux_field