pgd_field.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE pgd_field (DTCO, UG, U, USS, &
                            hprogram,hfield,harea,hfile,hfiletype,punif,pfield,opresent)
!     ##############################################################
!
!!**** *PGD_FIELD* monitor for averaging and interpolations of ISBA physiographic fields
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    V. Masson        Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    10/12/97
!!    09/2010 (E. Kourzeneva):   interpolation of the lake depth 
!!                               is not allowed and not necessary
!!
!!    02/2014 (B. Decharme):     interpolation of the lake depth 
!!                               re-allowed but using the nearest point
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_surf_atm_sso_n, ONLY : surf_atm_sso_t
!
USE modd_surf_par,       ONLY : xundef
USE modd_pgd_grid,       ONLY : nl
USE modd_pgdwork,        ONLY : xsumval, nsize, catype,      &
                                nvalnbr, nvalcount, xvallist, jpvalmax
!
USE modi_get_luout
USE modi_treat_field
USE modi_interpol_field
USE modi_pack_same_rank
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
USE modi_get_surf_mask_n
!
USE modi_get_type_dim_n
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_grid_t), INTENT(INOUT) :: ug
TYPE(surf_atm_t), INTENT(INOUT) :: u
TYPE(surf_atm_sso_t), INTENT(INOUT) :: uss
!
 CHARACTER(LEN=6),  INTENT(IN) :: hprogram  ! Type of program
 CHARACTER(LEN=*),  INTENT(IN) :: hfield    ! field name for prints
 CHARACTER(LEN=3),  INTENT(IN) :: harea     ! area where field is defined
!                                          ! 'ALL' : everywhere
!                                          ! 'NAT' : on nature
!                                          ! 'TWN' : on town
!                                          ! 'SEA' : on sea
!                                          ! 'WAT' : on inland waters
 CHARACTER(LEN=28), INTENT(IN) :: hfile     ! data file name
 CHARACTER(LEN=6),  INTENT(IN) :: hfiletype ! data file type
REAL,              INTENT(IN) :: punif     ! prescribed uniform value for field
REAL, DIMENSION(:),INTENT(OUT):: pfield    ! physiographic field
LOGICAL, OPTIONAL, INTENT(OUT) :: opresent
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
INTEGER                        :: ilu    ! expected physical size of full surface array
INTEGER                        :: iluout ! output listing logical unit
INTEGER, DIMENSION(:), POINTER :: imask  ! mask for packing from complete field to nature field
INTEGER                        :: idim   !

!
 CHARACTER(LEN=20)   :: yfield
 CHARACTER(LEN=6)    :: ymask
INTEGER             :: inpts     ! number of points used for interpolation
REAL, DIMENSION(NL) :: zfield    ! physiographic field on full grid
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!*    1.      Initializations
!             ---------------
!
IF (lhook) CALL dr_hook('PGD_FIELD',0,zhook_handle)
zfield(:) = xundef
IF (present(opresent)) opresent=.true.
!-------------------------------------------------------------------------------
!
!*    2.      Output listing logical unit
!             ---------------------------
!
 CALL get_luout(hprogram,iluout)
!
!-------------------------------------------------------------------------------
!
!*    3.      Read from file
!             --------------
!
IF (len_trim(hfile)/=0) THEN
!       
!-------------------------------------------------------------------------------
!
!*    4.      Averages the field
!             ------------------
!
  ALLOCATE(nsize(nl))
  ALLOCATE(xsumval(nl))
!
  nsize(:) = 0.
  xsumval(:) = 0.
  inpts        = 3
!
  IF(hfield=="water depth") THEN
    inpts = 1
  ENDIF  
!
  IF (catype=='MAJ') THEN
    ALLOCATE(nvalnbr(nl))
    ALLOCATE(nvalcount(nl,jpvalmax))
    ALLOCATE(xvallist(nl,jpvalmax))
    nvalnbr   = 0
    nvalcount = 0
    xvallist  = xundef
    inpts     = 1
  END IF
!
  yfield = '                    '
  yfield = hfield(1:min(len(hfield),20))
!
  CALL treat_field(ug, u, uss, &
                   hprogram,'SURF  ',hfiletype,'A_MESH',hfile,   &
                   yfield,zfield,harea                           )  
!
!-------------------------------------------------------------------------------
!
!*    4.      Mask for the interpolations
!             ---------------------------
!
  SELECT CASE (harea)
    CASE ('LAN')
      WHERE ((u%XTOWN(:)+u%XNATURE(:))==0. .AND. nsize(:)==0 ) nsize(:) = -1
    CASE ('TWN')
      WHERE (u%XTOWN  (:)==0. .AND. nsize(:)==0 ) nsize(:) = -1
    CASE ('BLD')
      WHERE (u%XTOWN  (:)==0. .AND. nsize(:)==0 ) nsize(:) = -1              
    CASE ('NAT')
      WHERE (u%XNATURE(:)==0. .AND. nsize(:)==0 ) nsize(:) = -1
    CASE ('SEA')
      WHERE (u%XSEA   (:)==0. .AND. nsize(:)==0 ) nsize(:) = -1
    CASE ('WAT')
      WHERE (u%XWATER (:)==0. .AND. nsize(:)==0 ) nsize(:) = -1
  END SELECT
!
!-------------------------------------------------------------------------------
!
!*    5.      Interpolation if some points are not initialized (no data for these points)
!             ------------------------------------------------
!
  IF (punif/=xundef) THEN
    CALL interpol_field(ug, u, &
                        hprogram,iluout,nsize,zfield(:),hfield,pdef=punif,knpts=inpts)
  ELSE
    CALL interpol_field(ug, u, &
                        hprogram,iluout,nsize,zfield(:),hfield)
  END IF          
!
  DEALLOCATE(nsize    )
  DEALLOCATE(xsumval  )
  IF (catype=='MAJ') THEN
    DEALLOCATE(nvalnbr  )
    DEALLOCATE(nvalcount)
    DEALLOCATE(xvallist )
  END IF
!
!-------------------------------------------------------------------------------
!
ELSEIF (punif/=xundef) THEN
!
!*    3.1     Use of the presribed field
!             --------------------------
!
  zfield(:) = punif
!
ELSE
!
  IF (present(opresent)) THEN
    opresent=.false.
    IF (lhook) CALL dr_hook('PGD_FIELD',1,zhook_handle)
    RETURN
  ENDIF
!
  WRITE(iluout,*) ' '
  WRITE(iluout,*) '***********************************************************'
  WRITE(iluout,*) '* Error in PGD field preparation of field : ', hfield
  WRITE(iluout,*) '* There is no prescribed value and no input file          *'
  WRITE(iluout,*) '***********************************************************'
  WRITE(iluout,*) ' '
  CALL abor1_sfx('PGD_FIELD: NO PRESCRIBED VALUE NOR INPUT FILE FOR '//hfield)
!
END IF
!-------------------------------------------------------------------------------
!
!*    6.      Mask for the field
!             ------------------
!
SELECT CASE (harea)
  CASE ('LAN')
          ymask = 'LAND  '
  CASE ('TWN')
          ymask = 'TOWN  '
    CASE ('BLD')
          ymask = 'TOWN '              
  CASE ('NAT')
          ymask = 'NATURE'
  CASE ('SEA')
          ymask = 'SEA   '
  CASE ('WAT')
          ymask = 'WATER '
  CASE default
          pfield(:) = zfield(:)
          IF (lhook) CALL dr_hook('PGD_FIELD',1,zhook_handle)
          RETURN
END SELECT

 CALL get_type_dim_n(dtco, u, &
                     ymask,idim)
IF (idim/=SIZE(pfield)) THEN
   WRITE(iluout,*)'Wrong dimension of MASK: ',idim,SIZE(pfield)
   CALL abor1_sfx('PGD_FIELD: WRONG DIMENSION OF MASK')
ENDIF

ALLOCATE(imask(idim))
ilu=0
 CALL get_surf_mask_n(dtco, u, &
                      ymask,idim,imask,ilu,iluout)
 CALL pack_same_rank(imask,zfield(:),pfield(:))
DEALLOCATE(imask)
IF (lhook) CALL dr_hook('PGD_FIELD',1,zhook_handle)

!
!-------------------------------------------------------------------------------
!
END SUBROUTINE pgd_field