prep_seaflux_grib.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_seaflux_grib(HPROGRAM,HSURF,HFILE,KLUOUT,PFIELD)
!     #################################################################################
!
!!****  *PREP_SEAFLUX_GRIB* - prepares SEAFLUX fields from operational GRIB
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     S. Malardel
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!!------------------------------------------------------------------
!

!
USE mode_read_grib
!
USE modd_type_date_surf
!
USE modi_prep_grib_grid
!
USE modd_prep,       ONLY : cingrid_type, cinterp_type
USE modd_grid_grib,  ONLY : cgrib_file, nni
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: hfile     ! name of file
INTEGER,            INTENT(IN)  :: kluout    ! logical unit of output listing
REAL,DIMENSION(:,:), POINTER    :: pfield    ! field to interpolate horizontally
!
!*      0.2    declarations of local variables
!
TYPE (date_time)                :: tztime_grib    ! current date and time
 CHARACTER(LEN=6)              :: yinmodel ! model from which GRIB file originates
REAL, DIMENSION(:)  ,     POINTER :: zmask => null()          ! Land mask
REAL, DIMENSION(:),       POINTER :: zfield => null()   ! field read
REAL(KIND=JPRB) :: zhook_handle
!
!-------------------------------------------------------------------------------------
!
!*      1.     Reading of grid
!              ---------------
!
IF (lhook) CALL dr_hook('PREP_SEAFLUX_GRIB',0,zhook_handle)
!
IF (trim(hfile).NE.cgrib_file) cgrib_file=""
!
 CALL prep_grib_grid(hfile,kluout,yinmodel,cingrid_type,tztime_grib)
!
 CALL read_grib_land_mask(hfile,kluout,yinmodel,zmask)
!
!*      2.     Reading of field
!              ----------------
!-----------------
SELECT CASE(hsurf)
!-----------------
!
!* 1.  Orography
!      ---------
!
  CASE('ZS     ')
    SELECT CASE (yinmodel)
      CASE ('ECMWF ','ARPEGE','ALADIN','MOCAGE')
        CALL read_grib_zs_sea(hfile,kluout,yinmodel,zmask,zfield)
        ALLOCATE(pfield(SIZE(zfield),1))
        pfield(:,1) = zfield(:)
        DEALLOCATE(zfield)
    END SELECT

!
!* 2.  Temperature profiles
!      --------------------
!
  CASE('SST    ')
    SELECT CASE (yinmodel)
      CASE ('ECMWF ','ARPEGE','ALADIN','MOCAGE')
        CALL read_grib_sst(hfile,kluout,yinmodel,zmask,zfield)
        ALLOCATE(pfield(SIZE(zfield),1))
        pfield(:,1) = zfield(:)
        DEALLOCATE(zfield)
    END SELECT
!
!* 3.  Sea surface salinity and ice fraction
!      -------------------------------------
!
  CASE('SSS    ','SIC    ')
      ALLOCATE(pfield(nni,1))
      pfield = 0.0
!
END SELECT
!
DEALLOCATE(zmask)
!
!*      4.     Interpolation method
!              --------------------
!
 cinterp_type='HORIBL'
IF (lhook) CALL dr_hook('PREP_SEAFLUX_GRIB',1,zhook_handle)
!
!-------------------------------------------------------------------------------------
END SUBROUTINE prep_seaflux_grib