prep_sst_init.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
    SUBROUTINE prep_sst_init (DTS, S, &
                              psst)
!   ###############################################################
!!****  *SST_UPDATE*
!!
!!    PURPOSE
!!    -------
!
!     performs the time evolution of sst
!              
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!    none
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!      
!!    none
!!
!!    REFERENCE
!!    ---------
!!
!!      
!!    AUTHOR
!!    ------
!!
!!      P. Le Moigne          * Meteo-France *
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    09/2007
!!
!-------------------------------------------------------------------------------
!
!*       0.     DECLARATIONS
!               ------------
!
!
USE modd_data_seaflux_n, ONLY : data_seaflux_t
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_type_date_surf
USE modi_temporal_dists
USE modi_temporal_lts
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_seaflux_t), INTENT(INOUT) :: dts
TYPE(seaflux_t), INTENT(INOUT) :: s
!
REAL,   DIMENSION(:), INTENT(INOUT) :: psst    ! sst
!
!*      0.2    declarations of local variables
!
INTEGER                                  :: idecade  ! decade of simulation
INTEGER                                  :: jtime    ! decade of simulation
INTEGER, SAVE                            :: ji
INTEGER                                  :: jxp
REAL, DIMENSION(SIZE(PSST))              :: zsst
REAL, SAVE                               :: zsdtjx
REAL                                     :: zdt, zalpha
REAL(KIND=JPRB) :: zhook_handle
!-----------------------------------------------------------------
!
!
IF (lhook) CALL dr_hook('PREP_SST_INIT',0,zhook_handle)
loop: DO ji = dts%NTIME-1,1,-1
         s%JSX = ji
         IF (.NOT.temporal_lts(s%TTIME,dts%TDATA_SST(s%JSX))) EXIT loop
      ENDDO loop

IF ( temporal_lts( s%TTIME, dts%TDATA_SST(s%JSX) ) ) THEN
   zsst(:) = dts%XDATA_SST(:,s%JSX)     
ELSE IF ( .NOT. temporal_lts( s%TTIME, dts%TDATA_SST(dts%NTIME) ) ) THEN
  zsst(:) = dts%XDATA_SST(:,dts%NTIME)
ELSE

   CALL temporal_dists( dts%TDATA_SST(s%JSX+1)%TDATE%YEAR,dts%TDATA_SST(s%JSX+1)%TDATE%MONTH,   &
                           dts%TDATA_SST(s%JSX+1)%TDATE%DAY ,dts%TDATA_SST(s%JSX+1)%TIME,          &
                           dts%TDATA_SST(s%JSX)%TDATE%YEAR,dts%TDATA_SST(s%JSX)%TDATE%MONTH,       &
                           dts%TDATA_SST(s%JSX)%TDATE%DAY ,dts%TDATA_SST(s%JSX)%TIME,              &
                           zsdtjx                                                      )  

   CALL temporal_dists( s%TTIME%TDATE%YEAR   ,s%TTIME%TDATE%MONTH,                      &
                           s%TTIME%TDATE%DAY    ,s%TTIME%TIME,                             &
                           dts%TDATA_SST(s%JSX)%TDATE%YEAR,dts%TDATA_SST(s%JSX)%TDATE%MONTH,       &
                           dts%TDATA_SST(s%JSX)%TDATE%DAY ,dts%TDATA_SST(s%JSX)%TIME,              &
                           zdt                                                         )  
!
    zalpha = zdt / zsdtjx
!
    zsst(:)= dts%XDATA_SST(:,s%JSX)+(dts%XDATA_SST(:,s%JSX+1)-dts%XDATA_SST(:,s%JSX))*zalpha
                       
END IF

psst(:) = zsst(:)
IF (lhook) CALL dr_hook('PREP_SST_INIT',1,zhook_handle)
!
!-----------------------------------------------------------------
!
END SUBROUTINE prep_sst_init