get_surf_sizen.F90

Go to the documentation of this file.

!SFX_LIC Copyright 1994-2014 CNRS, Meteo-France and Universite Paul Sabatier
!SFX_LIC This is part of the SURFEX software governed by the CeCILL-C licence
!SFX_LIC version 1. See LICENSE, CeCILL-C_V1-en.txt and CeCILL-C_V1-fr.txt  
!SFX_LIC for details. version 1.
!     #########
      SUBROUTINE get_surf_size_n (DTCO, U, &
                                  HTYPE,KL)
!     #####################################################
!
!!****  *GET_SURF_SIZE_n* - routine to define the masks between all surface 
!!    points and each of the four surface types
!!
!!    PURPOSE
!!    -------
!!
!!**  METHOD
!!    -------
!!
!!    REFERENCE
!!    ---------
!!
!!
!!    AUTHOR
!!    ------
!!      V. Masson    *Meteo France*
!!
!!    MODIFICATIONS
!!    -------------
!!      Original    01/2004
!-------------------------------------------------------------------------------
!
!*       0.    DECLARATIONS
!              ------------
!
!
!
!
USE modd_data_cover_n, ONLY : data_cover_t
USE modd_surf_atm_n, ONLY : surf_atm_t
!
USE modi_convert_cover_frac
!
!
USE yomhook   ,ONLY : lhook,   dr_hook
USE parkind1  ,ONLY : jprb
!
IMPLICIT NONE
!
!*       0.1   Declarations of arguments
!              -------------------------
!
!
TYPE(data_cover_t), INTENT(INOUT) :: DTCO
TYPE(surf_atm_t), INTENT(INOUT) :: U
!
 CHARACTER(LEN=*),  INTENT(IN)    :: HTYPE    ! Type of surface
INTEGER,           INTENT(OUT)   :: KL       ! number of points of this surface type
!
!*       0.2   Declarations of local variables
!              -------------------------------
!
REAL, DIMENSION(:),   ALLOCATABLE :: ZSEA   ! sea cover
REAL, DIMENSION(:),   ALLOCATABLE :: ZNATURE! nature cover
REAL, DIMENSION(:),   ALLOCATABLE :: ZTOWN  ! town cover
REAL, DIMENSION(:),   ALLOCATABLE :: ZWATER ! water cover
!
INTEGER           :: ILU    ! total horizontal size
REAL(KIND=JPRB) :: ZHOOK_HANDLE
!-------------------------------------------------------------------------------
!
!*        1.    Fractions
!              ---------
!
IF (lhook) CALL dr_hook('GET_SURF_SIZE_N',0,zhook_handle)
ilu = SIZE(u%XCOVER,1)
!
ALLOCATE(zsea(ilu))
ALLOCATE(znature(ilu))
ALLOCATE(ztown(ilu))
ALLOCATE(zwater(ilu))
IF (.NOT.ASSOCIATED(u%XSEA)) THEN
  CALL convert_cover_frac(dtco, &
                          u%XCOVER,u%LCOVER,zsea,znature,ztown,zwater)
ELSE
  zsea    = u%XSEA
  znature = u%XNATURE
  zwater  = u%XWATER
  ztown   = u%XTOWN
END IF
!
SELECT CASE (htype)
  CASE ('FULL')
   kl = ilu
   !
  CASE ('NATURE')
   kl = count(znature(:) > 0.)
   !
  CASE ('SEA')
   kl = count(zsea(:) > 0.)
   !
  CASE ('TOWN')
   kl = count(ztown(:) > 0.)
   !
  CASE ('WATER')
   !       
   kl = count(zwater(:) > 0.)
   !
  CASE ('LAND')
   !
   kl = count(znature(:) + ztown(:) > 0.)
   !
END SELECT
!-------------------------------------------------------------------------------
DEALLOCATE(zsea   )
DEALLOCATE(znature)
DEALLOCATE(ztown  )
DEALLOCATE(zwater )
IF (lhook) CALL dr_hook('GET_SURF_SIZE_N',1,zhook_handle)
!-------------------------------------------------------------------------------
!
END SUBROUTINE get_surf_size_n