get_surf_maskn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #####################################################
      SUBROUTINE get_surf_mask_n (DTCO, U, &
                                  htype,kdim,kmask,klu,kluout)
!     #####################################################
!
!!****  *GET_SURF_MASK_n* - routine to define the masks between all surface 
!!    points and each of the four surface types
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    -------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson    *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modd_surf_par,   ONLY : nundef
!
USE modi_convert_cover_frac
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
USE modi_abor1_sfx
!
USE modi_get_1d_mask
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: dtco
TYPE(surf_atm_t), INTENT(INOUT) :: u
!
 CHARACTER(LEN=*),  INTENT(IN)    :: htype    ! Type of surface
INTEGER, INTENT(IN)              :: kdim     ! dimension of mask
INTEGER, DIMENSION(KDIM), INTENT(OUT) :: kmask    ! mask for reading of the files
INTEGER, INTENT(INOUT)           :: klu      ! expected physical size of full surface array
INTEGER, INTENT(IN)              :: kluout   ! output listing logical unit 
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
INTEGER           :: ilu    ! total horizontal size
REAL(KIND=JPRB) :: zhook_handle
!-------------------------------------------------------------------------------
!
!*       1.     Dimension initializations:
!               -------------------------
!
IF (lhook) CALL dr_hook('GET_SURF_MASK_N',0,zhook_handle)
IF (.NOT. ASSOCIATED(u%XCOVER)) THEN
  CALL get_mask(klu,'FULL',kmask)
  IF (lhook) CALL dr_hook('GET_SURF_MASK_N',1,zhook_handle)
  RETURN
END IF
!
!-------------------------------------------------------------------------------
!
!*        2.    Fractions
!              ---------
!
ilu = SIZE(u%XCOVER,1)
!
IF (klu==nundef .OR. klu==0) klu = ilu
!
IF (ilu/=klu) THEN
  WRITE(kluout,*) 'Error in initialization of masks for reading or writing'
  WRITE(kluout,*) 'size expected for reading/writing from atmosphere files : ',klu
  WRITE(kluout,*) 'size of surface array in module MODD_SURF_ATM           : ',ilu
  CALL abor1_sfx('GET_SURF_MASK: ERROR IN INITIALIZATION OF MASK FOR READING OR WRITING')
END IF
!
 CALL get_mask(ilu,htype,kmask)
!
IF (lhook) CALL dr_hook('GET_SURF_MASK_N',1,zhook_handle)
!-------------------------------------------------------------------------------
 CONTAINS
!
SUBROUTINE get_mask(KLU,YTYPE,IMASK)
!
IMPLICIT NONE
!
INTEGER, INTENT(IN) :: klu
 CHARACTER(LEN=*),  INTENT(IN)  :: ytype    ! Type of surface
INTEGER, DIMENSION(:), INTENT(OUT) :: imask
!
REAL, DIMENSION(KLU) :: zsea   ! sea cover
REAL, DIMENSION(KLU) :: znature! nature cover
REAL, DIMENSION(KLU) :: ztown  ! town cover
REAL, DIMENSION(KLU) :: zwater ! water cover
REAL, DIMENSION(KLU) :: zland  ! land cover
REAL, DIMENSION(KLU) :: zsurf
INTEGER :: ilu2
REAL(KIND=JPRB) :: zhook_handle
!
IF (lhook) CALL dr_hook('GET_SURF_MASK_N:GET_MASK',0,zhook_handle)
!
IF (ytype.NE.'FULL' .AND. ytype.NE.'EXTZON') THEN
  !      
  IF (.NOT. ASSOCIATED(u%XSEA)) THEN
    CALL convert_cover_frac(dtco, &
                            u%XCOVER,u%LCOVER,zsea,znature,ztown,zwater)
  ELSE
    zsea    = u%XSEA
    znature = u%XNATURE
    zwater  = u%XWATER
    ztown   = u%XTOWN
  END IF
  zland =  znature + ztown
  !
  SELECT CASE (ytype)
    CASE ('NATURE')
      zsurf = znature
    CASE ('SEA')
      zsurf = zsea
    CASE ('TOWN')
      zsurf = ztown
    CASE ('WATER')
      zsurf = zwater
    CASE ('LAND')
      zsurf = zland
  END SELECT
  !
  ilu2 = count(zsurf(:) > 0.)
  !
ELSE
  !
  zsurf(:) = 1.
  ilu2 = klu
  !
ENDIF
!
 CALL get_1d_mask(ilu2,klu,zsurf,imask)
!
IF (lhook) CALL dr_hook('GET_SURF_MASK_N:GET_MASK',1,zhook_handle)
!
END SUBROUTINE get_mask
!
END SUBROUTINE get_surf_mask_n