read_pgd_seaflux_parn.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE read_pgd_seaflux_par_n (DTCO, U, GCP, DTS, KDIM, HPROGRAM,KSIZE,HDIR)
!     ################################################
!
!!****  *READ_PGD_SEAFLUX_PAR_n* - reads SEAFLUX sst
!!                        
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    ------
!!
!!    EXTERNAL
!!    --------
!!
!!
!!    IMPLICIT ARGUMENTS
!!    ------------------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      P. Le Moigne   *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    09/2007 
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
USE modd_grid_conf_proj_n, ONLY : grid_conf_proj_t
!
USE modd_data_seaflux_n, ONLY : data_seaflux_t
!
USE modd_type_date_surf
USE modd_prep,             ONLY : linterp
!
USE modi_get_luout
USE modi_read_surf
USE modi_hor_interpol
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
TYPE(grid_conf_proj_t),INTENT(INOUT) :: GCP
!
TYPE(data_seaflux_t), INTENT(INOUT) :: DTS
!
INTEGER, INTENT(IN) :: KDIM
!
 CHARACTER(LEN=6),  INTENT(IN)  :: HPROGRAM ! program calling
INTEGER, INTENT(IN) :: KSIZE
 CHARACTER(LEN=1),OPTIONAL,INTENT(IN)  :: HDIR       ! type of field :
!                                                   ! 'H' : field with
!                                                   !       horizontal spatial dim.
!                                                   ! '-' : no horizontal dim.
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(:,:), ALLOCATABLE :: ZDATA_SST
 CHARACTER(LEN=12) :: YRECFM         ! Name of the article to be read
 CHARACTER(LEN=100):: YCOMMENT       ! Comment string
 CHARACTER(LEN=1)  :: YDIR
INTEGER           :: ILUOUT
INTEGER           :: IRESP          ! IRESP  : return-code if a problem appears
INTEGER           :: JTIME          ! loop index
INTEGER           :: IVERSION, IBUGFIX
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
IF (lhook) CALL dr_hook('READ_PGD_SEAFLUX_PAR_N',0,zhook_handle)
!
 CALL get_luout(hprogram,iluout)
!
ydir = 'H'
IF (PRESENT(hdir)) ydir = hdir
!
yrecfm='VERSION'
 CALL read_surf(hprogram,yrecfm,iversion,iresp)
!
yrecfm='BUG'
 CALL read_surf(hprogram,yrecfm,ibugfix,iresp)
!
IF (iversion<4 .OR. iversion==4 .AND. ibugfix<=4 .OR. &
    iversion>5 .OR. iversion==5 .AND. ibugfix>=1) THEN
  yrecfm='ND_SEA_TIME'
ELSE
  yrecfm='NDATA_SEA_TIME'
ENDIF
 CALL read_surf(hprogram,yrecfm,dts%NTIME,iresp,hcomment=ycomment)
!
ALLOCATE(zdata_sst(ksize,dts%NTIME))
DO jtime=1,dts%NTIME
  !
  IF (iversion>5 .OR. iversion==5 .AND. ibugfix>=1) THEN
    WRITE(yrecfm,fmt='(A7,I3.3)') 'D_SST_T',jtime
  ELSEIF (iversion<4 .OR. iversion==4 .AND. ibugfix<=4) THEN
    WRITE(yrecfm,fmt='(A9,I3.3)') 'DATA_SST_',jtime
  ELSE
    WRITE(yrecfm,fmt='(A10,I3.3)') 'DATA_SST_T',jtime
  ENDIF
  !
  CALL read_surf(hprogram,yrecfm,zdata_sst(:,jtime),iresp,&
                 hcomment=ycomment,hdir=ydir)
  !
END DO
!
ALLOCATE(dts%XDATA_SST(kdim,dts%NTIME))
IF (kdim/=ksize) THEN
  linterp(:) = .true.      
  DO jtime=1,dts%NTIME
    CALL hor_interpol(dtco, u, gcp, iluout,zdata_sst(:,jtime:jtime),dts%XDATA_SST(:,jtime:jtime))
  ENDDO
  DEALLOCATE(zdata_sst)
ELSE
  dts%XDATA_SST(:,:) = zdata_sst(:,:)
ENDIF
!
ALLOCATE(dts%TDATA_SST       (dts%NTIME))
!
IF (iversion<4 .OR. iversion==4 .AND. ibugfix<=4) THEN
  DO jtime=1,dts%NTIME
    WRITE(yrecfm,fmt='(A7,I3.3)') 'DTA_SST',jtime
    ycomment='(-)'
    CALL read_surf(hprogram,yrecfm,dts%TDATA_SST,iresp,hcomment=ycomment)
  END DO
ELSE
  IF (iversion>7 .OR. iversion==7 .AND. ibugfix>=3) THEN
    yrecfm='TD_SST'
  ELSE
    yrecfm='TDATA_SST'
  ENDIF
  ycomment='(-)'
  CALL read_surf(hprogram,yrecfm,dts%TDATA_SST,iresp,hcomment=ycomment)
ENDIF
!
IF (lhook) CALL dr_hook('READ_PGD_SEAFLUX_PAR_N',1,zhook_handle)
!-------------------------------------------------------------------------------
END SUBROUTINE read_pgd_seaflux_par_n