zoom_pgd_seaflux.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     ######spl
      SUBROUTINE zoom_pgd_seaflux (DTCO, DTS, SG, S, UG, U, GCP, &
                                   HPROGRAM,HINIFILE,HINIFILETYPE,HFILE,HFILETYPE)
!     ##############################################################
!
!!**** *PGD_SEAFLUX* monitor for averaging and interpolations of SEAFLUX physiographic fields
!!
!!    PURPOSE
!!    -------
!!
!!    METHOD
!!    ------
!!   
!
!!    EXTERNAL
!!    --------
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!    AUTHOR
!!    ------
!!
!!    P. Le Moigne     Meteo-France
!!
!!    MODIFICATION
!!    ------------
!!
!!    Original    09/2008
!!    G. TANGUY   03/2009 : add reading and interpolation of XDATA_SST and 
!!                          TDATA_SST in the case LDATA_SST=T
!!
!----------------------------------------------------------------------------
!
!*    0.     DECLARATION
!            -----------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_data_seaflux_n, ONLY : data_seaflux_t
USE modd_sfx_grid_n, ONLY : grid_t
USE modd_seaflux_n, ONLY : seaflux_t
USE modd_surf_atm_grid_n, ONLY : surf_atm_grid_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_data_cover_par,  ONLY : jpcover
USE modd_prep,             ONLY : cingrid_type, cinterp_type, linterp
!
!
USE modi_get_luout
USE modi_open_aux_io_surf
USE modi_get_surf_size_n
USE modi_pack_pgd
USE modi_prep_grid_extern
USE modi_prep_output_grid
USE modi_read_surf
USE modi_hor_interpol
USE modi_read_pgd_seaflux_par_n
USE modi_close_aux_io_surf
USE modi_clean_prep_output_grid
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*    0.1    Declaration of arguments
!            ------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(data_seaflux_t), INTENT(INOUT) :: DTS
TYPE(grid_t), INTENT(INOUT) :: SG
TYPE(seaflux_t), INTENT(INOUT) :: S
TYPE(surf_atm_grid_t), INTENT(INOUT) :: UG
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
 CHARACTER(LEN=6),     INTENT(IN)  :: HPROGRAM    ! Type of program
 CHARACTER(LEN=28),    INTENT(IN)  :: HINIFILE    ! input atmospheric file name
 CHARACTER(LEN=6),     INTENT(IN)  :: HINIFILETYPE! input atmospheric file type
 CHARACTER(LEN=28),    INTENT(IN)  :: HFILE       ! output file name
 CHARACTER(LEN=6),     INTENT(IN)  :: HFILETYPE   ! output file type
!
!
!*    0.2    Declaration of local variables
!            ------------------------------
!
!*    0.3    Declaration of namelists
!            ------------------------
!
REAL, DIMENSION(:,:), ALLOCATABLE  :: ZSEABATHY, ZWORK
INTEGER :: ILUOUT
INTEGER :: INI
INTEGER :: IRESP
INTEGER           :: JTIME          ! loop index
INTEGER           :: IVERSION, IBUGFIX
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('ZOOM_PGD_SEAFLUX',0,zhook_handle)
 CALL get_luout(hprogram,iluout)
!
!*      1.     Preparation of IO for reading in the file
!              -----------------------------------------
!
!* Note that all points are read, even those without physical meaning.
!  These points will not be used during the horizontal interpolation step.
!  Their value must be defined as XUNDEF.
!
!
 CALL open_aux_io_surf(hinifile,hinifiletype,'FULL  ')
!
!-------------------------------------------------------------------------------
!
!*    5.      Number of points and packing
!             ----------------------------
!
 CALL get_surf_size_n(dtco, u, 'SEA   ',sg%NDIM)
!
ALLOCATE(s%LCOVER     (jpcover))
ALLOCATE(s%XZS        (sg%NDIM))
ALLOCATE(sg%XLAT       (sg%NDIM))
ALLOCATE(sg%XLON       (sg%NDIM))
ALLOCATE(sg%XMESH_SIZE (sg%NDIM))
!
 CALL pack_pgd(dtco, u, hprogram, 'SEA   ', sg, s%LCOVER,  s%XCOVER, s%XZS )  
!
!------------------------------------------------------------------------------
!
!*      2.     Reading of grid
!              ---------------
!
 CALL prep_output_grid(ug%G, sg, u%NSIZE_FULL, iluout)
!
 CALL prep_grid_extern(gcp, hinifiletype,iluout,cingrid_type,cinterp_type,ini)
!
!* mask where interpolations must be done
!
linterp(:) = .true.
!
!------------------------------------------------------------------------------
!
!*      3.     Reading of fields
!              -----------------
!
ALLOCATE(zseabathy(ini,1))
 CALL read_surf(hprogram,'BATHY',zseabathy(:,1),iresp,hdir='A')
!
ALLOCATE(zwork(sg%NDIM,1))
 CALL hor_interpol(dtco, u, gcp, iluout,zseabathy(:,1:1),zwork(:,1:1)) 
ALLOCATE(s%XSEABATHY (sg%NDIM))
s%XSEABATHY(:) = zwork(:,1)
DEALLOCATE(zseabathy,zwork)
!
!============================================================
! G. TANGUY 03/2009
! reading of fields for SST_DATA
 CALL read_surf(hprogram,'SST_DATA',dts%LSST_DATA,iresp)
!
IF (dts%LSST_DATA) &
  CALL read_pgd_seaflux_par_n(dtco, u, gcp, dts, sg%NDIM, hprogram,ini,hdir='A')
!
!============================================================
!
 CALL close_aux_io_surf(hinifile,hinifiletype)
!
!============================================================
!
 CALL clean_prep_output_grid
IF (lhook) CALL dr_hook('ZOOM_PGD_SEAFLUX',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE zoom_pgd_seaflux