prep_hor_ocean_fields.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
SUBROUTINE prep_hor_ocean_fields (DTCO, UG, U, &
                                   o, or, sg, s, &
                                  hprogram,hsurf,hfile,hfiletype,kluout,ounif)
!     #######################################################
!
!
!!****  *PREP_HOR_OCEAN_FIELDS* - prepares all oceanic fields for the 1D oceanic model
!!
!!    PURPOSE
!!    -------
!
!!**  METHOD
!!    ------
!!
!!    REFERENCE
!!    ---------
!!      
!!
!!    AUTHOR
!!    ------
!!     C. Lebeaupin Brossier 
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2008
!!      Modified    07/2012, P. Le Moigne : CMO1D phasing
!!------------------------------------------------------------------
!
!
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_ocean_n, ONLY : ocean_t
USE modd_ocean_rel_n, ONLY : ocean_rel_t
USE modd_seaflux_grid_n, ONLY : seaflux_grid_t
USE modd_seaflux_n, ONLY : seaflux_t
!
USE modd_surf_par,       ONLY : xundef
USE modd_ocean_csts,     ONLY : xrhoswref
USE modd_ocean_grid, ONLY : xdz1,xzhoc,nockmin,nockmax
!
USE modi_prep_hor_ocean_field
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*      0.1    declarations of arguments
!
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
TYPE(ocean_t), INTENT(INOUT) :: o
TYPE(ocean_rel_t), INTENT(INOUT) :: or
TYPE(seaflux_grid_t), INTENT(INOUT) :: sg
TYPE(seaflux_t), INTENT(INOUT) :: s
!
 CHARACTER(LEN=6),   INTENT(IN)  :: hprogram  ! program calling surf. schemes
 CHARACTER(LEN=7),   INTENT(IN)  :: hsurf     ! type of field
 CHARACTER(LEN=28),  INTENT(IN)  :: hfile     ! file name
 CHARACTER(LEN=6),   INTENT(IN)  :: hfiletype ! file type
INTEGER,            INTENT(IN)  :: kluout    ! logical unit of output listing
LOGICAL,            INTENT(IN)  :: ounif     ! flag for prescribed uniform field
!
!
!*      0.2    declarations of local variables
!
 CHARACTER(LEN=8)                    :: ysurf   ! type of field
 CHARACTER(LEN=28)                   :: yncvarname   ! variable to read
!
INTEGER                             :: il        ! number of points
INTEGER                             :: ik1
INTEGER                             :: j, jlev   ! loop counters
REAL(KIND=JPRB) :: zhook_handle
!---------------------------------------------------------------------------
!
!*      1.     Patch
!
!---------------------------------------------------------------------------
!
!*      3.     Treatment of oceanic temperature
IF (lhook) CALL dr_hook('PREP_HOR_OCEAN_FIELDS',0,zhook_handle)
ysurf='TEMP_OC'
yncvarname='temperature'
 CALL prep_hor_ocean_field(dtco, ug, u, &
                           o, or, sg, &
                           hprogram,hfile,hfiletype,kluout,ounif,ysurf,yncvarname)
!---------------------------------------------------------------------------
!
!*      4.     Treatment of oceanic salinity
ysurf='SALT_OC'
yncvarname='salinity'
 CALL prep_hor_ocean_field(dtco, ug, u, &
                           o, or, sg, &
                           hprogram,hfile,hfiletype,kluout,ounif,ysurf,yncvarname)
!---------------------------------------------------------------------------
!
!*      5.     Treatment of oceanic current
ysurf='UCUR_OC'
yncvarname='u'
 CALL prep_hor_ocean_field(dtco, ug, u, &
                           o, or, sg, &
                           hprogram,hfile,hfiletype,kluout,ounif,ysurf,yncvarname)
ysurf='VCUR_OC'
yncvarname='v'
 CALL prep_hor_ocean_field(dtco, ug, u, &
                           o, or, sg, &
                           hprogram,hfile,hfiletype,kluout,ounif,ysurf,yncvarname)
!---------------------------------------------------------------------------
!
ik1=nockmin+1
il = SIZE(o%XSEAT,1)
IF (il/=0) THEN
  ALLOCATE(o%XSEAE      (SIZE(o%XSEAT,1),nockmin:nockmax))
  o%XSEAE(:,:)   =1.e-3
  ALLOCATE(o%XSEABATH   (SIZE(o%XSEAT,1),nockmin:nockmax))
  o%XSEABATH(:,:)=1.
  ALLOCATE(o%XSEAHMO    (SIZE(o%XSEAT,1)))
  o%XSEAHMO(:)   =xundef
  ALLOCATE(o%XLE        (SIZE(o%XSEAT,1),nockmin:nockmax))
  ALLOCATE(o%XLK        (SIZE(o%XSEAT,1),nockmin:nockmax))
  ALLOCATE(o%XKMEL      (SIZE(o%XSEAT,1),nockmin:nockmax))
  ALLOCATE(o%XKMELM     (SIZE(o%XSEAT,1),nockmin:nockmax))
  o%XLE(:,:)    =xundef
  o%XLK(:,:)    =xundef
  o%XKMEL(:,:)  =xundef
  o%XKMELM(:,:) =xundef
  ALLOCATE(o%XSEATEND   (SIZE(o%XSEAT,1)))
  o%XSEATEND(:) =xundef
  !
  ALLOCATE(o%XDTFNSOL   (SIZE(o%XSEAT,1)))
  o%XDTFNSOL(:) = xundef
  ALLOCATE(o%XDTFSOL    (SIZE(o%XSEAT,1),nockmin:nockmax))
  o%XDTFSOL(:,:)= xundef  
!!----------------------------------------------------------------------------
!!
!!*      6.     Treatment of bathymetry indice and 
!!              apply bathy mask
  DO j=1,il
    DO jlev=ik1+1,nockmax
      IF (s%XSEABATHY(j)-xzhoc(jlev)>0.) THEN
        o%XSEABATH(j,jlev)=0.
        o%XSEAE(j,jlev)  = xundef
        o%XSEAU(j,jlev)  = xundef
        o%XSEAV(j,jlev)  = xundef
        o%XSEAT(j,jlev)  = xundef
        o%XSEAS(j,jlev)  = xundef
        !
        or%XSEAT_REL(j,jlev)  = xundef
        or%XSEAS_REL(j,jlev)  = xundef
        !
        or%XSEAU_REL(j,jlev)  = xundef
        or%XSEAV_REL(j,jlev)  = xundef
        !        
      ENDIF 
    ENDDO
  ENDDO
!
!---------------------------------------------------------------------------
ENDIF
IF (lhook) CALL dr_hook('PREP_HOR_OCEAN_FIELDS',1,zhook_handle)
!----------------------------------------------------------------------------
END SUBROUTINE prep_hor_ocean_fields